第二部分:寫入數據庫(這是修改的主要內容)upload.asp頁內容
<%
'----------------------------------------------------------
'***************** 風聲無組件上傳類 2.0 *****************
'用法舉例:批量上傳
'該例主要說明默認模式下FileItem在批量上傳中的應用
'以上傳附件爲例
'下面是上傳程序(upload.asp)的代碼和註釋
'**********************************************************
'----------------------------------------------------------
OPTION EXPLICIT
Server.ScriptTimeOut=5000
%>
<!--#include FILE="UpLoadClass.asp"-->
<!--#include file="conn.asp" -->
<%
dim request2,formPath,formName,intCount,intTemp,protitle,protext,showindex,proclass,upfile,rs,sql
'建立上傳對象
set request2=new UpLoadClass
'設置文件允許的附件類型爲gif/jpg/rar/zip
request2.FileType="gif/jpg"
'設置服務器文件保存路徑
request2.SavePath="../UpLoadFile/"
'打開對象
request2.open()
%>
<html>
<head>
<title>批量上傳——風聲無組件上傳類</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<link href="db_sc8.css" rel="stylesheet" type="text/css">
</head>
<body>
<br>
<table width="90%" border="0" align="center" cellpadding="5" cellspacing="0" bgcolor="#FFFFFF">
<tr>
<td class="text12">
<%
'顯示類版本
'response.Write("<br>"&request2.version&"<br>")
'顯示文章標題
response.Write("<br>文章標題:"&request2.Form("proTitle"))
'----列出所有上傳了的文件開始----
'將記錄寫入數據庫,此爲自己新增部分
Set Rs =Server.CreateObject("Adodb.RecordSet")
Sql="select * from product"
rs.open sql,conn,1,3
intCount=0
for intTemp=1 to Ubound(request2.FileItem)
'獲取表單文件控件名稱,注意FileItem下標從1開始
formName=request2.FileItem(intTemp)
'顯示源文件路徑與文件名
response.write "<br>"&request2.form(formName&"_Path")&request2.form(formName&"_Name")
'顯示文件大小(字節數)
response.write "("&request2.form(formName&"_Size")&") => "
'顯示目標文件路徑與文件名
response.Write formPath&request2.form(formName)&" "
'顯示文件保存狀態
select case request2.form(formName&"_Err")
case -1:
response.write "沒有文件上傳<br>"
case 0:
response.write "上傳文件成功<br>"
intCount=intCount+1
case 1:
response.write "文件太大,拒絕上傳<br>"
case 2:
response.write "文件格式不對,拒絕上傳<br>"
case 3:
response.write "文件太大且格式不對,拒絕上傳<br>"
end select
upfile=request2.form(formName)
protitle=request2.Form("protitle")
rs.addnew
rs("propic")=upfile
rs("protitle")=protitle
rs.update
next
'----列出所有上傳了的文件結束----
rs.close
set rs=nothing
response.write "<br>"&intCount&" 張圖片上傳成功! "
response.write "[<a href=""javascript:history.back();"">返回</a>]"
%> </td>
</tr>
</table>
</body>
</html>
<%
'釋放上傳對象
set request2=nothing
%>