linux kernel 從入口到start_kernel 的代碼分析
本文的很多內容是參考了網上某位大俠的文章寫的<<>>,有些東西是直接從他那copy過來的。
最近分析了一下u-boot的源碼,並寫了分文檔, 爲了能夠銜接那篇文章,這次又把arm linux的啓動代碼大致分析了一下,特此寫下了這篇文檔。一來是大家可以看看u-boot到底是如何具體跳轉到linux下跑的,二來也爲自己更深入的學習linux kernel打下基礎。
本文以arm 版的linux爲例, 從kernel的第一條指令開始分析,一直分析到進入start_kernel()函數,也就是kernel啓動的彙編部分,我們把它稱之爲第一部分, 以後有時間在把啓動的第二部分在分析一下。我們當前以linux-2.6.18內核版本作爲範例來分析,本文中所有的代碼前面都會加上行號以便於講解。
由於啓動部分有一些代碼是平臺相關的,雖然大部分的平臺所實現的功能都比較類似,但是爲了更好的對code進行說明,對於平臺相關的代碼,我們選擇smdk2410平臺,
CPU是s3c2410(arm核是arm920T)進行分析。
另外,本文是以未壓縮的kernel來分析的.對於內核解壓縮部分的code,在 arch/arm/boot/compressed中,本文不做討論。
一. 啓動條件
通常從系統上電執行的boot loader的代碼, 而要從boot loader跳轉到linux kernel的第一條指令處執行需要一些特定的條件。關於對boot loader的分析請看我的另一篇文檔u-boot源碼分析。
這裏討論下進入到linux kernel時必須具備的一些條件,這一般是boot loader在跳轉到kernel之前要完成的:
1. CPU必須處於SVC(supervisor)模式,並且IRQ和FIQ中斷都是禁止的;
2. MMU(內存管理單元)必須是關閉的, 此時虛擬地址就是物理地址;
3. 數據cache(Data cache)必須是關閉的
4. 指令cache(Instruction cache)可以是打開的,也可以是關閉的,這個沒有強制要求;
5. CPU 通用寄存器0 (r0)必須是 0;
6. CPU 通用寄存器1 (r1)必須是 ARM Linux machine type (關於machine type, 我們後面會有講解)
7. CPU 通用寄存器2 (r2) 必須是 kernel parameter list 的物理地址(parameter list 是由boot loader傳遞給kernel,用來描述設備信息屬性的列表)。
更詳細的關於啓動arm linux之前要做哪些準備工作可以參考,“Booting ARM Linux"文檔
二. starting kernel
首先,我們先對幾個重要的宏進行說明(我們針對有MMU的情況):
宏 |
位置 |
默認值 |
說明 |
KERNEL_RAM_ADDR |
arch/arm/kernel/head.S +26 |
0xc0008000 |
kernel在RAM中的虛擬地址 |
PAGE_OFFSET |
include/asm-arm/memeory.h +50 |
0xc0000000 |
內核空間的起始虛擬地址 |
TEXT_OFFSET |
arch/arm/Makefile +131 |
0x00008000 |
內核在RAM中起始位置相對於 RAM起始地址的偏移 |
TEXTADDR |
arch/arm/kernel/head.S +49 |
0xc0008000 |
kernel的起始虛擬地址 |
PHYS_OFFSET |
include/asm-arm/arch- *** /memory.h |
平臺相關 |
RAM的起始物理地址,對於s3c2410來說在include/asm-arm/arch-s3c2410/memory.h下定義,值爲0x30000000(ram接在片選6上) |
內核的入口是stext,這是在arch/arm/kernel/vmlinux.lds.S中定義的:
00011: ENTRY(stext)
對於vmlinux.lds.S,這是ld script文件,此文件的格式和彙編及C程序都不同,本文不對ld script作過多的介紹,只對內核中用到的內容進行講解,關於ld的詳細內容可以參考ld.info
這裏的ENTRY(stext) 表示程序的入口是在符號stext.
而符號stext是在arch/arm/kernel/head.S中定義的:
下面我們將arm linux boot的主要代碼列出來進行一個概括的介紹,然後,我們會逐個的進行詳細的講解.
在arch/arm/kernel/head.S中 72 - 94 行,是arm linux boot的主代碼:
00072: ENTRY(stext)
00073: msr cpsr_c, #PSR_F_BIT | PSR_I_BIT | SVC_MODE @ ensure svc mode
00074: @ and irqs disabled
00075: mrc p15, 0, r9, c0, c0 @ get processor id
00076: bl __lookup_processor_type @ r5=procinfo r9=cpuid
00077: movs r10, r5 @ invalid processor (r5=0)?
00078: beq __error_p @ yes, error 'p'
00079: bl __lookup_machine_type @ r5=machinfo
00080: movs r8, r5 @ invalid machine (r5=0)?
00081: beq __error_a @ yes, error 'a'
00082: bl __create_page_tables
在進入linux kernel前要確保在管理模式下,並且IRQ,FIQ都是關閉的,因此在00073行就是要確保這幾個條件成立。
1. 確定 processor type
arch/arm/kernel/head.S中:
00075: mrc p15, 0, r9, c0, c0 @ get processor id
00076: bl __lookup_processor_type @ r5=procinfo r9=cpuid
00077: movs r10, r5 @ invalid processor (r5=0)?
00078: beq __error_p @ yes, error 'p'
75行: 通過cp15協處理器的c0寄存器來獲得processor id的指令. 關於cp15的詳細內容可參考相關的arm手冊,也可直接參考s3c2410的data sheet。
76行: 跳轉到__lookup_processor_type.在__lookup_processor_type中,會把找到匹配的processor type 對象存儲在r5中。
77,78行: 判斷r5中的processor type是否是0,如果是0,說明系統中沒找到匹配當前processor type的對象, 則跳轉到__error_p(出錯)。系統中會預先定義本系統支持的processor type 對象集。
__lookup_processor_type 函數主要是根據從cpu中獲得的processor id和系統中預先定義的本系統能支持的proc_info集進行匹配,看系統能否支持當前的processor, 並將匹配到的proc_info的基地址存到r5中, 0表示沒有找到對應的processor
type.
下面我們分析__lookup_processor_type函數。
arch/arm/kernel/head-common.S中:
00145: .type __lookup_processor_type, %function
00146: __lookup_processor_type:
00147: adr r3, 3f
00148: ldmda r3, {r5 - r7}
00149: sub r3, r3, r7 @ get offset between virt&phys
00150: add r5, r5, r3 @ convert virt addresses to
00151: add r6, r6, r3 @ physical address space
00152: 1: ldmia r5, {r3, r4} @ value, mask
00153: and r4, r4, r9 @ mask wanted bits
00154: teq r3, r4
00155: beq 2f
00156: add r5, r5, #PROC_INFO_SZ @ sizeof(proc_info_list)
00157: cmp r5, r6
00158: blo 1b
00159: mov r5, #0 @ unknown processor
00160: 2: mov pc, lr
00161:
00162: /*
00163: * This provides a C-API version of the above function.
00164: */
00165: ENTRY(lookup_processor_type)
00166: stmfd sp!, {r4 - r7, r9, lr}
00167: mov r9, r0
00168: bl __lookup_processor_type
00169: mov r0, r5
00170: ldmfd sp!, {r4 - r7, r9, pc}
00171:
00172: /*
00173: * Look in include/asm-arm/procinfo.h and arch/arm/kernel/arch.[ch] for
00174: * more information about the __proc_info and __arch_info structures.
00175: */
00176: .long __proc_info_begin
00177: .long __proc_info_end
00178: 3: .long .
00179: .long __arch_info_begin
00180: .long __arch_info_end
145, 146行是函數定義
147行: 取地址指令,這裏的3f是向前symbol名稱是3的位置,即第178行,將該地址存入r3. 這裏需要注意的是,adr指令取址,獲得的是基於pc的一個地址,要格外注意,這個地址是3f處的"運行時地址",由於此時MMU還沒有打開,也可以理解成物理地址(實地址).(詳細內容可參考arm指令手冊)
148行: 因爲r3中的地址是178行的位置的地址,因而執行完後:
r5存的是176行符號 __proc_info_begin的地址;
r6存的是177行符號 __proc_info_end的地址;
r7存的是3f處的地址.
這裏需要注意鏈接地址和運行時地址的區別. r3存儲的是運行時地址(物理地址),而r7中存儲的是鏈接地址(虛擬地址).
__proc_info_begin和__proc_info_end是在arch/arm/kernel/vmlinux.lds.S中:
00031: __proc_info_begin = .;
00032: *(.proc.info.init)
00033: __proc_info_end = .;
這裏是聲明瞭兩個變量:__proc_info_begin 和 __proc_info_end,其中等號後面的"."是location counter(詳細內容請參考ld.info)
這三行的意思是: __proc_info_begin 的位置上,放置所有文件中的 ".proc.info.init" 段的內容,然後緊接着是 __proc_info_end 的位置.
kernel 使用struct proc_info_list來描述processor type.
在 include/asm-arm/procinfo.h 中:
00029: struct proc_info_list {
00030: unsigned int cpu_val;
00031: unsigned int cpu_mask;
00032: unsigned long __cpu_mm_mmu_flags; /* used by head.S */
00033: unsigned long __cpu_io_mmu_flags; /* used by head.S */
00034: unsigned long __cpu_flush; /* used by head.S */
00035: const char *arch_name;
00036: const char *elf_name;
00037: unsigned int elf_hwcap;
00038: const char *cpu_name;
00039: struct processor *proc;
00040: struct cpu_tlb_fns *tlb;
00041: struct cpu_user_fns *user;
00042: struct cpu_cache_fns *cache;
00043:
};
我們當前以s3c2410爲例,其processor是920t的.
在arch/arm/mm/proc-arm920.S 中:
00448: .section ".proc.info.init", #alloc, #execinstr
00449:
00450: .type __arm920_proc_info,#object
00451: __arm920_proc_info:
00452: .long 0x41009200
004523: .long 0xff00fff0
00454: .long PMD_TYPE_SECT | /
00455: PMD_SECT_BUFFERABLE | /
00456: PMD_SECT_CACHEABLE | /
00457: PMD_BIT4 | /
00458: PMD_SECT_AP_WRITE | /
00459: PMD_SECT_AP_READ
00460: .long PMD_TYPE_SECT | /
00461: PMD_BIT4 | /
00462: PMD_SECT_AP_WRITE | /
00463: PMD_SECT_AP_READ
00464: b __arm920_setup
00465: .long cpu_arch_name
00466: .long cpu_elf_name
00467: .long HWCAP_SWP | HWCAP_HALF | HWCAP_THUMB
00468: .long cpu_arm920_name
00469: .long arm920_processor_functions
00470: .long v4wbi_tlb_fns
00471: .long v4wb_user_fns
00472: #ifndef CONFIG_CPU_DCACHE_WRITETHROUGH
00473: .long arm920_cache_fns
00474: #else
00475: .long v4wt_cache_fns
00476: #endif
00477: .size __arm920_proc_info, . - __arm920_proc_info
從448行,我們可以看到 __arm920_proc_info 被放到了".proc.info.init"段中.對照struct proc_info_list,我們可以看到 __cpu_flush的定義是在464行,即__arm920_setup.(我們將在"4. 調用平臺特定的__cpu_flush函數"一節中詳細分析這部分的內容.)
我們繼續分析__lookup_processor_type
149行: 從上面的分析我們可以知道r3中存儲的是3f處的物理地址,而r7存儲的是3f處的虛擬地址,這一行是計算當前程序運行的物理地址和虛擬地址的差值,將其保存到r3中.
150行: 將r5存儲的虛擬地址(__proc_info_begin)轉換成物理地址
151行: 將r6存儲的虛擬地址(__proc_info_end)轉換成物理地址
152行: 對照struct proc_info_list,可以得知,這句是將當前proc_info的cpu_val和cpu_mask分別存
到r3, r4中
153行: r9中存儲了processor id(arch/arm/kernel/head.S中的75行),與r4的cpu_mask進行邏輯與得到我們需要的值
154行: 將153行中得到的值與r3中的cpu_val進行比較
155行: 如果相等,說明我們找到了對應的processor type,跳到160行,返回
156行: 如果不相等, 將r5指向下一個proc_info,
157行: 和r6比較,檢查是否到了__proc_info_end.
158行: 如果沒有到__proc_info_end,表明還有proc_info配置,返回152行繼續查找
159行: 執行到這裏,說明所有的proc_info都匹配過了,但是沒有找到匹配的,將r5設置成0(unknown
processor)
160行: 返回
2. 確定 machine type
繼續分析head.S,確定了processor type之後,就要確定machine type了
arch/arm/kernel/head.S中:
00079: bl __lookup_machine_type @ r5=machinfo
00080: movs r8, r5 @ invalid machine (r5=0)?
00081: beq __error_a @ yes, error 'a'
79行: 跳轉到__lookup_machine_type函數, 和proc_info一樣,在系統中也預先定義好了本系統能支持的machine type集, 在__lookup_machine_type中,就是要查找系統中是否有對當前machine type的支持, 如果查找到則會把struct machine_desc的基地址(machine type)存儲在r5中。
80,81行: 將r5中的 machine_desc的基地址存儲到r8中,並判斷r5是否是0,如果是0,說明是無效的machine type,跳轉到__error_a(出錯)
__lookup_machine_type 函數
下面我們分析__lookup_machine_type 函數:
arch/arm/kernel/head-common.S中:
00176: .long __proc_info_begin
00177: .long __proc_info_end
00178: 3: .long .
00179: .long __arch_info_begin
00180: .long __arch_info_end
00181:
00182: /*
00183: * Lookup machine architecture in the linker-build list of architectures.
00184: * Note that we can't use the absolute addresses for the __arch_info
00185: * lists since we aren't running with the MMU on (and therefore, we are
00186: * not in the correct address space). We have to calculate the offset.
00187: *
00188: * r1 = machine architecture number
00189: * Returns:
00190: * r3, r4, r6 corrupted
00191: * r5 = mach_info pointer in physical address space
00192: */
00193: .type __lookup_machine_type, %function
00194: __lookup_machine_type:
00195: adr r3, 3b
00196: ldmia r3, {r4, r5, r6}
00197: sub r3, r3, r4 @ get offset between virt&phys
00198: add r5, r5, r3 @ convert virt addresses to
00199: add r6, r6, r3 @ physical address space
00200: 1: ldr r3, [r5, #MACHINFO_TYPE] @ get machine type
00201: teq r3, r1 @ matches loader number?
00202: beq 2f @ found
00203: add r5, r5, #SIZEOF_MACHINE_DESC @ next machine_desc
00204: cmp r5, r6
00205: blo 1b
00206: mov r5, #0 @ unknown machine
00207: 2: mov pc, lr
實際上上面這段代碼的原理和確定processor type的原理是一樣的。
內核中,一般使用宏MACHINE_START來定義machine type。
對於smdk2410來說, 在 arch/arm/mach-s3c2410/Mach-smdk2410.c 中:
MACHINE_START(SMDK2410, "SMDK2410") /* @TODO: request a new identifier and switch
* to SMDK2410 */
/* Maintainer: Jonas Dietsche */
.phys_io = S3C2410_PA_UART,
.io_pg_offst = (((u32)S3C24XX_VA_UART) >> 18) & 0xfffc,
.boot_params = S3C2410_SDRAM_PA + 0x100,
.map_io = smdk2410_map_io,
.init_irq = s3c24xx_init_irq,
.init_machine = smdk_machine_init,
.timer = &s3c24xx_timer,
MACHINE_END
195行:把3b處的地址存入r3中,3b處的地址就是178行處的地址。
196行: 把3b處開始的連續地址即3b處的地址,__arch_info_begin,__arch_info_end依次存入r4,r5,r6.
197行: r3中存儲的是3b處的物理地址,而r4中存儲的是3b處的虛擬地址,這裏計算處物理地址和虛擬地址的差值,保存到r3中
198行: 將r5存儲的虛擬地址(__arch_info_begin)轉換成物理地址
199行: 將r6存儲的虛擬地址(__arch_info_end)轉換成物理地址
200行: MACHINFO_TYPE 在 arch/arm/kernel/asm-offset.c 101行定義, 這裏是取 struct machine_desc中的nr(architecture number) 到r3中
201行: 將r3中取到的machine type 和 r1中的 machine type(見前面的"啓動條件")進行比較
202行: 如果相同,說明找到了對應的machine type,跳轉到207行的2f處,此時r5中存儲了對應的struct machine_desc的基地址
203行: 如果不匹配, 則取下一個machine_desc的地址
204行: 和r6進行比較,檢查是否到了__arch_info_end.
205行: 如果沒到尾,說明還有machine_desc,返回200行繼續查找.
206行: 執行到這裏,說明所有的machind_desc都查找完了,並且沒有找到匹配的, 將r5設置成0(unknown machine).
207行: 返回
3. 創建頁表
繼續分析head.S,確定了processor type和 machine type之後,就是創建頁表。
通過前面的兩步,我們已經確定了processor type 和 machine type.
此時,一些特定寄存器的值如下所示:
r8 = machine info (struct machine_desc的基地址)
r9 = cpu id (通過cp15協處理器獲得的cpu id)
r10 = procinfo (struct proc_info_list的基地址)
創建頁表是通過函數 __create_page_tables 來實現的.
這裏,我們使用的是arm的L1主頁表,L1主頁表也稱爲段頁表(section page table), L1 主頁表將4 GB 的地址空間分成若干個1 MB的段(section),因此L1頁表包含4096個頁表項(section entry). 每個頁表項是32 bits(4 bytes)
因而L1主頁表佔用 4096 *4 = 16k的內存空間.
對於ARM920,其L1 section entry的格式爲可參考arm920t TRM):
它的地址翻譯過程如下:
下面我們來分析 __create_page_tables 函數:
在 arch/arm/kernel/head.S 中:
00206: .type __create_page_tables, %function
00207: __create_page_tables:
00208: pgtbl r4 @ page table address
00209:
00210: /*
00211: * Clear the 16K level 1 swapper page table
00212: */
00213: mov r0, r4
00214: mov r3, #0
00215: add r6, r0, #0x4000
00216: 1: str r3, [r0], #4
00217: str r3, [r0], #4
00218: str r3, [r0], #4
00219: str r3, [r0], #4
00220: teq r0, r6
00221: bne 1b
00222:
00223: ldr r7, [r10, #PROCINFO_MM_MMUFLAGS] @ mm_mmuflags
00224:
00225: /*
00226: * Create identity mapping for first MB of kernel to
00227: * cater for the MMU enable. This identity mapping
00228: * will be removed by paging_init(). We use our current program
00229: * counter to determine corresponding section base address.
00230: */
00231: mov r6, pc, lsr #20 @ start of kernel section
00232: orr r3, r7, r6, lsl #20 @ flags + kernel base
00233: str r3, [r4, r6, lsl #2] @ identity mapping
00234:
00235: /*
00236: * Now setup the pagetables for our kernel direct
00237: * mapped region. We round TEXTADDR down to the
00238: * nearest megabyte boundary. It is assumed that
00239: * the kernel fits within 4 contigous 1MB sections.
00240: */
00241: add r0, r4, #(TEXTADDR & 0xff000000) >> 18 @ start of kernel
00242: str r3, [r0, #(TEXTADDR & 0x00f00000) >> 18]!
00243: add r3, r3, #1 << 20
00244: str r3, [r0, #4]! @ KERNEL + 1MB
00245: add r3, r3, #1 << 20
00246: str r3, [r0, #4]! @ KERNEL + 2MB
00247: add r3, r3, #1 << 20
00248: str r3, [r0, #4] @ KERNEL + 3MB
00249:
00250: /*
00251: * Then map first 1MB of ram in case it contains our boot params.
00252: */
00253: add r0, r4, #PAGE_OFFSET >> 18
00254: orr r6, r7, #PHYS_OFFSET
00255: str r6, [r0]
...
00314: mov pc, lr
00315: .ltorg
206, 207行: 函數聲明
208行: 通過宏 pgtbl 將r4設置成頁表的基地址(物理地址)
宏pgtbl 在 arch/arm/kernel/head.S 中:
00042: .macro pgtbl, rd
00043: ldr /rd, =(__virt_to_phys(KERNEL_RAM_ADDR - 0x4000))
00044: .endm
可以看到,頁表是位於 KERNEL_RAM_ADDR 下面 16k 的位置
宏 __virt_to_phys 是在incude/asm-arm/memory.h 中:
00125: #ifndef __virt_to_phys
00126: #define __virt_to_phys(x) ((x) - PAGE_OFFSET + PHYS_OFFSET)
00127: #define __phys_to_virt(x) ((x) - PHYS_OFFSET + PAGE_OFFSET)
00128: #endif
下面從213行 - 221行, 是將這16k 的頁表清0.
213行: r0 = r4, 將頁表基地址存在r0中
214行: 將 r3 置成0
215行: r6 = 頁表基地址 + 16k, 可以看到這是頁表的尾地址
216 - 221 行: 循環,從 r0 到 r6 將這16k頁表用0填充.
223行: 獲得proc_info_list的__cpu_mm_mmu_flags的值,並存儲到 r7中. (宏PROCINFO_MM_MMUFLAGS是在arch/arm/kernel/asm-offset.c中定義)
231行: 通過pc值的高12位(右移20位),得到kernel的section基址(從上面的圖可以看出),並存儲到r6中.因爲當前是通過運行時地址得到的kernel的section地址,因而是物理地址.
232行: r3 = r7 | (r6 << 20); flags + kernel base,得到頁表中需要設置的值.
233行: 設置頁表: mem[r4 + r6 * 4] = r3,這裏,因爲頁表的每一項是32 bits(4 bytes),所以要乘以4(<<2).
上面這三行,設置了kernel當前運行的section(物理地址所在的page entry)的頁表項
241--248行: TEXTADDR是內核的起始虛擬地址(0xc0008000), 這幾行是設置kernel起始4M虛擬地址的頁表項(個人覺得242行設置的頁表項和上面233行設置的頁表項是同一個,因爲r3沒有變,就是kernel頭1M的頁表項)。
/* TODO: 這兩行的code很奇怪,爲什麼要先取TEXTADDR的高8位(Bit[31:24])0xff000000,然後再取後面的8位(Bit[23:20])0x00f00000*/
253行: 將r0設置爲RAM第一兆虛擬地址的頁表項地址(page entry)
254行: r7中存儲的是mmu flags, 邏輯或上RAM的起始物理地址,得到RAM第一個MB頁表項的值.
255行: 設置RAM的第一個MB虛擬地址的頁表.
上面這三行是用來設置RAM中第一兆虛擬地址的頁表. 之所以要設置這個頁表項的原因是RAM的第一兆內存中可能存儲着boot params.
這樣,kernel所需要的基本的頁表我們都設置完了, 如下圖所示:
4. 調用平臺特定的 __cpu_flush 函數
當 __create_page_tables 返回之後
此時,一些特定寄存器的值如下所示:
r4 = pgtbl (page table 的物理基地址)
r8 = machine info (struct machine_desc的基地址)
r9 = cpu id (通過cp15協處理器獲得的cpu id)
r10 = procinfo (struct proc_info_list的基地址)
在我們需要開啓mmu之前,做一些必須的工作:清除ICache, 清除 DCache, 清除 Writebuffer, 清除TLB等.這些一般是通過cp15協處理器來實現的,並且是平臺相關的. 這就是__cpu_flush 需要做的工作
在 arch/arm/kernel/head.S中
00091: ldr r13, __switch_data @ address to jump to after
00092: @ mmu has been enabled
00093: adr lr, __enable_mmu @ return (PIC) address
00094: add pc, r10, #PROCINFO_INITFUNC
第91行: 將r13設置爲 __switch_data 的地址
第92行: 將lr設置爲 __enable_mmu 的地址
第93行: r10存儲的是procinfo的基地址, PROCINFO_INITFUNC是在 arch/arm/kernel/asm-offset.c 中107行定義. 該行將pc設爲 proc_info_list的 __cpu_flush 函數的地址, 即下面跳轉到該函數.在分析__lookup_processor_type 的時候,我們已經知道,對於 ARM920t 來說,其__cpu_flush指向的是函數 __arm920_setup
下面我們來分析函數 __arm920_setup
在 arch/arm/mm/proc-arm920.S 中:
00385: .type __arm920_setup, #function
00386: __arm920_setup:
00387: mov r0, #0
00388: mcr p15, 0, r0, c7, c7 @ invalidate I,D caches on v4
00389: mcr p15, 0, r0, c7, c10, 4 @ drain write buffer on v4
00390: #ifdef CONFIG_MMU
00391: mcr p15, 0, r0, c8, c7 @ invalidate I,D TLBs on v4
00392: #endif
00393: adr r5, arm920_crval
00394: ldmia r5, {r5, r6}
00395: mrc p15, 0, r0, c1, c0 @ get control register v4
00396: bic r0, r0, r5
00397: orr r0, r0, r6
00398: mov pc, lr
00399: .size __arm920_setup, . - __arm920_setup
385,386行: 定義__arm920_setup函數。
387行: 設置r0爲0。
388行: 使數據cahche, 指令cache無效。
389行: 使write buffer無效。
391行: 使數據TLB,指令TLB無效。
393行: 獲取arm920_crval的地址,並存入r5。
394行: 獲取arm920_crval地址處的連續8字節分別存入r5,r6。
arm920_crval在arch/arm/mm/proc-arm920t.c:
.type arm920_crval, #object
arm920_crval:
crval clear=0x00003f3f, mmuset=0x00003135, ucset=0x00001130
由此可知,r5 = 0x00003f3f, r6 = 0x00003135
395行: 獲取CP15下控制寄存器的值,並存入r0。
396行: 通過查看arm920_crval的值可知該行是清除r0中相關位,爲以後對這些位的賦值做準備。
397行: 設置r0中的相關位,即爲mmu做相應設置。
398行: 函數返回。
5. 開啓mmu
開啓mmu是由函數 __enable_mmu 實現的.
在進入 __enable_mmu 的時候, r0中已經存放了控制寄存器c1的一些配置(在上一步中進行的設置), 但是並沒有真正的打開mmu, 在 __enable_mmu 中,我們將打開mmu.
此時,一些特定寄存器的值如下所示:
r0 = c1 parameters (用來配置控制寄存器的參數)
r4 = pgtbl (page table 的物理基地址)
r8 = machine info (struct machine_desc的基地址)
r9 = cpu id (通過cp15協處理器獲得的cpu id)
r10 = procinfo (struct proc_info_list的基地址)
在 arch/arm/kernel/head.S 中:
00146: .type __enable_mmu, %function
00147: __enable_mmu:
00148: #ifdef CONFIG_ALIGNMENT_TRAP
00149: orr r0, r0, #CR_A
00150: #else
00151: bic r0, r0, #CR_A
00152: #endif
00153: #ifdef CONFIG_CPU_DCACHE_DISABLE
00154: bic r0, r0, #CR_C
00155: #endif
00156: #ifdef CONFIG_CPU_BPREDICT_DISABLE
00157: bic r0, r0, #CR_Z
00158: #endif
00159: #ifdef CONFIG_CPU_ICACHE_DISABLE
00160: bic r0, r0, #CR_I
00161: #endif
00162: mov r5, #(domain_val(DOMAIN_USER, DOMAIN_MANAGER) | /
00163: domain_val(DOMAIN_KERNEL, DOMAIN_MANAGER) | /
00164: domain_val(DOMAIN_TABLE, DOMAIN_MANAGER) | /
00165: domain_val(DOMAIN_IO, DOMAIN_CLIENT))
00166: mcr p15, 0, r5, c3, c0, 0 @ load domain access register
00167: mcr p15, 0, r4, c2, c0, 0 @ load page table pointer
00168: b __turn_mmu_on
00169:
00170: /*
00171: * Enable the MMU. This completely changes the structure of the visible
00172: * memory space. You will not be able to trace execution through this.
00173: * If you have an enquiry about this, *please* check the linux-arm-kernel
00174: * mailing list archives BEFORE sending another post to the list.
00175: *
00176: * r0 = cp#15 control register
00177: * r13 = *virtual* address to jump to upon completion
00178: *
00179: * other registers depend on the function called upon completion
00180: */
00181: .align 5
00182: .type __turn_mmu_on, %function
00183:__turn_mmu_on:
00184: mov r0, r0
00185: mcr p15, 0, r0, c1, c0, 0 @ write control reg
00186: mrc p15, 0, r3, c0, c0, 0 @ read id reg
00187: mov r3, r3
00188: mov r3, r3
00189: mov pc, r13
146,147行: 定義__enable_mmu函數。
148--152行:根據配置使能或禁止地址對齊錯誤檢測。
153--155行:根據配置使能或禁止數據cache。
156--158行:reserved。
159--161行:根據配置使能或禁止指令cache。
162--165行:配置相應的訪問權限並存入r5。
166行:把訪問權限寫入CP15協處理器。
167行:把頁表地址寫入CP15協處理器。
168行:跳轉到__turn_mmu_on來打開MMU。
接下來就是打開MMU了,我們看它的代碼:
第185行: 寫cp15的控制寄存器c1, 這裏是打開mmu的動作,同時會打開cache等(根據r0相應的配置)
第186行: 讀取id寄存器.
第187 - 188行: 兩個nop.
第189行: 取r13到pc中,我們前面已經看到了, r13中存儲的是 __switch_data (在arch/arm/kernel/head.S 91行),下面會跳到 __switch_data.
第187,188行的兩個nop是非常重要的,因爲在185行打開mmu 動作之後,要等到3個cycle之後纔會生效,這和arm的流水線有關係.
因而,在打開mmu動作之後又加了兩個nop動作.
6. 切換數據
下面我們就來看__switch_data:
在 arch/arm/kernel/head-common.S 中:
00014: .type __switch_data, %object
00015: __switch_data:
00016: .long __mmap_switched
00017: .long __data_loc @ r4
00018: .long __data_start @ r5
00019: .long __bss_start @ r6
00020: .long _end @ r7
00021: .long processor_id @ r4
00022: .long __machine_arch_type @ r5
00023: .long cr_alignment @ r6
00024: .long init_thread_union + THREAD_START_SP @ sp
00025:
第14, 15行: 對象定義。
第16 - 24行: 爲對象裏的每個域賦值,例如第16行存儲的是 __mmap_switched 的地址, 第17行存儲的是 __data_loc 的地址 ......
由上面對__switch_data的定義可知,最終調用的是__mmap_switched
下面我們就來看__mmap_switched:
在 arch/arm/kernel/head-common.S 中:
00026: /*
00027: * The following fragment of code is executed with the MMU on in MMU mode,
00028: * and uses absolute addresses; this is not position independent.
00029: *
00030: * r0 = cp#15 control register
00031: * r1 = machine ID
00032: * r9 = processor ID
00033: */
00034: .type __mmap_switched, %function
00035: __mmap_switched:
00036: adr r3, __switch_data + 4
00037:
00038: ldmia r3!, {r4, r5, r6, r7}
00039: cmp r4, r5 @ Copy data segment if needed
00040: 1: cmpne r5, r6
00041: ldrne fp, [r4], #4
00042: strne fp, [r5], #4
00043: bne 1b
00044:
00045: mov fp, #0 @ Clear BSS (and zero fp)
00046: 1: cmp r6, r7
00047: strcc fp, [r6],#4
00048: bcc 1b
00049:
00050: ldmia r3, {r4, r5, r6, sp}
00051: str r9, [r4] @ Save processor ID
00052: str r1, [r5] @ Save machine type
00053: bic r4, r0, #CR_A @ Clear 'A' bit
00054: stmia r6, {r0, r4} @ Save control register values
00055: b start_kernel
注意上面這些代碼就已經跑在了MMU打開的情況下了。
第34, 35行: 函數 __mmap_switched的定義。
第36行: 取 __switch_data + 4的地址到r3. 從上文可以看到這個地址就是第17行的地址.
第38行: 依次取出從第17行到第20行的地址,存儲到r4, r5, r6, r7 中. 並且累加r3的值.當執行完後, r3指向了第21行的位置.
對照上文,我們可以得知:
r4 - __data_loc
r5 - __data_start
r6 - __bss_start
r7 - _end
這幾個符號都是在 arch/arm/kernel/vmlinux.lds.S 中定義的變量:
00102: #ifdef CONFIG_XIP_KERNEL
00103: __data_loc = ALIGN(4); /* location in binary */
00104: . = PAGE_OFFSET + TEXT_OFFSET;
00105: #else
00106: . = ALIGN(THREAD_SIZE);
00107: __data_loc = .;
00108: #endif
00109:
00110: .data : AT(__data_loc) {
00111: __data_start = .; /* address in memory */
00112:
00113: /*
00114: * first, the init task union, aligned
00115: * to an 8192 byte boundary.
00116: */
00117: *(.init.task)
......
00158: .bss : {
00159: __bss_start = .; /* BSS */
00160: *(.bss)
00161: *(COMMON)
00162: _end = .;
00163: }
對於這四個變量,我們簡單的介紹一下:
__data_loc 是數據存放的位置
__data_start 是數據開始的位置
__bss_start 是bss開始的位置
_end 是bss結束的位置, 也是內核結束的位置
其中對第110行的指令講解一下: 這裏定義了.data 段,後面的AT(__data_loc) 的意思是這部分的內容是在__data_loc中存儲的(要注意,儲存的位置和鏈接的位置是可以不相同的).
關於 AT 詳細的信息請參考 ld.info
第38行: 比較 __data_loc 和 __data_start
第39 - 43行: 這幾行是判斷數據存儲的位置和數據的開始的位置是否相等,如果不相等,則需要搬運數據,從 __data_loc 將數據搬到 __data_start. 其中 __bss_start 是bss的開始的位置,也標誌了 data 結束的位置,因而用其作爲判斷數據是否搬運完成.
第45 - 48行: 是清除 bss 段的內容,將其都置成0. 這裏使用 _end 來判斷 bss 的結束位置.
第50行: 因爲在第38行的時候,r3被更新到指向第21行的位置.因而這裏取得r4, r5, r6, sp的值分別是:
r4 - processor_id
r5 - __machine_arch_type
r6 - cr_alignment
sp - init_thread_union + THREAD_START_SP
processor_id 和 __machine_arch_type 這兩個變量是在 arch/arm/kernel/setup.c 中 第62, 63行中定義的.
cr_alignment 是在 arch/arm/kernel/entry-armv.S 中定義的:
00182: .globl cr_alignment
00183: .globl cr_no_alignment
00184: cr_alignment:
00185: .space 4
00186: cr_no_alignment:
00187: .space 4
init_thread_union 是 init進程的基地址. 在 arch/arm/kernel/init_task.c 中:
00034: __attribute__((__section__(".init.task"))) =
00035: { INIT_THREAD_INFO(init_task) };
對照 vmlnux.lds.S 中的 的117行,我們可以知道init task是存放在 .data 段的開始8k, 並且是THREAD_SIZE(8k)對齊的
第51行: 將r9中存放的 processor id (在arch/arm/kernel/head.S 75行) 賦值給變量 processor_id
第52行: 將r1中存放的 machine id (見"啓動條件"一節)賦值給變量 __machine_arch_type
第53行: 清除r0中的 CR_A 位並將值存到r4中. CR_A 是在 include/asm-arm/system.h 21行定義, 是cp15控制寄存器c1的Bit[1](alignment fault enable/disable)
第54行: 這一行是存儲控制寄存器的值.
從上面 arch/arm/kernel/entry-armv.S 的代碼我們可以得知.
這一句是將r0存儲到了 cr_alignment 中,將r4存儲到了 cr_no_alignment 中.
第55行: 最終跳轉到start_kernel