幾例在ASP存儲過程的使用方法

一、使用Command對象和Parameter對象傳遞參數

本講將主要使用Microsoft SQL Server7.0數據庫，先建立一個連接文件AdoSQL7.asp備用，以後用到時不再特別說明。

<% 'AdoSQL7.asp

Option Explicit

Response.Expires = 0

'第一部分: 建立連接

Dim Cnn, StrCnn

Set Cnn = Server.CreateObject("ADODB.Connection")

StrCnn = "Provider=sqloledb; User ID=sa; Password=; Initial Catalog=pubs; Data Source=ICBCZJP"

Cnn.Open StrCnn

%>

注意：自己使用時要將Data Source設爲你的數據庫服務器所在的機器名。

另外，以前使用Access數據庫時，用Microsoft Access97可以很方便的查看字段及數據，而使用SQL Server數據庫，尤其是並不在數據庫服務器，而是在另一臺機器上調試ASP腳本時，要查看字段及數據便需另外安裝工具，這裏向你提供一個工具：Msqry32.exe（Microsoft Query），這個文件隨Office97安裝，一般位於目錄“Microsoft Office/Office”下。

例wuf70.asp：

<%@ LANGUAGE="VBSCRIPT" %>

<!--#include file="AdoSQL7.asp"-->

<!--#include file="adovbs.inc"-->

<% ' wuf70.asp

Dim cmdTest, prmTest, rsTest

'創建 Command 對象

Set cmdTest = Server.CreateObject("ADODB.Command")

‘Recordset、Command對象都可以通過ActiveConnection屬性來連接Connection對象

cmdTest.ActiveConnection = Cnn

'SQL命令 - 含兩個參數， 用 ？ 表示

cmdTest.CommandText = "Update jobs Set job_desc = ? Where job_id = ?"

'設命令類型爲 SQL 語句

cmdTest.CommandType = adCmdText

'Prepared 屬性決定是否將 SQL 命令先行編譯，將其設爲True，可以加快運行

cmdTest.Prepared = True


'創建 Parameter 對象

Set prmTest=cmdTest.CreateParameter("job_desc",adVarChar,adParamInput,50,"網絡")

'將數據追加到 Parameters 數據集合中

cmdTest.Parameters.Append prmTest


Set prmTest = cmdTest.CreateParameter("job_id",adSmallInt,adParamInput,,"12")

cmdTest.Parameters.Append prmTest


'執行修改 – 不需要返回結果，簡單的使用cmdTest.Execute 就可以了

cmdTest.Execute


'重新設置參數運行 – 便可修改另一條數據

cmdTest.Parameters("job_id") = "1"

cmdTest.Parameters("job_desc") = "測試"

cmdTest.Execute


'重新設置參數運行

cmdTest("job_id") = "14"

cmdTest("job_desc") = "金融"

cmdTest.Execute


Set rsTest = Cnn.Execute("Select job_id,job_desc From jobs")

While Not rsTest.EOF

Response.Write rsTest(0) & rsTest(1) & "<br>"

rsTest.MoveNext

Wend


Cnn.close : Set prmTest = Nothing

Set cmdTest = Nothing: Set Cnn = Nothing

%>

分析：

1．Command對象的CreateParameter方法用來爲SQL命令或存儲過程建立參數對象，共有五個參數（五個參數都是可選項）：

第一個參數：參數對象的名稱；

第二個參數：參數對象的數據類型，種類太多，還是參考ADO幫助吧，這裏adVarChar（字符串值）、adSmallInt（2 字節帶符號整型）；

第三個參數：參數類型。可以是：adParamInput（指示輸入參數）、adParamOutput（ 指示爲輸出參數）、adParamReturnvalue（指示爲返回值）、adParamUnknown（指示參數類型無法確定）、adParamInputOutput（指示爲輸入/輸出參數）；

第四個參數：參數的數據長度，最好指定爲與數據庫中對應字段長度相等，以免使用時出錯，尤其數據類型爲VarChar時，如果是整型或日期型則不必提供該值；

第五個參數：參數的設置初值。

2．cmdTest.Parameters.Append方法增加一個Parameter對象到Parameters數據集合中，從本例中也可看到如何使用多個參數。

3．從本例可以看到，只需要重新設定輸入參數，便可執行對其他數據的修改，非常方便，這一思路在編程時也是最常用的方法之一。

4．重設參數，既可以使用cmdTest.Parameters，也可以省略爲cmdTest("job_id")。


二、在ASP中使用存儲過程

什麼是存儲過程（存儲過程位於數據庫服務器中，是一個SQL語句的集合，可包含一個或多個SQL語句）、怎樣創建存儲過程不屬於本講座的內容，本講座主要是舉例說明在ASP中如何調用存儲過程。

使用存儲過程的好處是大大的，存儲過程比在ASP腳本中運行SQL命令效率更高；可以提高整體性能並減輕網絡負載（減少了在網絡服務器和數據服務器之間的交互）；可以優化ASP代碼和增強代碼靈活性等等。

