ASP顯示分頁導航條

 

<%'**************************************************************************************
'*                                                                                      *
'*                                     文件說明部分                                     *
'*                                                                                      *
'****************************************************************************************

'----------------------------------------------------------------------------------------
'該文件中實現的函數:
'    GetPage(Max)    獲取頁碼,返回類型:int
'    ShowPage(intCurPage,intPageCount,intPageSize,intRecordCount)    顯示導航條,無返回值
'----------------------------------------------------------------------------------------

'使用實例:把以下*號中的代碼放到ASP文件中的body之間
'----------------------------------------------------------------------------------------
'*<form action='' method='get' name='frmPage'>
'*< %
'*    intPageSize=5    '頁面大小:rs.pagesize
'*    intPageCount=6    '頁面數量:rs.pagecount
'*    intRecordCount=29    '總共記錄數量:rs.recordcount
'*    intCurPage=GetPage(intPageCount )    '獲取當前頁:rs.absolutepage
'*    call showpage(intCurPage,intPageCount,intPageSize,intRecordCount)    '顯示導航條
'*% >
'</form>
'----------------------------------------------------------------------------------------

'****************************************************************************************
'*                                                                                      *
'*                                     函數實現部分                                     *
'*                                                                                      *
'****************************************************************************************
%>
<script language="javascript">
     function viewPage(ipage){
        document.frmPage.m_page.value=ipage;
        document.frmPage.submit();        
     }
</script>
<%
'----------------------------------------------------------------------------------------
'函數名稱:GetPage(maxPageNum)
'函數功能:獲取m_page並且轉爲正確int類型頁碼
'參數列表:Max最大限制頁碼,如:rs.pagesize
'程序設計:覃雁祿[email protected]
'設計日期:2006-9-20
'----------------------------------------------------------------------------------------
function GetPage(Max)
        Page=Request("m_page")                   
        if Page="" then 
            Page=1
        elseif not IsNumeric(Page) then 
            Page=1 
        else
            Page=Cint(Page) 
        end if 
        if Page<1 then
            Page=1
        end if
        if Page>Max then
            Page=Max
        end if        
        GetPage=Page
end function


'----------------------------------------------------------------------------------------
'函數名稱:ShowPage(p_Current,p_Total,p_PageSize,r_Total)
'函數功能:顯示分頁導航條
'參數列表:
'        p_Total:總頁數
'        p_Current:當前頁
'        p_PageSize:每頁記錄數
'        r_Total:總記錄數
'程序設計:覃雁祿[email protected]
'設計日期:2006-9-20
'調用方法:
'    將該頁代碼包含到要調用的頁面.添加名稱爲"frmPage"的窗體,
'    在窗體中調用 ShowPage(p_Current,p_Total,p_PageSize,r_Total).
'    要傳遞的其它參數可以用該形式傳遞:<input name="keys" type="hidden" id="keys" value="1">
'    實例如下:
'    <form action="" method="get" name="frmPage">
'        <input name="keys" type="hidden" id="keys" value="1">
'        < %Call ShowPage(p_Current,p_Total,p_PageSize,r_Total)% >
'    </form>
'備    注:
'    爲方便添加其它參數,該函數不提供窗體,
'    所以調用時需放在一個窗體裏,並且將窗體名稱命名爲:frmPage.
'------------------------------------------------------------------------------------------
Sub ShowPage(p_Current,p_Total,p_PageSize,r_Total)
    response.Write "總計<font color='#FF0000'>"&r_Total&"</font>條記錄 "
    response.Write "頁次<font color='#FF0000'>"&p_Current&"</font>/<font color='#FF0000'>"&p_Total&"</font> "
    response.Write "每頁<font color='#FF0000'>"&p_PageSize&"</font>條"
    if p_Total>1 then  '當記錄大於一頁時
        if p_Current=1 then     '當前記錄爲第一頁
            response.Write " 首頁 上頁 <a href='JavaScript:viewPage("&p_Current+1&")'>下頁</a> "
            response.Write "<a href='JavaScript:viewPage("&p_Total&")' >尾頁</a>"    
        elseif p_Current=p_Total then     '當前記錄爲最後一頁
            response.Write " <a href='JavaScript:viewPage(1)'>首頁</a> "
            response.Write "<a href='JavaScript:viewPage("&p_Current-1&")'>上頁</a> 下頁 尾頁"        
        else
            response.Write " <a href='JavaScript:viewPage(1)'>首頁</a> <a href='JavaScript:viewPage("&p_Current-1&")'>上頁</a> "
            response.Write "<a href='JavaScript:viewPage("&p_Current+1&")'>下頁</a> <a href='JavaScript:viewPage("&p_Total&")'>尾頁</a>"
        end if 
    else    '當記錄只有一頁時
        response.Write " 首頁 上頁 下頁 尾頁"
    end if
    response.Write " <input name='m_page' type='text' size='3' maxlength='5' value='"&p_Current&"' onMouseOver='this.focus();this.select()'/>"
    response.Write " <input name='btnGo' type='submit' value='GO'/>"
End Sub
%>