uboot 的啓動過程及工作原理

uboot 的啓動過程及工作原理
2.1 啓動模式介紹
    大多數 Boot Loader 都包含兩種不同的操作模式:"啓動加載"模式和"下載"模式,這種區別僅對於開發人
員纔有意義。但從最終用戶的角度看,Boot Loader 的作用就是用來加載操作系統,而並不存在所謂的啓動加
載模式與下載工作模式的區別。
    啓動加載(Boot loading)模式:這種模式也稱爲"自主"(Autonomous)模式。也即 Boot Loader 從目標機
上的某個固態存儲設備上將操作系統加載到 RAM 中運行,整個過程並沒有用戶的介入。這種模式是 Boot
Loader 的正常工作模式,因此在嵌入式產品發佈的時侯,Boot Loader 顯然必須工作在這種模式下。
    下載(Downloading)模式:在這種模式下,目標機上的 Boot Loader 將通過串口連接或網絡連接等通信手
段從主機(Host)下載文件,比如:下載內核映像和根文件系統映像等。從主機下載的文件通常首先被 Boot
Loader 保存到目標機的 RAM 中,然後再被 BootLoader 寫到目標機上的 FLASH 類固態存儲設備中。Boot
Loader 的這種模式通常在第一次安裝內核與根文件系統時被使用;此外,以後的系統更新也會使用 Boot
Loader 的這種工作模式。工作於這種模式下的 Boot Loader 通常都會向它的終端用戶提供一個簡單的命令
行接口。
   UBoot 這樣功能強大的 Boot Loader 同時支持這兩種工作模式,而且允許用戶在這兩種工作模式之間進行
切換。
    大多數 bootloader 都分爲階段 1(stage1)和階段 2(stage2)兩大部分,uboot 也不例外。依賴於 CPU 體系結構
的代碼(如 CPU 初始化代碼等)通常都放在階段 1 中且通常用彙編語言實現,而階段 2 則通常用 C 語言來實
現,這樣可以實現複雜的功能,而且有更好的可讀性和移植性。
2.2 階段 1 介紹
uboot 的 stage1 代碼通常放在 start.s 文件中,它用彙編語言寫成,其主要代碼部分如下:
2.2.1 定義入口
由於一個可執行的 Image 必須有一個入口點,並且只能有一個全局入口,通常這個入口放在 ROM(Flash)的 0x0
地址,因此,必須通知編譯器以使其知道這個入口,該工作可通過修改連接器腳本來完成。
     1. board/crane2410/uboot.lds: ENTRY(_start)   ==> cpu/arm920t/start.S: .globl _start
     2. uboot 代碼區(TEXT_BASE = 0x33F80000)定義在 board/crane2410/config.mk

2.2.2 設置異常向量
_start: b   reset                      @ 0x00000000
        ldr pc, _undefined_instruction @ 0x00000004
        ldr pc, _software_interrupt    @ 0x00000008
        ldr pc, _prefetch_abort        @ 0x0000000c
        ldr pc, _data_abort            @ 0x00000010
        ldr pc, _not_used              @ 0x00000014
        ldr pc, _irq                    @ 0x 0000018
                                           0
        ldr pc, _fiq                    @ 0x 000001c
                                           0
      當發生異常時,執行 cpu/arm920t/interrupts.c 中定義的中斷處理函數。
2.2.3 設置 CPU 的模式爲 SVC 模式
        mrs     r0,cpsr
        bic     r0,r0,#0x1f
        orr     r0,r0,#0xd3
        msr     cpsr,r0
2.2.4 關閉看門狗
#if defined(CONFIG_S3C2400) || defined(CONFIG_S3C2410)
        ldr     r0, =pWTCON
        mov     r1, #0x0     @ 根據三星手冊進行調置。
        str     r1, [r0]
2.2.5 禁掉所有中斷
        mov     r1, #0xffffffff
        ldr     r0, =INTMSK
        str     r1, [r0]
# if defined(CONFIG_S3C2410)
        ldr     r1, =0x3ff
        ldr     r0, =INTSUBMSK
        str     r1, [r0]
2.2.6 設置以 CPU 的頻率
    默認頻率爲      FCLK:HCLK:PCLK = 1:2:4,默認 FCLK 的值爲 120 MHz,該值爲 S3C2410 手冊的推薦值。
        ldr     r0, =CLKDIVN
        mov     r1, #3
        str     r1, [r0]
2.2.7 設置 CP15
   設置 CP15, 失效指令(I)Cache 和數據(D)Cache 後, 禁止 MMU 與 Cache。