（一）在存儲過程中使用輸入參數

本例中使用的存儲過程爲SQL Server7.0自帶的“byroyalty”，裏面的一條SQL語句非常簡單，無非是多了一個Create PROCEDURE byroyalty，並且有一個輸入參數爲@percentage：

Create PROCEDURE byroyalty @percentage int

AS

select au_id from titleauthor

where titleauthor.royaltyper = @percentage

serve by www.cidu.net

例wuf71.asp

<% @LANGUAGE = VBScript %>

<!--#include file="AdoSQL7.asp"-->

<!--#include file="adovbs.inc"-->

<% ' wuf71.asp

Dim cmdTest, prmTest, rsTest

Set cmdTest = Server.CreateObject("ADODB.Command")

cmdTest.CommandText = "byroyalty" '存儲過程名

'設命令類型爲 存儲過程

cmdTest.CommandType = adCmdStoredProc


'創建 Parameter 對象

Set prmTest = Server.CreateObject("ADODB.Parameter")

‘Type屬性對應wuf70.asp中的第二個參數

prmTest.Type = adInteger '4 字節的帶符號整型

‘Direction屬性對應wuf70.asp中的第三個參數

prmTest.Direction = adParamInput

‘value屬性對應wuf70.asp中的第五個參數

prmTest.value = 30

cmdTest.Parameters.Append prmTest


Set cmdTest.ActiveConnection = Cnn

‘需要返回一個記錄集，故使用Set rsTest = cmdTest.Execute

Set rsTest = cmdTest.Execute


While Not rsTest.EOF

Response.Write rsTest(0) & "<br>"

rsTest.MoveNext

Wend


Cnn.close

Set rsTest = Nothing : Set prmTest = Nothing

Set cmdTest = Nothing: Set Cnn = Nothing

%>

CommandText屬性既可以指定SQL命令，也可以指定爲存儲過程或者是表名稱。

在本例中，創建Parameter對象與wuf70.asp略有不同，其實仔細看看，意思也是差不多的，本例還有兩個屬性未用：prmTest.Name、prmTest.Size，加上Type、Direction和value，對應於wuf70.asp中的五個參數。


（二）使用輸出參數

從數據庫表中取得一個記錄或計算一個值時，需要使用返回輸出參數的存儲過程。爲了舉例，先在SQL Server的pubs庫中新建一存儲過程OUTemploy，該存儲過程需要輸入兩個日期，然後輸出一個最大值。

Create PROCEDURE OUTemploy

(

@job_lvl tinyint OUTPUT,

@hire_date1 datetime,

@hire_date2 datetime

)

AS

select @job_lvl = MAX(job_lvl) from employee

where hire_date >= @hire_date1 and hire_date <= @hire_date2

有多種方法可以建立存儲過程：

1．使用Microsoft SQL Server的Enterprise Manager，打開後在左邊的樹目錄中依次打開：Console Root – Microsoft SQL Servers – SQL Server Group – ICBCZJP(Windows NT) – databases – pubs – stored procedure – New stored procedure，輸入存儲過程後，還可對其進行語法檢測；

2．使用Microsoft SQL Server的Query Analyzer，先連接數據庫服務器並選擇pubs數據庫。輸入上面的存儲過程並點擊Execute Query(或按F5)；

3．使用VB6.0，打開菜單“視圖”/“數據視圖窗口”後，右鍵單擊“數據鏈接”/“新建數據鏈接”；

4．使用ASP腳本創建存儲過程，例wuf75.asp：

<% @LANGUAGE = VBScript %>

<!--#include file="AdoSQL7.asp"-->

<!--#include file="adovbs.inc"-->

<% ' wuf75.asp

Dim StrSQL

'注: & Chr(10) & Chr(13) 完全可以不要, 主要是爲了好看

StrSQL="Create PROCEDURE OUTemploy ( @job_lvl tinyint OUTPUT, " & Chr(10) & Chr(13) &_

"@hire_date1 datetime, @hire_date2 datetime) AS " & Chr(10) & Chr(13) &_

"select @job_lvl = MAX(job_lvl) from employee " &_

"where hire_date >= @hire_date1 and hire_date <= @hire_date2"


Cnn.Execute StrSQL

Response.Write "創建存儲過程成功"

Cnn.close: Set Cnn = Nothing

%>

存儲過程創建後，除了使用菜單，你還可以使用SQL語句“Drop Procedure OUTemploy”刪除它。

例wuf72.asp – 把所需要的輸入參數送入存儲過程並取得輸出結果。

<% @LANGUAGE = VBScript %>

<!--#include file="AdoSQL7.asp"-->

<!--#include file="adovbs.inc"-->

<% ' wuf72.asp

Dim cmdTest, prmTest

Set cmdTest = Server.CreateObject("ADODB.Command")

cmdTest.ActiveConnection = Cnn

