汇编语言实验十三(2)

一、题目描述

编写并安装int 7ch中断例程，功能为完成loop指令功能
参数：(cx)=循环次数，(bx)=位移
测试程序如下：

assume cs:code
code segment
start:	mov ax,0b800h
	mov es,ax
	mov di,160*12
	mov bx,offset s-offset se
	mov cx,80
s:	mov byte ptr es:[di],'!'
	add di,2
	int 7ch
se:	nop
	mov ax,4c00h
	int 21h
code ends
end start

二、安装中断例程

和实验十三（1）一样，我们需要把中断例程代码转移到0:200，然后将设置7ch处的中断向量指向0:200处即可

assume cs:code

code segment 
start:	mov ax,cs
	mov ds,ax
	mov si,offset do0

	mov ax,0
	mov es,ax
	mov di,200h

	mov cx,offset do0end-offset do0	;中断例程代码地址
	cld								;设置传输方向为正
	rep movsb						;传输源程序
		
	mov ax,0
	mov es,ax
	mov word ptr es:[7ch*4],200h
	mov word ptr es:[7ch*4+2],0		;设置中断向量

	mov ax,4c00h
	int 21h
	
do0:								;这里是中断例程的代码
do0end:	nop
	
code ends
end start

三、编写中断例程代码

功能比较简单，实现loop，可以将loop分解为三个步骤：
(1)dec cx
(2)判断cx是否为0
(3)跳转到指定命令
关键在于如何跳转
我们知道int 7ch后栈中存储的是CS:IP，也就是不继续循环的话我们返回源程序要跳转的地址，直接iret就好了，那如果继续循环呢，在已知位移的情况下，我们只要将栈顶存储的IP加上bx就可以使返回的地址是循环开头的命令

需要注意的是，我们需要一个寄存器来指向栈顶，而不能直接对栈顶修改元素，默认的段地址为ss的偏移寄存器是bp，所以我们需要把sp传给bp，然后对[bp]进行操作

所以我们在整个过程中只改变了bp寄存器的值，我们需要还原，就要在一开始压入栈。没错，这时候栈顶不再是IP了，而是bp了，所以我们实际上是要对[bp+2]进行操作
下面是中断例程代码

do0:	push bp
	mov bp,sp
	dec cx
	jcxz do1
	add [bp+2],bx
do1:	pop bp
	iret
do0end:	nop

四、运行结果