cpu_init_crit:
        mov     r0, #0
        mcr     p15, 0, r0, c7, c7, 0   /* 失效 I/D cache, 見 S3C2410 手冊附錄的 2-16 */
        mcr     p15, 0, r0, c8, c7, 0   /* 失效 TLB, 見 S3C2410 手冊附錄的 2-18 */
        /*
         * 禁止 MMU 和 caches, 詳見 S3C2410 手冊附錄 2-11
         */
        mrc     p15, 0, r0, c1, c0, 0
        bic     r0, r0, #0x00002300     /* 清除 bits 13, 9:8 (--V- --RS)
                                 * Bit 8: Disable System Protection
                                 * Bit 7: Disable ROM Protection
                                 * Bit 13: 異常向量表基地址: 0x0000 0000
                                 */
        bic     r0, r0, #0x00000087     /* 清除 bits 7, 2:0 (B--- -CAM)
                                 * Bit 0: MMU disabled
                                 * Bit 1: Alignment Fault checking disabled
                                 * Bit 2: Data cache disabled
                                 * Bit 7: 0 = Little-endian operation
                                  */
         orr     r0, r0, #0x00000002      /* set bit 2 (A) Align, 1 = Fault checking enabled */
         orr     r0, r0, #0x00001000     /* set bit 12 (I) I-Cache, 1 = Instruction cache enabled
*/
         mcr     p15, 0, r0, c1, c0, 0
2.2.8 配置內存區控制寄存器
    配置內存區控制寄存器,寄存器的具體值通常由開發板廠商或硬件工程師提供. 如果您對總線週期及外圍
芯片非常熟悉, 也可以自己確定, 在 UBOOT 中的設置文件是 board/crane2410/lowlevel_init.S, 該文件包含
lowleve_init 程序段. 詳細寄存器設置及值的解釋見 3.2.2 啓動 AXD 配置開發板一節中的第 5 點.
         mov     ip, lr
         bl      lowlevel_init
         mov     lr, ip
2.2.9 安裝 U-BOOT 使的棧空間
    下面這段代碼只對不是從 Nand Flash 啓動的代碼段有意義,對從 Nand Flash 啓動的代碼,沒有意義。因爲
從 Nand Flash 中把 UBOOT 執行代碼搬移到 RAM,由 2.1.9 中代碼完成.
#ifndef CONFIG_SKIP_RELOCATE_UBOOT
...
#endif
stack_setup:
        ldr    r0, _TEXT_BASE               /* 代碼段的起始地址            */
        sub    r0, r0, #CFG_MALLOC_LEN      /* 分配的動態內存區             */
        sub    r0, r0, #CFG_GBL_DATA_SIZE /* UBOOT開發板全局數據存放 */
#ifdef CONFIG_USE_IRQ
        /* 分配 IRQ 和 FIQ 棧空間 */
        sub    r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
#endif
        sub    sp, r0, #12                  /* 留下 3 個字爲 Abort       */
2.2.10 BSS 段清 0
clear_bss:
        ldr    r0, _bss_start        /* BSS 段的起始地址         */
        ldr    r1, _bss_end          /* BSS 段的結束地址         */
        mov    r2, #0x00000000              /* BSS 段置 0                     */
clbss_l:str    r2, [r0]              /* 循環清除 BSS 段 */
        add    r0, r0, #4
        cmp    r0, r1
        ble    clbss_l
2.2.11 搬移 Nand Flash 代碼
從 Nand Flash 中, 把數據拷貝到 RAM, 是由 copy_myself 程序段完成, 該程序段詳細解釋見:第七部分的 3.1 節.
#ifdef CONFIG_S3C2410_NAND_BOOT
        bl    copy_myself
        @ jump to ram
        ldr   r1, =on_the_ram
        add pc, r1, #0
        nop
        nop
       1:    b     1b          @ infinite loop
       on_the_ram:
#endif
2.2.12 進入 C 代碼部分
        ldr     pc, _start_armboot
        _start_armboot: .word start_armboot

2.2.12 進入 C 代碼部分
          ldr      pc, _start_armboot
          _start_armboot: .word start_armboot
2.3 階段 2 的 C 語言代碼部分
lib_arm/board.c 中的 start armboot 是 C 語言開始的函數,也是整個啓動代碼中 C 語言的主函數,同時還是整個
uboot(armboot)的主函數,該函數主要完成如下操作:
2.3.1 調用一系列的初始化函數
1. 指定初始函數表:
init_fnc_t *init_sequence[] = {
         cpu_init,              /* cpu 的基本設置             */
         board_init,            /* 開發板的基本初始化             */
         interrupt_init,        /* 初始化中斷                 */
         env_init,              /* 初始化環境變量               */
         init_baudrate,         /* 初始化波特率                */
         serial_init,           /* 串口通訊初始化               */
         console_init_f,        /* 控制檯初始化第一階段 */
         display_banner,        /* 通知代碼已經運行到該處 */
         dram_init,             /* 配製可用的內存區              */
         display_dram_config,
#if defined(CONFIG_VCMA9) || defined (CONFIG_CMC_PU2)
         checkboard,
#endif
         NULL,
};
執行初始化函數的代碼如下:
         for (init_fnc_ptr = init_sequence; *init_fnc_ptr; ++init_fnc_ptr) {
                 if ((*init_fnc_ptr)() != 0) {
                        hang ();
                 }
         }