cmdTest.CommandText = "OUTemploy" '存儲過程名

cmdTest.CommandType = adCmdStoredProc


'創建 Parameter 對象

Set prmTest = cmdTest.CreateParameter("job_lvl",adTinyInt,adParamOutput)

cmdTest.Parameters.Append prmTest

'adTinyInt - 1 字節帶符號整型

'adDbDate - 日期值 (yyyymmdd)


Set prmTest = cmdTest.CreateParameter("hiredate1",adDBDate,adParamInput,,"1993-05-09")

cmdTest.Parameters.Append prmTest


Set prmTest = cmdTest.CreateParameter("hiredate2",adDBDate,adParamInput,,"1994-02-01")

cmdTest.Parameters.Append prmTest


cmdTest.Execute

‘下面三種表達方式意思一樣

Response.Write cmdtest("job_lvl") & "<br>"

Response.Write cmdTest.Parameters("job_lvl") & "<br>"

Response.Write cmdTest.Parameters("job_lvl").value


Cnn.close

Set prmTest = Nothing

Set cmdTest = Nothing: Set Cnn = Nothing

%>

（三）使用返回代碼參數

用Return語句可以從存儲過程返回不同的返回代碼，如下面存儲過程先取得一個記錄集，然後，若有叫Margaret的僱員則返回1，否則返回0。

Create Procedure Returnemploy

AS

select emp_id, fname from employee

If Exists(Select fname From employee Where fname='Margaret')

Return(1)

Else

Return(0)

例wuf73.asp

<% @LANGUAGE = VBScript %>

<!--#include file="AdoSQL7.asp"-->

<!--#include file="adovbs.inc"-->

<% ' wuf73.asp

Dim cmdTest, prmTest, rsTest

Set cmdTest = Server.CreateObject("ADODB.Command")

cmdTest.ActiveConnection = Cnn

cmdTest.CommandText = "Returnemploy" '存儲過程名

cmdTest.CommandType = adCmdStoredProc


Set prmTest = cmdTest.CreateParameter("Returnvalue",adInteger,adParamReturnvalue)

cmdTest.Parameters.Append prmTest


Set rsTest = cmdTest.Execute()

While Not rsTest.EOF

Response.Write rsTest(0) & " ][ " & rsTest(1) & "<br>"

rsTest.MoveNext

Wend

rsTest.Close: Set rsTest = Nothing

'返回 cmdtest("Returnvalue") 之前,必須先關閉rsTest, 否則結果錯誤


If cmdtest("Returnvalue") = 1 Then

Response.Write "有該僱員"

Else

Response.Write "無該僱員"

End If


Cnn.close

Set prmTest = Nothing

Set cmdTest = Nothing: Set Cnn = Nothing

%>


三、如何處理大數據

這裏的“大數據”主要是指Text（大文本）和image（圖像）字段，採用前面所述的方法無法正確獲取其數據。必須首先使用Size = rsTest(0).ActualSize獲取字段值的實際長度，然後再使用rsTest(0).GetChunk(Size)取得數據。在實際使用過程中，由於這些字段都比較大，爲了節省、合理使用服務器資源，一般均採取分段讀取的方法。例wuf74.asp:

<% @LANGUAGE = VBScript %>

<!--#include file="AdoSQL7.asp"-->

<!--#include file="adovbs.inc"-->

<% ' wuf74.asp

Dim StrSQL, rsTest

‘pr_info 是一個文本字段

StrSQL = "Select pr_info,pub_id From pub_info"

Set rsTest = Cnn.Execute(StrSQL)


Dim BasicSize, BeginSize, LText

Do While Not rsTest.EOF

Response.Write rsTest(1) & "<br>"

‘每次讀取 1024字節

BasicSize = 1024

BeginSize = 0

While BeginSize < rsTest(0).ActualSize

LText = rsTest(0).GetChunk(BasicSize)

BeginSize = BeginSize + BasicSize

‘逐段輸出到客戶端

Response.Write LText

Wend

Response.Write "<br><br>"

rsTest.MoveNext

Loop

Cnn.close

Set rsTest = Nothing: Set Cnn = Nothing

%>

在本例中，每次最多讀取1024字節，分多次讀完。反之，如果將大數據寫至數據庫中，方法類似上面，不過不是使用GetChunk方法，而是使用AppendChunk方法：

rsTest(0).AppendChunk Ltext

注意：最後介紹一個關於SQL Server數據庫的小技巧，如果你遇到過這種情況：數據庫的中文數據顯示出來均是亂碼，請不要驚慌。你只要去我的站點下載sqlsrv32.dll覆蓋“C:/Windows/System”下的同名文件就可以了。問題發生的源頭是SQL Server驅動程序，典型的情況發生在Windows98第二版（SQL Server驅動程序的版本號爲3.70.06.23）或Windows2000中或者安裝了MDAC2.5（版本號爲3.70.08.20）。