windows下bat啓用MaraiaDB服務

分享知識  傳遞快樂

 

此命令是本人用於操作MaraiaDB服務的啓動、停止、重啓、查看配置等操作，僅供參考。

如有需要了解更多bat命令，請點擊查看《BAT命令常用API》。

 

代碼如下：

::對服務的操作
@ECHO OFF
TITLE WNMP管理程序
COLOR 0A

set WNMP_HOME=D:/WnmpServer/wnmp/bin
set MARIADB_HOME=%WNMP_HOME%/mariadb/10.4.10/bin
set SERVER_NAME=MariaDB

:MENU
:: 判斷程序是否存在
ECHO **********************************
ECHO *	
ECHO *	MariaDB程序管理
ECHO *	
ECHO **********************************

echo.
echo. [1] 啓動MariaDB
echo. [2] 關閉MariaDB
echo. [3] 重啓MariaDB
echo. [4] 刪除MariaDB
echo. [5] 查看進程
echo. [6] 查看版本
echo. [7] 刷新
echo. [0] 退出
echo.

echo.請輸入選擇的序號:
set /p ID=
	if "%id%"=="1" goto start 
	if "%id%"=="2" goto stop 
	if "%id%"=="3" goto restart 
	if "%id%"=="4" goto remove
	if "%id%"=="5" goto show 
	if "%id%"=="6" goto version
	if "%id%"=="7" goto refresh
	if "%id%"=="0" exit
PAUSE 


::*************************************************************************************
::創建
::*************************************************************************************
::啓動
:start 
	call :StartMariaDB
	call :Line
	goto MENU

::停止
:stop 
	call :StopMariaDB
	call :Line
	goto MENU

::重啓
:restart
	call :StopMariaDB
	call :StartMariaDB
	call :Line
	goto MENU

::刪除
:remove
	call :RemoveMariaDB
	call :Line
	goto MENU

::查看版本
:version
    call :MariaDBVer
	call :Line
	goto MENU

::查看進程
:show
	call :ShowMariaDB
	call :Line
	goto MENU

::刷新
:refresh
	echo. 
	cls
	goto MENU

::*************************************************************************************
::底層
::*************************************************************************************
::啓動
:StartMariaDB
	echo.
	::判斷服務是否存在，errorlevel返回0存在，1不存在
	sc query %SERVER_NAME% |findstr /i "%SERVER_NAME%">nul 2>nul
	::echo errorlevel：%errorlevel%
	if %errorlevel% EQU 1 (
		echo 服務不存在，正在創建服務....
		%MARIADB_HOME%/mysql_install_db.exe --datadir=%WNMP_HOME%/mariadb/database --service=%SERVER_NAME% --password=admini
		net start %SERVER_NAME%
	) else (
		::判斷服務是否啓動（如果是停止，則啓動服務）
		sc query %SERVER_NAME% |find /i "STOPPED">nul 2>nul
		::echo errorlevel：%errorlevel%
		for /F "tokens=3 delims=: " %%H in ('sc query %SERVER_NAME% ^| findstr "STATE"') do (
			::echo %%H
			if /I "%%H" EQU "STOPPED" (
				net start %SERVER_NAME%
			) else (
				echo %%H
			)
		)
	)
	goto :eof

::關閉
:StopMariaDB
	echo.
	::判斷服務是否存在，errorlevel返回0存在，1不存在
	sc query %SERVER_NAME% |findstr /i "%SERVER_NAME%">nul 2>nul
	::echo errorlevel：%errorlevel%
	if %errorlevel% EQU 0 (
		::判斷服務是否啓動
		sc query %SERVER_NAME% |find /i "RUNNING">nul 2>nul
		::echo errorlevel：%errorlevel%
		for /F "tokens=3 delims=: " %%H in ('sc query %SERVER_NAME% ^| findstr "STATE"') do (
			::echo %%H
			if /I "%%H" EQU "RUNNING" (
				net stop %SERVER_NAME%
			) else (
				echo %%H
			)
		)
	) else (
		echo 服務不存在，請創建服務！
	)
	goto :eof

::刪除
:RemoveMariaDB
	echo.
	::判斷服務是否存在，errorlevel返回0存在，1不存在
	sc query %SERVER_NAME% |findstr /i "%SERVER_NAME%">nul 2>nul
	::echo errorlevel：%errorlevel%
	if %errorlevel% EQU 0 (
		::判斷服務是否啓動（如果是服務已啓動，先停止再刪除）
		sc query %SERVER_NAME% |find /i "STOPPED">nul 2>nul
		::echo errorlevel：%errorlevel%
		for /F "tokens=3 delims=: " %%H in ('sc query %SERVER_NAME% ^| findstr "STATE"') do (
			::echo %%H
			if /I "%%H" EQU "STOPPED" (
				%MARIADB_HOME%/mysqld --remove %SERVER_NAME%
			) else if /I "%%H" EQU "RUNNING" (
				net stop %SERVER_NAME%
				%MARIADB_HOME%/mysqld --remove %SERVER_NAME%
			)
		)
	) else (
		echo 服務不存在！
	)
	goto :eof

::查看版本
:MariaDBVer
	echo. 
	%MARIADB_HOME%/mysqld -v
 	goto :eof
	

::查看進程
:ShowMariaDB
	echo. 
	tasklist|find /i "mysqld.exe"
	goto :eof

::
:Line
	echo.
	echo #########################################################
	echo.
	echo.

 

 

 

 

 

 

 

 

 

——————————
如有不足請留言指正
相互學習，共同進步