列舉網絡資源

在窗體中添加二個Panel,二個SpeedButton,一個StatusBar1,一個ImageList1控件,如圖：

unit U_NET;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, Buttons, ComCtrls, ExtCtrls, ImgList;

type
  TNetResourceArray = ^TnetResource;
  TfrmNet = class(TForm)
    StatusBar: TStatusBar;
    Panel1: TPanel;
    TreeView: TTreeView;
    Panel2: TPanel;
    btnOK: TSpeedButton;
    btnCancel: TSpeedButton;
    ImageList: TImageList;
    procedure FormActivate(Sender: TObject);
    procedure TreeViewClick(Sender: TObject);
    procedure btnOKClick(Sender: TObject);
    procedure btnCancelClick(Sender: TObject);
  private
    procedure GetComputerName; //獲取計算機名
    procedure GetGroupName; //獲取組名
    { Private declarations }
  public

    { Public declarations }
  end;
 
//打開窗體，並返回選定的計算機名。
function NetExecute(aFormClass: TFormClass): string;
var
  frmNet: TfrmNet;
  node: Ttreenode;
  aComputerName : string;//全局變量，存儲選中的主機名
implementation

{$R *.DFM}
//打開窗體，並返回選定的計算機名。
function NetExecute(aFormClass: TFormClass): string;
begin
  aComputerName := '';
  with aFormClass.Create(Application) do
  begin
    try
      showModal;
    finally
      free;
    end;
    result := aComputerName;
  end;
end;

procedure TfrmNet.FormActivate(Sender: TObject);
begin
  node := treeview.Items.add(Treeview.topitem, '整個網絡');
  node.imageindex := 0;
  treeview.SetFocus;
end;

//獲取組名
procedure TfrmNet.GetGroupName;
var
  NetResource: TNetResource;
  Buf: Pointer;
  Count, BufSize, Res: DWORD;
  lphEnum: THandle;
  p: TNetResourceArray;
  i, j: SmallInt;
  NetworkTypeList: TList;
  my_node_1: Ttreenode;
begin
  statusbar.panels[0].text := '正在列舉域名...，請稍侯';
  statusbar.refresh;
  screen.Cursor := crHourGlass;
  NetworkTypeList := TList.Create;
  //獲取整個網絡中的文件資源的句柄，lphEnum爲返回名柄
  Res := WNetOpenEnum(RESOURCE_GLOBALNET, RESOURCETYPE_DISK,
    RESOURCEUSAGE_CONTAINER, nil, lphEnum);
  if Res <> NO_ERROR then exit; //執行失敗
  //獲取整個網絡中的網絡類型信息
  Count := $FFFFFFFF; //不限資源數目
  BufSize := 8192; //緩衝區大小設置爲8K
  GetMem(Buf, BufSize); //申請內存，用於獲取工作組信息
  Res := WNetEnumResource(lphEnum, Count, Pointer(Buf), BufSize);
  if (Res = ERROR_NO_MORE_ITEMS) //資源列舉完畢
    or (Res <> NO_ERROR) //執行失敗
    then Exit;
  P := TNetResourceArray(Buf);
  for I := 0 to Count - 1 do //記錄各個網絡類型的信息
  begin
    NetworkTypeList.Add(p);
    Inc(P);
  end;
  //WNetCloseEnum關閉一個列舉句柄
  Res := WNetCloseEnum(lphEnum); //關閉一次列舉
  if Res <> NO_ERROR then exit;

  for J := 0 to NetworkTypeList.Count - 1 do //列出各個網絡類型中的所有工作組名稱
  begin //列出一個網絡類型中的所有工作組名稱
    NetResource := TNetResource(NetworkTypeList.Items[J]^); //網絡類型信息
  //獲取某個網絡類型的文件資源的句柄，NetResource爲網絡類型信息，lphEnum爲返回名柄
    Res := WNetOpenEnum(RESOURCE_GLOBALNET, RESOURCETYPE_DISK,
      RESOURCEUSAGE_CONTAINER, @NetResource, lphEnum);
    if Res <> NO_ERROR then break; //執行失敗

    while true do //列舉一個網絡類型的所有工作組的信息
    begin
      Count := $FFFFFFFF; //不限資源數目
      BufSize := 8192; //緩衝區大小設置爲8K
      GetMem(Buf, BufSize); //申請內存，用於獲取工作組信息
              //獲取一個網絡類型的文件資源信息，
      Res := WNetEnumResource(lphEnum, Count, Pointer(Buf), BufSize);
      if (Res = ERROR_NO_MORE_ITEMS) //資源列舉完畢
        or (Res <> NO_ERROR) //執行失敗
        then break;
      P := TNetResourceArray(Buf);
      for I := 0 to Count - 1 do //列舉各個工作組的信息
      begin
        my_node_1 := treeview.Items.addchild(node, StrPAS(P^.lpRemoteName)); //取得一個工作組的名稱
        my_node_1.imageindex := 1;
        Inc(P);
      end;
    end;
    Res := WNetCloseEnum(lphEnum); //關閉一次列舉
    if Res <> NO_ERROR then break; //執行失敗
  end;
  FreeMem(Buf);
  NetworkTypeList.Destroy;
  screen.Cursor := crDefault;
  statusbar.panels[0].text := '';
  statusbar.refresh;