2. 配置可用的 Flash 區
    flash_init ()
3. 初始化內存分配函數
    mem_malloc_init()
4. nand flash 初始化
#if (CONFIG_COMMANDS & CFG_CMD_NAND)
             puts ("NAND:");
             nand_init();              /* 初始化 NAND */
見第七部分 3.2.3 節中的第 3 點 nand_init()函數.
5. 初始化環境變量
   env_relocate ();
6. 外圍設備初始化
    devices_init()
7. I2C 總線初始化
   i2c_init();
8. LCD 初始化
   drv_lcd_init();
9. VIDEO 初始化
   drv_video_init();
10. 鍵盤初始化
   drv_keyboard_init();
11. 系統初始化
   drv_system_init();
2.3.2 初始化網絡設備
初始化相關網絡設備,填寫 IP、MAC 地址等。
1. 設置 IP 地址
         /* IP Address */
         gd->bd->bi_ip_addr = getenv_IPaddr ("ipaddr");
           /* MAC Address */
           {
                     int i;
                     ulong reg;
                     char *s, *e;
                     uchar tmp[64];
                     i = getenv_r ("ethaddr", tmp, sizeof (tmp));
                     s = (i > 0) ? tmp : NULL;
                     for (reg = 0; reg < 6; ++reg) {
                             gd->bd->bi_enetaddr[reg] = s ? simple_strtoul (s, &e, 16) : 0;
                             if (s)
                                     s = (*e) ? e + 1 : e;
                     }
           }
2.3.3 進入主 UBOOT 命令行
進入命令循環(即整個 boot 的工作循環),接受用戶從串口輸入的命令,然後進行相應的工作。
           for (;;) {
                     main_loop (); /* 在 common/main.c */
           }
2.4 代碼搬運
爲了支持 NAND flash 起動,S3C2410 內建了內部的 4k 的 SRAM 緩存“Steppingstone”。當起動時,NAND
flash 最初的 4k 字節將被讀入”Steppingstone”然後開始執行起動代碼。通常起動代碼會把 NAND flash 中的內容
拷到 SDRAM 中以便執行主代碼。
使用硬件的 ECC, NAND flash 中的數據的有效性將會得到檢測。
功能
     1. NAND flash 模式:支持讀/刪除/編程 NAND Flash
     2. 自動起動模式:在復位時起動代碼將被讀入”Steppingstone”中,然後開始執行起動代碼。
     3. 硬件 ECC 檢測模塊(硬件檢測,軟件糾正)
     4. “Steppingstone” 4KB 內部 SRAM 在起動後可以另外使用。

lds 文件說明
1.1 主要符號說明
1. OUTPUT_FORMAT(bfdname)
   指定輸出可執行文件格式.
2. OUTPUT_ARCH(bfdname)
   指定輸出可執行文件所運行 CPU 平臺
3. ENTRY(symbol)
   指定可執行文件的入口段
1.2 段定義說明
1. 段定義格式
   SECTIONS { ...
      段名 : {
          內容
      }
      ...
   }
1.3 uboot.lds 文件說明
OUTPUT_FORMAT("elf32littlearm", "elf32littlearm", "elf32littlearm")
;指定輸出可執行文件是 elf 格式,32 位 ARM 指令,小端
OUTPUT_ARCH(arm)
;指定輸出可執行文件的平臺爲 ARM
ENTRY(_start)
;指定輸出可執行文件的起始代碼段爲_start.
SECTIONS
{
          . = 0x00000000 ; 從 0x0 位置開始
          . = ALIGN(4) ; 代碼以 4 字節對齊
          .text      : ;指定代碼段
          {
             cpu/arm920t/start.o   (.text) ; 代碼的第一個代碼部分
             *(.text) ;其它代碼部分
          }
          . = ALIGN(4)
          .rodata : { *(.rodata) } ;指定只讀數據段
          . = ALIGN(4);
          .data : { *(.data) } ;指定讀/寫數據段
          . = ALIGN(4);
          .got : { *(.got) } ;指定 got 段, got 段式是 uboot 自定義的一個段, 非標準段
          __u_boot_cmd_start = . ;把__u_boot_cmd_start 賦值爲當前位置, 即起始位置
          .u_boot_cmd : { *(.u_boot_cmd) } ;指定 u_boot_cmd 段, uboot 把所有的 uboot 命令放在該段.
          __u_boot_cmd_end = .;把__u_boot_cmd_end 賦值爲當前位置,即結束位置
          . = ALIGN(4);
          __bss_start = .; 把__bss_start 賦值爲當前位置,即 bss 段的開始位置
          .bss : { *(.bss) }; 指定 bss 段
          _end = .; 把_end 賦值爲當前位置,即 bss 段的結束位置
}