彙編之串處理

串處理

1. 串的概念

• 串：n個存儲單元稱爲串。根據存儲單元的內容，有不同的叫法，如字符串數組等。
• 串處理：對串的操作稱爲串處理。

2. 串處理指令

• 定義：串操作指令是$8086$指令系統中比較獨特的一類指令，採用比較特殊的數據串尋址方式，是可以直接實現存儲區之間操作的指令。
• 操作對象：內存中連續存放的數據串，即在連續的內存區域中以字爲單位的字串，或是以字節爲單位的字節串。

2.1 串傳送$MOVS$

• 格式：

　　　MOVS  DST,SRC
　　　MOVSB  （字節）
　　　MOVSW   （字）

• 功能：將以$SI$爲指針的源串中的一個字節（或字）存儲單元中的數據傳送至以$DI$爲指針的目的地址中去，並自動修改指針，使之指向下一個字節（或字）存儲單元。
• 執行操作：
  1. $DS：[SI]→ES：[DI]$。
  2. 當$DF=0$時，$SI$和$DI$自動增量；當$DF=1$時，$SI$和$DI$自動減量。
• 舉例：傳送$100$個字節操作數的例子。
  傳送一個字節

	mov si,offset source
	mov di,offset destination
	mov cx,100	；cx←傳送次數
	cld	；置DF=0，地址增加
again:	movsb	；傳送一個字節
	dec cx	；傳送次數減1
	jnz again
	；判斷傳送次數cx是否爲0
	；不爲0，則到again位置執行指令
	；否則，結束

傳送一個字

	mov si,offset source
	mov di,offset destination
	mov cx,50	；cx←傳送次數
	cld	；置DF=0，地址增加
again:	movsw	；傳送一個字
	dec cx	；傳送次數減1
	jnz again
	；判斷傳送次數cx是否爲0
	；不爲0，則到again位置執行指令
	；否則，結束

2.2 串比較$CMPS$

• 格式：

　　　CMPS  SRC,DST
　　　CMPSB  （字節）
　　　CMPSW   （字）

• 功能：將$SI$所指的源串中的一個字節（或字）存儲單元中的數據與$DI$所指的目的串中的一個字節（或字）存儲單元中的數據相減，並根據相減的結果設置標誌，但結果並不保存。
• 執行操作：
  1. $（[SI]）－（[DI]）$。
  2. 修改串指針，使之指向串中的下一個元素。
     當$DF=0$時，（$SI$）和（$DI$）增量。
     當$DF=1$時，（$SI$）和（$DI$）減量。
• 舉例：對$string1$和$string2$兩個字符串進行比較，若串相同，在$result$單元中置$0$，否則置$－1$。

	mov si,offset string1
	mov di,offset string2
	mov cx,count
	cld
again:	cmpsb	；比較兩個字符
	jnz unmat	；有不同字符，轉移
	dec cx
	jnz again	；進行下一個字符比較
	mov al,0	；字符串相等，設置00h
	jmp output	；轉向output
unmat:	mov al,0ffh	；設置ffh
output:	mov result,al	；輸出結果標記

2.3 串掃描$SCAS$

• 格式：

　　　SCAS     DST
　　　SCASB  （字節）
　　　SCASW   （字）

• 功能：$AL$（字節）或$AX$（字）中的內容與$DI$所指的目的串中的一個字節（或字）存儲單元中的數據相減，根據相減結果設置標誌位，結果不保存。
• 執行操作：
  1. 字節操作:$AL－[DI]$,字操作:$AX－[DI]$。
  2. 修改指針使之指向串中的下一個元素。
     　當$DF=0$時，（$DI$）增量。
     　當$DF=1$時，（$DI$）減量。
• 舉例：查找字符串

	mov di,offset string
	mov al,20h　；空格的ASCII碼值
	mov cx,count
	cld