end;

//獲取計算機名
procedure TfrmNet.GetComputerName;
var
  NetResource: TNetResource;
  Buf: Pointer;
  Count, BufSize, Res: DWord;
  Ind: Integer;
  lphEnum: THandle;
  Temp: TNetResourceArray;
  groupname: string;
  my_node: Ttreenode;
  my_node_2: Ttreenode;
begin
  screen.Cursor := crHourGlass;
  statusbar.panels[0].text := '正在列舉組名...，請稍侯';
  statusbar.refresh;
  my_node := treeview.Selected;
  groupname := treeview.Selected.Text;
  FillChar(NetResource, SizeOf(NetResource), 0); //初始化網絡層次信息
  NetResource.lpRemoteName := @GroupName[1]; //指定工作組名稱
  NetResource.dwDisplayType := RESOURCEDISPLAYTYPE_SERVER; //類型爲服務器（工作組）
  NetResource.dwUsage := RESOURCEUSAGE_CONTAINER;
  NetResource.dwScope := RESOURCETYPE_DISK; //列舉文件資源信息
  //獲取指定工作組的網絡資源句柄
  Res := WNetOpenEnum(RESOURCE_GLOBALNET, RESOURCETYPE_DISK,
    RESOURCEUSAGE_CONTAINER, @NetResource, lphEnum);
  if Res <> NO_ERROR then Exit; //執行失敗
  while True do //列舉指定工作組的網絡資源
  begin
    Count := $FFFFFFFF; //不限資源數目
    BufSize := 8192; //緩衝區大小設置爲8K
    GetMem(Buf, BufSize); //申請內存，用於獲取工作組信息
   //獲取計算機名稱
    Res := WNetEnumResource(lphEnum, Count, Pointer(Buf), BufSize);
    if Res = ERROR_NO_MORE_ITEMS then break; //資源列舉完畢
    if (Res <> NO_ERROR) then Exit; //執行失敗
    Temp := TNetResourceArray(Buf);
    for Ind := 0 to Count - 1 do //列舉工作組的計算機名稱
    begin
      //獲取工作組的計算機名稱，+2表示刪除"//"，如//Aaron=>Aaron
      my_node_2 := treeview.Items.AddChild(my_node, Temp^.lpRemoteName + 2);
      my_node_2.imageindex := 2;
      Inc(Temp);
    end;
  end;
  Res := WNetCloseEnum(lphEnum); //關閉一次列舉
  if Res <> NO_ERROR then exit; //執行失敗
  FreeMem(Buf);
  screen.Cursor := crDefault;
  statusbar.panels[0].text := '';
  statusbar.refresh;
end;

//當樹型目錄被點擊時
procedure TfrmNet.TreeViewClick(Sender: TObject);
begin
  if treeview.Selected.Level = 0 then
  begin
    if treeview.Selected.count = 0 then
    //添加工作組名
      GetGroupName;
  end;
  if treeview.selected.level = 1 then
  begin
    if treeview.Selected.count = 0 then
    //添加計算機名
      GetComputerName;
  end;
  if treeview.Selected.level = 2 then
    btnOK.Enabled := true
  else
    btnOK.Enabled := false
end;

//確定按鈕，返回被選中的主機名
procedure TfrmNet.btnOKClick(Sender: TObject);
begin
  aComputerName := treeview.Selected.Text;
  close;
end;

procedure TfrmNet.btnCancelClick(Sender: TObject);
begin
  close;
end;

end.