server2003版本以上自帶工具，2000和xp想用，拷貝文件即可
1. 用批處理文件刪除當前目錄下 7 天以前的擴展名爲bkf文件（以當前系統時間爲基準）
示例： forfiles /m *.bkf /d -7 /c "cmd /c del @file /f"
2. forfiles 自動刪除7天前文件 （以當前系統時間爲基準）
示例: forfiles /p "d:/test" /s /m *.* /d -7 /c "cmd /c del @path"
d:/test換成你要的目錄路徑; /d -7 指刪除7天以前文件。
3. 刪除所有的空目錄(以刪除d:/test目錄下爲例) ：
dir /ad/b/s d:/test/ |sort /r >d:/kill.txt
For /f "tokens=*" %%i in (d:/kill.txt) DO rd "%%i"
del d:/kill.txt
4. 先刪7 天以前文件，再刪所有的空目錄 ;把以下複製到bat文件中。
@echo off
forfiles /p "d:/test" /s /m *.* /d -7 /c "cmd /c del @path"
dir /ad/b/s d:/test/ |sort /r >d:/kill.txt
For /f "tokens=*" %%i in (d:/kill.txt) DO rd "%%i"
del d:/kill.txt
5. forfiles 命令的用法及參數:
forfiles /p <目標目錄名> /d <天數> /c <執行的命令>
/p 指定了要在哪個目錄裏查找文件，默認是當前工作目錄。
/d 指定一個日期或天數，用於比較文件的最後修改日期是否符合條件。
/c 對每個找到的文件執行的命令。
例1.要把在C盤根目錄下最後修改日期大於或等於2010年1月7日的文件複製到D盤根目錄下:
forfiles /p "c:/" /d "2007-7-1" /c "cmd /c copy @path d:/"
例2.刪除在C盤backup目錄下最後修改日期在10天前的文件：
forfiles /p "c:/backup" /d -10 /c "cmd /c echo deleting @file ... && del /f @path"
6. forfiles /p 包含要刪除文件的完整路徑（如：F:/Logfiles) /m *.log -d -7 /c "cmd /c del /f
@path"
解釋一下相關參數及命令
/p <Path> ： 指定開始搜索文件的位置，如果不指定則默認爲當前目錄。
/m <SearchMask> ： 文件查找所使用的通配符如代碼中的"*.log"則爲所有日誌文件，當然也可以指定諸
如"manmee_*.log"這樣以manmee開頭的所有日誌文件。如果不指定此參數則默認爲"*.*"。
/d [{+|-}][{<Date>|<Days>}] ： 指定想選擇文件的最後修改時間，上文中用了 "/d -7" 表示所有以當
天爲基礎，7天以前的文件。當然這裏還可以指定具體時間，例如："/d -01/7/2010"這樣所有早於2010年
1月7日的文件。注意指定的時間必須是"MM/DD/YYYY"的格式。
/c 對所有文件以此執行指定的命令，命令體須在雙引號(")內，默認是"cmd /c echo @file"。上文中用
到的是"cmd /c del /f @path"刪除指定文件。（這裏的@file 和 @path 爲變量，下文中將解釋。）
下面說一下上文中用到的參數：
@PATH ： 表示文件的完整的路徑。
@File ： 表示文件名稱。
接下來我們看看刪除文件夾的操作，如果你看了上面的介紹，相信這命令你一看就能看懂。
forfiles /p 包含文件夾的路徑(如：F:/) /m 文件夾名稱(如：LogFiles) -d 0 /c "cmd /c if @ISDIR
== true rd /s/q @path"
注意這裏的"包含文件夾的路徑"不能包含要刪除的文件夾，如以上代碼所表示的就是，在F盤中查找名爲
LogFiles的文件或文件夾（不能指定查找文件夾，不過在刪除時我們做了判斷）。
還有就是這裏出現了一個新的參數"@ISDIR"他用於判斷當前文件類型是否是"文件夾類型"，如果是則爲
true否則爲false。
相信到這大家就明白了，最後再將代碼保存爲批處理文件，然後加入計劃任務定期執行即可。
看了上面的例子，覺得在 Windows Server 2003 下面要刪除老文件很簡單吧。
但如果操作系統是 Windows 2000/XP 就比較麻煩，因爲它們沒有forfiles命令，只能靠自己寫批處理來
實現了。
下面是我寫的批處理文件內容：
@echo off
rem ******************************
rem * 按時間刪除文件目錄的批處理 *
rem ******************************
rem 設置臨時目錄的路徑
set tempDir=%tmp%/remove_%date:~0,10%
if not exist %tempDir% md %tempDir%
rem 設置處理日期的腳本文件的路徑
set scriptFile=%tempDir%/get_date.vbs
rem 獲得要保留的天數
set days=%~1
if "%days%" == "" goto printUsage
rem 獲得目標目錄的路徑
set dirPath=%~2
if "%dirPath%" == "" set dirPath=.
rem 獲得要操作的文件形式
set fileSpec=%~3
if "%fileSpec%" == "" set fileSpec=*.*
rem 生成計算日期的腳本文件並獲得刪除的截止日期
echo d=date()-%1 > %scriptFile%
echo s=right("0000" ^& year(d),4) ^& "-" ^& right("00" ^& month(d),2) ^& "-" ^& right("00"
^& day(d),2) >> %scriptFile%
echo wscript.echo s >> %scriptFile%
for /f %%i in ('cscript /nologo %scriptFile%') do set lastDate=%%i
rem 處理目標目錄裏的每個對象
for /f "tokens=1,2,3* delims=<> " %%i in ('dir "%dirPath%/%fileSpec%" /a /-c /tc') do call
:proc "%%i" "%%j" "%%k" "%%l"
goto :done
rem 處理目標目錄裏對象的過程
:proc
rem 獲得對象的創建日期並判斷是否爲有效格式
set fileDate=%~1
echo %fileDate% | findstr "[0-9][0-9][0-9][0-9]-[0-9][0-9]-[0-9][0-9]" > nul
if errorlevel 1 goto end
rem 獲得對象的類型
set fileType=%~3
if "%fileType%" == "" goto end
rem 獲得對象的名稱
set fileName=%~4
if "%fileName%" == "" goto end
if "%fileName%" == "." goto end
if "%fileName%" == ".." goto end
if "%fileName%" == "字節" goto end
if "%fileName%" == "可用字節" goto end
rem 判斷對象日期是否小於或等於刪除的截止日期
if "%fileDate:~0,10%" leq "%lastDate%" (
echo deleting "%fileName%" ...
if "%fileType%" == "DIR" ( rd /s /q "%dirPath%/%fileName%" ) else ( del /q /f "%dirPath%/%
fileName%" )
)
goto end
:error
echo An error occurred during backuping.
:done
rd /s /q %tempDir%
goto end
:printUsage
echo Usage: %0 ^<Days^> [Work directory] [Target file specification (can include wildcards)]
goto end
:end
主要是利用Windows的腳本功能來計算要刪除文件的截止日期，然後for加dir命令來提取文件的日期進行
判斷。
關於forfiles和for的詳細信息，可以在Windows的幫助與支持中找到。