again:	scasb	；搜索
	jz found	；爲0（ZF=1），發現空格
	dec cx	；不是空格
	jnz again	；搜索下一個字符
	...	；不含空格，則繼續執行
found:	...

2.4 串獲取$LODS$

格式：

　　　LODS     SRC
　　　LODSB  （字節）
　　　LODSW   （字）

• 功能：將$SI$所指的源串中的一個字節（或字）存儲單元中的數據取出來送入$AL$（或$AX$）中。
• 執行操作：
  1. 字節操作：$[SI]→AL$，字操作：$[SI]→AX$。
  2. 修改指針$SI$，使它指向串中的下一個元素。
     當$DF=0$時，$SI$增量。
     當$DF=1$時，$SI$減量。

2.5 串存入$STOS$

• 格式：

　　　STOS     DST
　　　STOSB  （字節）
　　　STOSW   （字）

• 功能：將$AL$或$AX$中的數據送入$DI$所指的目的串中的字節（或字）存儲單元中。
• 操作執行：
  1. 字節操作：$AL→[DI]$，字操作：$AX→[DI]$。
  2. 修改指針$DI$，使之指向串中的下一個元素。
     當$DF=0$時，$DI$增量；
     當$DF=1$時，$DI$減量。
• 舉例：數據區初始化

	mov ax,0
	mov di,0
	mov cx,1000h
	cld	；DF=0，地址增加
again:	stosw	；傳送一個字
	loop again	；傳送次數cx是否爲0

3. 串與循環

• 串操作指令執行一次，僅對數據串中的一個字節或字進行操作。但是在串操作指令前，都可以加一個重複前綴，實現串操作的重複執行。

3.1 $REP$重複前綴指令

• 格式：

 REP　串指令

• 功能：當$CX≠0$時，重複執行後面的串指令。可以理解爲每執行一次後面的串指令，$CX$減$1$，並回送$CX$，直到$CX＝0$，重複執行結束。
• 說明： $REP$指令一般用在$MOVS$、$STOS$指令前。
• 舉例：重複串傳送

	mov si,offset source
	mov di,offset destination
	mov cx,100	；cx←傳送次數
	cld
	rep movsb

rep movsb 等於一下程序。

again:	movsb	；傳送一個字節
	dec cx	；傳送次數減1
	jnz again	；判斷傳送次數cx是否爲0
	；不爲0（ZF=0），則轉移again位置執行
	；否則，結束

3.2 $REPZ$重複前綴指令

• 格式：

 REPZ　串指令

• 功能：重複執行串指令的條件是： $CX≠0$，且字符相等$ZF＝1$。可以理解爲：每執行一次串指令，$CX$減$1$回送$CX$，並判斷$ZF$是否爲$0$，只要$CX＝0$或$ZF＝0$，重複執行結束。
• 說明： $REPZ$後面常跟$CMPS$串指令，用於字符串的比較。
• 舉例：比較字符串

	mov si,offset string1
	mov di,offset string2
	mov cx,count
	cld
	repz cmpsb	；重複比較兩個字符
	jnz unmat	；字符串不等，轉移
	mov al,0	；字符串相等，設置00h
	jmp output	；轉向output
unmat:	mov al,0ffh	；設置ffh
output:	mov result,al	；輸出結果標記

3.3 $REPNZ$重複前綴指令

• 格式：

REPNZ　串指令

• 功能：重複執行後面串指令的條件是：$CX≠0$並且串不相等 $ZF＝0$。可以理解爲：每執行一次後面的串指令，$CX$減$1$，並判斷$ZF$是否爲$1$，只要$CX＝0$或$ZF＝1$，重複執行結束。
• 說明： $REPNZ$後面常跟$SCAS$串指令，用於搜索一個字符。
• 舉例：查找字符串

	mov di,offset string
	mov al,20h
	mov cx,count
	cld
	repnz scasb	；搜索
	jz found	；（ZF=1），發現空格
	...	；不含空格，則繼續執行
found:	...