boot分析參考:https://blog.csdn.net/jinold/article/details/88210770
loader.asm
;nasm loader.asm -o loader.bin
org 0100h
jmp LABEL_START ; Start
; FAT12 磁盤的頭
; ----------------------------------------------------------------------
BS_OEMName DB 'ForrestY' ; OEM String, 必須 8 個字節
BPB_BytsPerSec DW 512 ; 每扇區字節數
BPB_SecPerClus DB 1 ; 每簇多少扇區
BPB_RsvdSecCnt DW 1 ; Boot 記錄佔用多少扇區
BPB_NumFATs DB 2 ; 共有多少 FAT 表
BPB_RootEntCnt DW 224 ; 根目錄文件數最大值
BPB_TotSec16 DW 2880 ; 邏輯扇區總數
BPB_Media DB 0xF0 ; 媒體描述符
BPB_FATSz16 DW 9 ; 每FAT扇區數
BPB_SecPerTrk DW 18 ; 每磁道扇區數
BPB_NumHeads DW 2 ; 磁頭數(面數)
BPB_HiddSec DD 0 ; 隱藏扇區數
BPB_TotSec32 DD 0 ; 如果 wTotalSectorCount 是 0 由這個值記錄扇區數
BS_DrvNum DB 0 ; 中斷 13 的驅動器號
BS_Reserved1 DB 0 ; 未使用
BS_BootSig DB 29h ; 擴展引導標記 (29h)
BS_VolID DD 0 ; 卷序列號
BS_VolLab DB 'OrangeS0.02'; 卷標, 必須 11 個字節
BS_FileSysType DB 'FAT12 ' ; 文件系統類型, 必須 8個字節
RootDirSectors equ 14 ; 根目錄佔用空間: RootDirSectors = ((BPB_RootEntCnt * 32) + (BPB_BytsPerSec – 1)) / BPB_BytsPerSec; 但如果按照此公式代碼過長
SectorNoOfRootDirectory equ 19 ; Root Directory 的第一個扇區號 = BPB_RsvdSecCnt + (BPB_NumFATs * FATSz)
SectorNoOfFAT1 equ 1 ; FAT1 的第一個扇區號 = BPB_RsvdSecCnt
DeltaSectorNo equ 17 ; DeltaSectorNo = BPB_RsvdSecCnt + (BPB_NumFATs * FATSz) - 2
; 文件的開始Sector號 = DirEntry中的開始Sector號 + 根目錄佔用Sector數目 + DeltaSectorNo
DA_32 EQU 4000h ; 32 位段
DA_LIMIT_4K EQU 8000h ; 段界限粒度爲 4K 字節
DA_DPL3 EQU 60h ; DPL = 3
DA_DRW EQU 92h ; 存在的可讀寫數據段屬性值
DA_CR EQU 9Ah ; 存在的可執行可讀代碼段屬性值
SA_RPL0 EQU 0 ; ┓
SA_RPL1 EQU 1 ; ┣ RPL
SA_RPL2 EQU 2 ; ┃
SA_RPL3 EQU 3 ; ┃
SA_RPL4 EQU 4 ; ┛
;------------------------------------------------------------------------
; 宏 ------------------------------------------------------------------------------------------------------
;
; 描述符 類型 入參1(%1), 入參2(%2), 入參3(%3)
; usage: Descriptor Base, Limit, Attr
; Base: dd
; Limit: dd (low 20 bits available)
; Attr: dw (lower 4 bits of higher byte are always 0)
%macro Descriptor 3
dw %2 & 0FFFFh ; 段界限1(雙字節:字節1~字節2)
dw %1 & 0FFFFh ; 段基址1(雙字節:字節3~字節4)
db (%1 >> 16) & 0FFh ; 段基址2(單字節:字節5)
dw ((%2 >> 8) & 0F00h) | (%3 & 0F0FFh) ; 屬性1 + 段界限2 + 屬性2(雙字節:字節6~字節7)
db (%1 >> 24) & 0FFh ; 段基址3(單字節:字節8)
%endmacro ; 共 8 字節
;
; 門 類型 入參1, 入參2, 入參3, 入參4
; usage: Gate Selector, Offset, DCount, Attr
; Selector: dw
; Offset: dd
; DCount: db
; Attr: db
%macro Gate 4
dw (%2 & 0FFFFh) ; 偏移 1 (2 字節)
dw %1 ; 選擇子 (2 字節)
dw (%3 & 1Fh) | ((%4 << 8) & 0FF00h) ; 屬性 (2 字節)
dw ((%2 >> 16) & 0FFFFh) ; 偏移 2 (2 字節)
%endmacro ; 共 8 字節
; ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
BaseOfLoader equ 09000h ; LOADER.BIN 被加載到的位置 ---- 段地址
BaseOfLoaderPhyAddr equ BaseOfLoader * 10h ; LOADER.BIN 被加載到的位置 ---- 物理地址 (= BaseOfLoader * 10h)
BaseOfKernelFile equ 08000h ; KERNEL.BIN 被加載到的位置 ---- 段地址
OffsetOfKernelFile equ 0h ; KERNEL.BIN 被加載到的位置 ---- 偏移地址
BaseOfKernelFilePhyAddr equ BaseOfKernelFile * 10h
KernelEntryPointPhyAddr equ 030400h ; 注意:1、必須與 MAKEFILE 中參數 -Ttext 的值相等!!
; 2、這是個地址而非僅僅是個偏移,如果 -Ttext 的值爲 0x400400,則它的值也應該是 0x400400。
PageDirBase equ 200000h ; 頁目錄開始地址: 2M
PageTblBase equ 201000h ; 頁表開始地址: 2M + 4K
;----------------------------------------------------------------------------
; 分頁機制使用的常量說明
;----------------------------------------------------------------------------
PG_P EQU 1 ; 頁存在屬性位
PG_RWR EQU 0 ; R/W 屬性位值, 讀/執行
PG_RWW EQU 2 ; R/W 屬性位值, 讀/寫/執行
PG_USS EQU 0 ; U/S 屬性位值, 系統級
PG_USU EQU 4 ; U/S 屬性位值, 用戶級
;----------------------------------------------------------------------------
; 下面是 FAT12 磁盤的頭, 之所以包含它是因爲下面用到了磁盤的一些信息
; GDT ------------------------------------------------------------------------------------------------------------------------------------------------------------
; 段基址 段界限 , 屬性
LABEL_GDT: Descriptor 0, 0, 0 ; 空描述符
LABEL_DESC_FLAT_C: Descriptor 0, 0fffffh, DA_CR |DA_32|DA_LIMIT_4K ; 0 ~ 4G
LABEL_DESC_FLAT_RW: Descriptor 0, 0fffffh, DA_DRW|DA_32|DA_LIMIT_4K ; 0 ~ 4G
LABEL_DESC_VIDEO_TEXT: Descriptor 0B8000h, 0ffffh, DA_DRW|DA_DPL3 ; 顯存首地址
LABEL_DESC_VIDEO_VGA: Descriptor 0A0000h, 0ffffh, DA_DRW|DA_DPL3 ; 顯存首地址
; GDT ------------------------------------------------------------------------------------------------------------------------------------------------------------
GdtLen equ $ - LABEL_GDT
GdtPtr dw GdtLen - 1 ; 段界限
dd BaseOfLoaderPhyAddr + LABEL_GDT ; 基地址
; GDT 選擇子 ----------------------------------------------------------------------------------
SelectorFlatC equ LABEL_DESC_FLAT_C - LABEL_GDT
SelectorFlatRW equ LABEL_DESC_FLAT_RW - LABEL_GDT
SelectorVideoText equ LABEL_DESC_VIDEO_TEXT - LABEL_GDT + SA_RPL3
SelectorVideoVGA equ LABEL_DESC_VIDEO_VGA - LABEL_GDT + SA_RPL4
; GDT 選擇子 ----------------------------------------------------------------------------------
BaseOfStack equ 0100h
LABEL_START: ; <--- 從這裏開始 *************
mov ax, cs
mov ds, ax
mov es, ax
mov ss, ax
mov sp, BaseOfStack
mov dh, 0 ; "Loading "
call DispStrRealMode ; 顯示字符串
; 得到內存數
mov ebx, 0 ; ebx = 後續值, 開始時需爲 0
mov di, _MemChkBuf ; es:di 指向一個地址範圍描述符結構(Address Range Descriptor Structure)
.MemChkLoop:
mov eax, 0E820h ; eax = 0000E820h
mov ecx, 20 ; ecx = 地址範圍描述符結構的大小
mov edx, 0534D4150h ; edx = 'SMAP'
int 15h ; int 15h
jc .MemChkFail
add di, 20
inc dword [_dwMCRNumber] ; dwMCRNumber = ARDS 的個數
cmp ebx, 0
jne .MemChkLoop
jmp .MemChkOK
.MemChkFail:
mov dword [_dwMCRNumber], 0
.MemChkOK:
; 下面在 A 盤的根目錄尋找 KERNEL.BIN
mov word [wSectorNo], SectorNoOfRootDirectory
xor ah, ah ; ┓
xor dl, dl ; ┣ 軟驅復位
int 13h ; ┛
LABEL_SEARCH_IN_ROOT_DIR_BEGIN:
cmp word [wRootDirSizeForLoop], 0 ; ┓
jz LABEL_NO_KERNELBIN ; ┣ 判斷根目錄區是不是已經讀完, 如果讀完表示沒有找到 KERNEL.BIN
dec word [wRootDirSizeForLoop] ; ┛
mov ax, BaseOfKernelFile
mov es, ax ; es <- BaseOfKernelFile
mov bx, OffsetOfKernelFile ; bx <- OffsetOfKernelFile 於是, es:bx = BaseOfKernelFile:OffsetOfKernelFile = BaseOfKernelFile * 10h + OffsetOfKernelFile
mov ax, [wSectorNo] ; ax <- Root Directory 中的某 Sector 號
mov cl, 1
call ReadSector
mov si, KernelFileName ; ds:si -> "KERNEL BIN"
mov di, OffsetOfKernelFile ; es:di -> BaseOfKernelFile:???? = BaseOfKernelFile*10h+????
cld
mov dx, 10h
LABEL_SEARCH_FOR_KERNELBIN:
cmp dx, 0 ; ┓
jz LABEL_GOTO_NEXT_SECTOR_IN_ROOT_DIR ; ┣ 循環次數控制, 如果已經讀完了一個 Sector, 就跳到下一個 Sector
dec dx ; ┛
mov cx, 11
LABEL_CMP_FILENAME:
cmp cx, 0 ; ┓
jz LABEL_FILENAME_FOUND ; ┣ 循環次數控制, 如果比較了 11 個字符都相等, 表示找到
dec cx ; ┛
lodsb ; ds:si -> al
cmp al, byte [es:di] ; if al == es:di
jz LABEL_GO_ON
jmp LABEL_DIFFERENT
LABEL_GO_ON:
inc di
jmp LABEL_CMP_FILENAME ; 繼續循環
LABEL_DIFFERENT:
and di, 0FFE0h ; else┓ 這時di的值不知道是什麼, di &= e0 爲了讓它是 20h 的倍數
add di, 20h ; ┃
mov si, KernelFileName ; ┣ di += 20h 下一個目錄條目
jmp LABEL_SEARCH_FOR_KERNELBIN; ┛
LABEL_GOTO_NEXT_SECTOR_IN_ROOT_DIR:
add word [wSectorNo], 1
jmp LABEL_SEARCH_IN_ROOT_DIR_BEGIN
LABEL_NO_KERNELBIN:
mov dh, 2 ; "No KERNEL."
call DispStrRealMode ; 顯示字符串
jmp $ ; 沒有找到 KERNEL.BIN, 死循環在這裏
LABEL_FILENAME_FOUND: ; 找到 KERNEL.BIN 後便來到這裏繼續
mov ax, RootDirSectors
and di, 0FFF0h ; di -> 當前條目的開始
push eax
mov eax, [es : di + 01Ch] ; ┓
mov dword [dwKernelSize], eax ; ┛保存 KERNEL.BIN 文件大小
pop eax
add di, 01Ah ; di -> 首 Sector
mov cx, word [es:di]
push cx ; 保存此 Sector 在 FAT 中的序號
add cx, ax
add cx, DeltaSectorNo ; 這時 cl 裏面是 LOADER.BIN 的起始扇區號 (從 0 開始數的序號)
mov ax, BaseOfKernelFile
mov es, ax ; es <- BaseOfKernelFile
mov bx, OffsetOfKernelFile ; bx <- OffsetOfKernelFile 於是, es:bx = BaseOfKernelFile:OffsetOfKernelFile = BaseOfKernelFile * 10h + OffsetOfKernelFile
mov ax, cx ; ax <- Sector 號
LABEL_GOON_LOADING_FILE:
push ax ; ┓
push bx ; ┃
mov ah, 0Eh ; ┃ 每讀一個扇區就在 "Loading " 後面打一個點, 形成這樣的效果:
mov al, '.' ; ┃
mov bl, 0Fh ; ┃ Loading ......
int 10h ; ┃
pop bx ; ┃
pop ax ; ┛
mov cl, 1
call ReadSector
pop ax ; 取出此 Sector 在 FAT 中的序號
call GetFATEntry
cmp ax, 0FFFh
jz LABEL_FILE_LOADED
push ax ; 保存 Sector 在 FAT 中的序號
mov dx, RootDirSectors
add ax, dx
add ax, DeltaSectorNo
add bx, [BPB_BytsPerSec]
jmp LABEL_GOON_LOADING_FILE
LABEL_FILE_LOADED:
call KillMotor ; 關閉軟驅馬達
mov dh, 1 ; "Ready."
call DispStrRealMode ; 顯示字符串
; 下面準備跳入保護模式 -------------------------------------------
; 加載 GDTR
lgdt [GdtPtr]
; 關中斷
cli
; 打開地址線A20===========================================================
; https://blog.csdn.net/longintchar/article/details/79365928
;---------------------方法1----切換速度慢-----------------------------
;CALL waitkbdout
;MOV AL,0xd1
;OUT 0x64,AL
;CALL waitkbdout
;MOV AL,0xdf ; enable A20
;OUT 0x60,AL
;CALL waitkbdout
;waitkbdout方法必須在[bits 32]內
;waitkbdout:
; IN AL,0x64
; AND AL,0x02
; JNZ waitkbdout
; RET
;---------------------方法2----切換速度快-----------------------------
in al, 92h
or al, 00000010b
out 92h, al
; 打開地址線A20===========================================================
; 準備切換到保護模式
mov eax, cr0
or eax, 1
mov cr0, eax
; 真正進入保護模式
jmp dword SelectorFlatC:(BaseOfLoaderPhyAddr+LABEL_PM_START)
;============================================================================
;變量
;----------------------------------------------------------------------------
wRootDirSizeForLoop dw RootDirSectors ; Root Directory 佔用的扇區數
wSectorNo dw 0 ; 要讀取的扇區號
bOdd db 0 ; 奇數還是偶數
dwKernelSize dd 0 ; KERNEL.BIN 文件大小
;============================================================================
;字符串
;----------------------------------------------------------------------------
KernelFileName db "KERNEL BIN", 0 ; KERNEL.BIN 之文件名
; 爲簡化代碼, 下面每個字符串的長度均爲 MessageLength
MessageLength equ 9
LoadMessage: db "Loading "
Message1 db "Ready. "
Message2 db "No KERNEL"
;============================================================================
;----------------------------------------------------------------------------
; 函數名: DispStrRealMode
;----------------------------------------------------------------------------
; 運行環境:
; 實模式(保護模式下顯示字符串由函數 DispStr 完成)
; 作用:
; 顯示一個字符串, 函數開始時 dh 中應該是字符串序號(0-based)
DispStrRealMode:
mov ax, MessageLength
mul dh
add ax, LoadMessage
mov bp, ax ; ┓
mov ax, ds ; ┣ ES:BP = 串地址
mov es, ax ; ┛
mov cx, MessageLength ; CX = 串長度
mov ax, 01301h ; AH = 13, AL = 01h
mov bx, 0007h ; 頁號爲0(BH = 0) 黑底白字(BL = 07h)
mov dl, 0
add dh, 3 ; 從第 3 行往下顯示
int 10h ; int 10h
ret
;----------------------------------------------------------------------------
; 函數名: ReadSector
;----------------------------------------------------------------------------
; 作用:
; 從序號(Directory Entry 中的 Sector 號)爲 ax 的的 Sector 開始, 將 cl 個 Sector 讀入 es:bx 中
ReadSector:
; -----------------------------------------------------------------------
; 怎樣由扇區號求扇區在磁盤中的位置 (扇區號 -> 柱面號, 起始扇區, 磁頭號)
; -----------------------------------------------------------------------
; 設扇區號爲 x
; ┌ 柱面號 = y >> 1
; x ┌ 商 y ┤
; -------------- => ┤ └ 磁頭號 = y & 1
; 每磁道扇區數 │
; └ 餘 z => 起始扇區號 = z + 1
push bp
mov bp, sp
sub esp, 2 ; 闢出兩個字節的堆棧區域保存要讀的扇區數: byte [bp-2]
mov byte [bp-2], cl
push bx ; 保存 bx
mov bl, [BPB_SecPerTrk] ; bl: 除數
div bl ; y 在 al 中, z 在 ah 中
inc ah ; z ++
mov cl, ah ; cl <- 起始扇區號
mov dh, al ; dh <- y
shr al, 1 ; y >> 1 (其實是 y/BPB_NumHeads, 這裏BPB_NumHeads=2)
mov ch, al ; ch <- 柱面號
and dh, 1 ; dh & 1 = 磁頭號
pop bx ; 恢復 bx
; 至此, "柱面號, 起始扇區, 磁頭號" 全部得到 ^^^^^^^^^^^^^^^^^^^^^^^^
mov dl, [BS_DrvNum] ; 驅動器號 (0 表示 A 盤)
.GoOnReading:
mov ah, 2 ; 讀
mov al, byte [bp-2] ; 讀 al 個扇區
int 13h
jc .GoOnReading ; 如果讀取錯誤 CF 會被置爲 1, 這時就不停地讀, 直到正確爲止
add esp, 2
pop bp
ret
;----------------------------------------------------------------------------
; 函數名: GetFATEntry
;----------------------------------------------------------------------------
; 作用:
; 找到序號爲 ax 的 Sector 在 FAT 中的條目, 結果放在 ax 中
; 需要注意的是, 中間需要讀 FAT 的扇區到 es:bx 處, 所以函數一開始保存了 es 和 bx
GetFATEntry:
push es
push bx
push ax
mov ax, BaseOfKernelFile ; ┓
sub ax, 0100h ; ┣ 在 BaseOfKernelFile 後面留出 4K 空間用於存放 FAT
mov es, ax ; ┛
pop ax
mov byte [bOdd], 0
mov bx, 3
mul bx ; dx:ax = ax * 3
mov bx, 2
div bx ; dx:ax / 2 ==> ax <- 商, dx <- 餘數
cmp dx, 0
jz LABEL_EVEN
mov byte [bOdd], 1
LABEL_EVEN:;偶數
xor dx, dx ; 現在 ax 中是 FATEntry 在 FAT 中的偏移量. 下面來計算 FATEntry 在哪個扇區中(FAT佔用不止一個扇區)
mov bx, [BPB_BytsPerSec]
div bx ; dx:ax / BPB_BytsPerSec ==> ax <- 商 (FATEntry 所在的扇區相對於 FAT 來說的扇區號)
; dx <- 餘數 (FATEntry 在扇區內的偏移)。
push dx
mov bx, 0 ; bx <- 0 於是, es:bx = (BaseOfKernelFile - 100):00 = (BaseOfKernelFile - 100) * 10h
add ax, SectorNoOfFAT1 ; 此句執行之後的 ax 就是 FATEntry 所在的扇區號
mov cl, 2
call ReadSector ; 讀取 FATEntry 所在的扇區, 一次讀兩個, 避免在邊界發生錯誤, 因爲一個 FATEntry 可能跨越兩個扇區
pop dx
add bx, dx
mov ax, [es:bx]
cmp byte [bOdd], 1
jnz LABEL_EVEN_2
shr ax, 4
LABEL_EVEN_2:
and ax, 0FFFh
LABEL_GET_FAT_ENRY_OK:
pop bx
pop es
ret
;----------------------------------------------------------------------------
;----------------------------------------------------------------------------
; 函數名: KillMotor
;----------------------------------------------------------------------------
; 作用:
; 關閉軟驅馬達
KillMotor:
push dx
mov dx, 03F2h
mov al, 0
out dx, al
pop dx
ret
;----------------------------------------------------------------------------
; 從此以後的代碼在保護模式下執行 ----------------------------------------------------
; 32 位代碼段. 由實模式跳入 ---------------------------------------------------------
[SECTION .s32]
ALIGN 32
[BITS 32]
LABEL_PM_START:
mov ax, SelectorVideoText
mov gs, ax
mov ax, SelectorFlatRW
mov ds, ax
mov es, ax
mov fs, ax
mov ss, ax
mov esp, TopOfStack
call InitKernel
;jmp $
;***************************************************************
jmp SelectorFlatC:KernelEntryPointPhyAddr ; 正式進入內核 *
; ------------------------------------------------------------------------
; 內存拷貝,仿 memcpy
; ------------------------------------------------------------------------
; void* MemCpy(void* es:pDest, void* ds:pSrc, int iSize);
; ------------------------------------------------------------------------
MemCpy:
push ebp
mov ebp, esp
push esi
push edi
push ecx
mov edi, [ebp + 8] ; Destination
mov esi, [ebp + 12] ; Source
mov ecx, [ebp + 16] ; Counter
.1:
cmp ecx, 0 ; 判斷計數器
jz .2 ; 計數器爲零時跳出
mov al, [ds:esi] ; ┓
inc esi ; ┃
; ┣ 逐字節移動
mov byte [es:edi], al ; ┃
inc edi ; ┛
dec ecx ; 計數器減一
jmp .1 ; 循環
.2:
mov eax, [ebp + 8] ; 返回值
pop ecx
pop edi
pop esi
mov esp, ebp
pop ebp
ret ; 函數結束,返回
; MemCpy 結束-------------------------------------------------------------
; InitKernel ---------------------------------------------------------------------------------
; 將 KERNEL.BIN 的內容經過整理對齊後放到新的位置
; 遍歷每一個 Program Header,根據 Program Header 中的信息來確定把什麼放進內存,放到什麼位置,以及放多少。
; --------------------------------------------------------------------------------------------
InitKernel:
xor esi, esi
mov cx, word [BaseOfKernelFilePhyAddr+2Ch];. ecx <- pELFHdr->e_phnum
movzx ecx, cx ;
mov esi, [BaseOfKernelFilePhyAddr + 1Ch] ; esi <- pELFHdr->e_phoff
add esi, BaseOfKernelFilePhyAddr;esi<-OffsetOfKernel+pELFHdr->e_phoff
.Begin:
mov eax, [esi + 0]
cmp eax, 0 ; PT_NULL
jz .NoAction
push dword [esi + 010h] ;size ;`.
mov eax, [esi + 04h] ; |
add eax, BaseOfKernelFilePhyAddr; | memcpy((void*)(pPHdr->p_vaddr),
push eax ;src ; | uchCode + pPHdr->p_offset,
push dword [esi + 08h] ;dst ; | pPHdr->p_filesz;
call MemCpy ; |
add esp, 12 ;/
.NoAction:
add esi, 020h ; esi += pELFHdr->e_phentsize
dec ecx
jnz .Begin
ret
; InitKernel ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
; SECTION .data1 之開始 ---------------------------------------------------------------------------------------------
[SECTION .data1]
ALIGN 32
LABEL_DATA:
; 實模式下使用這些符號
;; 變量
_dwMCRNumber: dd 0 ; Memory Check Result
_dwDispPos: dd (80 * 6 + 0) * 2 ; 屏幕第 6 行, 第 0 列。
_dwMemSize: dd 0
_ARDStruct: ; Address Range Descriptor Structure
_dwBaseAddrLow: dd 0
_dwBaseAddrHigh: dd 0
_dwLengthLow: dd 0
_dwLengthHigh: dd 0
_dwType: dd 0
_MemChkBuf: times 256 db 0
;
;; 保護模式下使用這些符號
dwDispPos equ BaseOfLoaderPhyAddr + _dwDispPos
dwMemSize equ BaseOfLoaderPhyAddr + _dwMemSize
dwMCRNumber equ BaseOfLoaderPhyAddr + _dwMCRNumber
ARDStruct equ BaseOfLoaderPhyAddr + _ARDStruct
dwBaseAddrLow equ BaseOfLoaderPhyAddr + _dwBaseAddrLow
dwBaseAddrHigh equ BaseOfLoaderPhyAddr + _dwBaseAddrHigh
dwLengthLow equ BaseOfLoaderPhyAddr + _dwLengthLow
dwLengthHigh equ BaseOfLoaderPhyAddr + _dwLengthHigh
dwType equ BaseOfLoaderPhyAddr + _dwType
MemChkBuf equ BaseOfLoaderPhyAddr + _MemChkBuf
; 堆棧就在數據段的末尾
StackSpace: times 1000h db 0
TopOfStack equ BaseOfLoaderPhyAddr + $ ; 棧頂
; SECTION .data1 之結束 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^