轉自：http://home.eeworld.com.cn/my/space-uid-135723-blogid-25548.html
大多數bootloader都分爲stage1和stage2兩部分，u-boot也不例外。依賴於CPU體系結構的代碼（如設備初始化代碼等）通常都放在stage1且可以用彙編語言來實現，而stage2則通常用C語言來實現，這樣可以實現複雜的功能，而且有更好的可讀性和移植性。
1、Stage1 start.S代碼結構
u-boot的stage1代碼通常放在start.S文件中，他用彙編語言寫成，其主要代碼部分如下：
（1）定義入口。由於一個可執行的Image必須有一個入口點，並且只能有一個全局入口，通常這個入口放在ROM（Flash）的0x0地址，因此，必須通知編譯器以使其知道這個入口，該工作可通過修改連接器腳本來完成。
（2）設置異常向量（Exception Vector）。
（3）設置CPU的速度、時鐘頻率及終端控制寄存器。
（4）初始化內存控制器。
（5）將ROM中的程序複製到RAM中。
（6）初始化堆棧。
（7）轉到RAM中執行，該工作可使用指令ldr pc來完成。
2、Stage2 C語言代碼部分
lib_arm/board.c中的start arm boot是C語言開始的函數也是整個啓動代碼中C語言的主函數，同時還是整個u-boot（armboot）的主函數，該函數只要完成如下操作：
（1）調用一系列的初始化函數。
（2）初始化Flash設備。
（3）初始化系統內存分配函數。
（4）如果目標系統擁有NAND設備，則初始化NAND設備。
（5）如果目標系統有顯示設備，則初始化該類設備。
（6）初始化相關網絡設備，填寫IP、MAC地址等。
（7）進去命令循環（即整個boot的工作循環），接受用戶從串口輸入的命令，然後進行相應的工作。
3、U-Boot的啓動順序(示例，其他u-boot版本類似)
cpu/arm920t/start.S
@文件包含處理
#include
@由頂層的mkconfig生成，其中只包含了一個文件：configs/<頂層makefile中6個參數的第1個參數>.h
#include
#include
/*
*************************************************************************
*
* Jump vector table as in table 3.1 in [1]
*
*************************************************************************
*/
注：ARM微處理器支持字節（8位）、半字（16位）、字（32位）3種數據類型
@向量跳轉表，每條佔四個字節（一個字），地址範圍爲0x0000 0000～@0x0000 0020
@ARM體系結構規定在上電覆位後的起始位置，必須有8條連續的跳
@轉指令，通過硬件實現。他們就是異常向量表。ARM在上電覆位後，@是從0x00000000開始啓動的，其實如果bootloader存在，在執行
@下面第一條指令後，就無條件跳轉到start_code，下面一部分並沒@執行。設置異常向量表的作用是識別bootloader。以後系統每當有@異常出現，則CPU會根據異常號，從內存的0x00000000處開始查表@做相應的處理
/******************************************************
;當一個異常出現以後，ARM會自動執行以下幾個步驟:
;1.把下一條指令的地址放到連接寄存器LR(通常是R14).---保存位置
;2.將相應的CPSR(當前程序狀態寄存器)複製到SPSR(備份的程序狀態寄存器)中---保存CPSR
;3.根據異常類型，強制設置CPSR的運行模式位
;4.強制PC(程序計數器)從相關異常向量地址取出下一條指令執行，從而跳轉到相應的異常處理程序中
*********************************************************/
.globl _start /*系統復位位置,整個程序入口*/
@_start是GNU彙編器的默認入口標籤，.globl將_start聲明爲外部程序可訪問的標籤，.globl是GNU彙編的保留關鍵字，前面加點是GNU彙編的語法
_start: b start_code @0x00
@ARM上電後執行的第一條指令，也即復位向量，跳轉到start_code
@reset用b，就是因爲reset在MMU建立前後都有可能發生
@其他的異常只有在MMU建立之後纔會發生
ldr pc, _undefined_instruction /*未定義指令異常,0x04*/
ldr pc, _software_interrupt /*軟中斷異常,0x08*/
ldr pc, _prefetch_abort /*內存操作異常,0x0c*/
ldr pc, _data_abort /*數據異常,0x10*/
ldr pc, _not_used /*未適用,0x14*/
ldr pc, _irq /*慢速中斷異常,0x18*/
ldr pc, _fiq /*快速中斷異常,0x1c*/
@對於ARM數據從內存到CPU之間的移動只能通過L/S指令，如：ldr r0,0x12345678爲把0x12345678內存中的數據寫到r0中，還有一個就是ldr僞指令，如：ldr r0,=0x12345678爲把0x12345678地址寫到r0中，mov只能完成寄存器間數據的移動，而且立即數長度限制在8位
_undefined_instruction: .word undefined_instruction
_software_interrupt: .word software_interrupt
_prefetch_abort: .word prefetch_abort
_data_abort: .word data_abort
_not_used: .word not_used
_irq: .word irq
_fiq: .word fiq
@.word爲GNU ARM彙編特有的僞操作，爲分配一段字內存單元（分配的單元爲字對齊的），可以使用.word把標誌符作爲常量使用。如_fiq:.word fiq即把fiq存入內存變量_fiq中，也即是把fiq放到地址_fiq中。
.balignl 16,0xdeadbeef
@.balignl是.balign的變體
@ .align僞操作用於表示對齊方式：通過添加填充字節使當前位置
@滿足一定的對齊方式。.balign的作用同.align。
@ .align {alignment} {,fill} {,max}
@ 其中：alignment用於指定對齊方式，可能的取值爲2的次
@冪，缺省爲4。fill是填充內容，缺省用0填充。max是填充字節@數最大值，如果填充字節數超過max, 就不進行對齊,例如：
@ .align 4 /* 指定對齊方式爲字對齊 */
【參考好野人的窩，於關u-boot中的.balignl 16,0xdeadbeef的理解http://haoyeren.blog.sohu.com/84511571.html】
/*
*************************************************************************
*
* Startup Code (called from the ARM reset exception vector)
*
* do important init only if we don't start from memory!
* relocate armboot to ram
* setup stack
* jump to second stage
*
*************************************************************************
@保存變量的數據區,保存一些全局變量,用於BOOT程序從FLASH拷貝@到RAM,或者其它的使用。
@還有一些變量的長度是通過連接腳本里得到,實際上由編譯器算出
@來的
_TEXT_BASE:
@因爲linux開始地址是0x30000000,我這裏是64M SDRAM,所以@TEXT_BASE = 0x33F80000 ？？？
.word TEXT_BASE /*uboot映像在SDRAM中的重定位地址*/
@TEXT_BASE在開發板相關的目錄中的config.mk文檔中定義, 他定
@義了代碼在運行時所在的地址, 那麼_TEXT_BASE中保存了這個地
@址（這個TEXT_BASE怎麼來的還不清楚）
.globl _armboot_start
_armboot_start:
.word _start
@用_start來初始化_armboot_start。（爲什麼要這麼定義一下還不明白）
/*
* These are defined in the board-specific linker script.
*/
@下面這些是定義在開發板目錄鏈接腳本中的
.globl _bss_start
_bss_start:
.word __bss_start
@__bss_start定義在和開發板相關的u-boot.lds中，_bss_start保存的是__bss_start標號所在的地址。
.globl _bss_end
_bss_end:
.word _end
@同上，這樣賦值是因爲代碼所在地址非編譯時的地址，直接取得該標號對應地址。
@中斷的堆棧設置
#ifdef CONFIG_USE_IRQ
/* IRQ stack memory (calculated at run-time) */
.globl IRQ_STACK_START
IRQ_STACK_START:
.word 0x0badc0de
/* IRQ stack memory (calculated at run-time) */
.globl FIQ_STACK_START
FIQ_STACK_START:
.word 0x0badc0de
#endif
/*
* the actual start code
*/
@復位後執行程序
@真正的初始化從這裏開始了。其實在CPU一上電以後就是跳到這裏執行的
reset:
/*
* set the cpu to SVC32 mode
*/
@更改處理器模式爲管理模式
@對狀態寄存器的修改要按照：讀出-修改-寫回的順序來執行
@
31 30 29 28 --- 7 6 - 4 3 2 1 0
N Z C V I F M4 M3 M2 M1 M0
0 0 0 0 0 User26 模式
0 0 0 0 1 FIQ26 模式
0 0 0 1 0 IRQ26 模式
0 0 0 1 1 SVC26 模式
1 0 0 0 0 User 模式
1 0 0 0 1 FIQ 模式
1 0 0 1 0 IRQ 模式
1 0 0 1 1 SVC 模式
1 0 1 1 1 ABT 模式
1 1 0 1 1 UND 模式
1 1 1 1 1 SYS 模式
mrs r0,cpsr
@將cpsr的值讀到r0中
bic r0,r0,#0x1f
@清除M0~M4
orr r0,r0,#0xd3
@禁止IRQ,FIQ中斷，並將處理器置於管理模式
msr cpsr,r0
@以下是點燈了，這裏應該會牽涉到硬件設置，移植的時候應該可以不要
bl coloured_LED_init
bl red_LED_on
@針對AT91RM9200進行特殊處理
#if defined(CONFIG_AT91RM9200DK) || defined(CONFIG_AT91RM9200EK)
/*
* relocate exception table
*/
ldr r0, =_start
ldr r1, =0x0
mov r2, #16
copyex:
subs r2, r2, #1
@sub帶上了s用來更改進位標誌，對於sub來說，若發生借位則C標誌置0，沒有則爲1，這跟adds指令相反！要注意。
ldr r3, [r0], #4
str r3, [r1], #4
bne copyex
#endif
@針對S3C2400和S3C2410進行特殊處理
@CONFIG_S3C2400、CONFIG_S3C2410等定義在include/configs/下不同開發板的頭文件中
#if defined(CONFIG_S3C2400) || defined(CONFIG_S3C2410)
/* turn off the watchdog */
@關閉看門狗定時器的自動復位功能並屏蔽所有中斷，上電後看門狗爲開，中斷爲關
# if defined(CONFIG_S3C2400)
# define pWTCON 0x15300000
# define INTMSK 0x14400008 /* Interupt-Controller base addresses */
# define CLKDIVN 0x14800014 /* clock divisor register */
#else @s3c2410的配置
# define pWTCON 0x53000000
@pWTCON定義爲看門狗控制寄存器的地址（s3c2410和s3c2440相同）
# define INTMSK 0x4A000008 /* Interupt-Controller base addresses */
@INTMSK定義爲主中斷屏蔽寄存器的地址（s3c2410和s3c2440相同）
# define INTSUBMSK 0x4A00001C
@INTSUBMSK定義爲副中斷屏蔽寄存器的地址（s3c2410和s3c2440相同）
# define CLKDIVN 0x4C000014 /* clock divisor register */
@CLKDIVN定義爲時鐘分頻控制寄存器的地址（s3c2410和s3c2440相同）
# endif
@至此寄存器地址設置完畢
ldr r0, =pWTCON
mov r1, #0x0
str r1, [r0]
@對於S3C2440和S3C2410的WTCON寄存器的[0]控制允許或禁止看門狗定時器的復位輸出功能，設置爲“0”禁止復位功能。
/*
* mask all IRQs by setting all bits in the INTMR - default
*/
mov r1, #0xffffffff
ldr r0, =INTMSK
str r1, [r0]
# if defined(CONFIG_S3C2410)
ldr r1, =0x3ff @2410好像應該爲7ff纔對（不理解uboot爲何是這個數字）
ldr r0, =INTSUBMSK
str r1, [r0]
# endif
@對於S3C2410的INTMSK寄存器的32位和INTSUBMSK寄存器的低11位每一位對應一箇中斷，相應位置“1”爲不響應相應的中斷。對於S3C2440的INTSUBMSK有15位可用，所以應該爲0x7fff了。
/* FCLK:HCLK:PCLK = 1:2:4 */
/* default FCLK is 120 MHz ! */
ldr r0, =CLKDIVN
mov r1, #3
str r1, [r0]
@時鐘分頻設置，FCLK爲核心提供時鐘，HCLK爲AHB（ARM920T,內存@控制器，中斷控制器，LCD控制器，DMA和主USB模塊）提供時鐘，@PCLK爲APB（看門狗、IIS、I2C、PWM、MMC、ADC、UART、GPIO、@RTC、SPI）提供時鐘。分頻數一般選擇1：4：8，所以HDIVN=2,PDIVN=1，@CLKDIVN=5，這裏僅僅是配置了分頻寄存器，關於MPLLCON的配置肯@定寫在lowlevel_init.S中了
@歸納出CLKDIVN的值跟分頻的關係：
@0x0 = 1:1:1 , 0x1 = 1:1:2 , 0x2 = 1:2:2 , 0x3 = 1:2:4, 0x4 = 1:4:4, 0x5 = 1:4:8, 0x6 = 1:3:3,
0x7 = 1:3:6
@S3C2440的輸出時鐘計算式爲:Mpll=(2*m*Fin)/(p*2^s)
S3C2410的輸出時鐘計算式爲:Mpll=(m*Fin)/(p*2^s)
m=M(the value for divider M)+8;p=P(the value for divider P)+2
M,P,S的選擇根據datasheet中PLL VALUE SELECTION TABLE表格進行，
我的開發板晶振爲16.9344M，所以輸出頻率選爲：399.65M的話M=0x6e,P=3,S=1
@s3c2440增加了攝像頭,其FCLK、HCLK、PCLK的分頻數還受到CAMDIVN[9]（默認爲0）,CAMDIVN[8]（默認爲0）的影響
#endif /* CONFIG_S3C2400 || CONFIG_S3C2410 */
/*
* we do sys-critical inits only at reboot,
* not when booting from ram!
*/
@選擇是否初始化CPU
#ifndef CONFIG_SKIP_LOWLEVEL_INIT
bl cpu_init_crit
@執行CPU初始化，BL完成跳轉的同時會把後面緊跟的一條指令地址保存到連接寄存器LR（R14）中。以使子程序執行完後正常返回。
#endif
@調試階段的代碼是直接在RAM中運行的，而最後需要把這些代碼 @固化到Flash中，因此U-Boot需要自己從Flash轉移到
@RAM中運行，這也是重定向的目的所在。
@通過adr指令得到當前代碼的地址信息：如果U-boot是從RAM @開始運行，則從adr,r0,_start得到的地址信息爲
@r0=_start=_TEXT_BASE=TEXT_BASE=0x33F80000; @如果U-boot從Flash開始運行，即從處理器對應的地址運行，
@則r0=0x0000,這時將會執行copy_loop標識的那段代碼了。
@ _TEXT_BASE 定義在board/smdk2410/config.mk中
#ifndef CONFIG_SKIP_RELOCATE_UBOOT
relocate: /* relocate U-Boot to RAM */
adr r0, _start /* r0 <- current position of code */
ldr r1, _TEXT_BASE /* test if we run from flash or RAM */
cmp r0, r1 /* don't reloc during debug */
beq stack_setup
ldr r2, _armboot_start
@_armboot_start爲_start地址
ldr r3, _bss_start
@_bss_start爲數據段地址
sub r2, r3, r2 /* r2 <- size of armboot */
add r2, r0, r2 /* r2 <- source end address */
copy_loop:
ldmia r0!, {r3-r10} /* copy from source address [r0] */
@從源地址[r0]讀取8個字節到寄存器,每讀一個就更新一次r0地址
@ldmia:r0安字節增長
stmia r1!, {r3-r10} /* copy to target address [r1] */
@LDM(STM)用於在寄存器所指的一片連續存儲器和寄存器列表的寄存@器間進行數據移動，或是進行壓棧和出棧操作。
@格式爲：LDM(STM){條件}{類型}基址寄存器{！}，寄存器列表{^}
@對於類型有以下幾種情況： IA 每次傳送後地址加1，用於移動數
@據塊
IB 每次傳送前地址加1，用於移動數據塊
DA 每次傳送後地址減1，用於移動數據塊
DB 每次傳送前地址減1，用於移動數據塊
FD 滿遞減堆棧，用於操作堆棧（即先移動指針再操作數據，相當於DB）
ED 空遞減堆棧，用於操作堆棧（即先操作數據再移動指針，相當於DA）
FA 滿遞增堆棧，用於操作堆棧（即先移動指針再操作數據，相當於IB）
EA 空遞增堆棧，用於操作堆棧（即先操作數據再移動指針，相當於IA）
（這裏是不是應該要涉及到NAND或者NOR的讀寫？沒有看出來）
cmp r0, r2 /* until source end addreee [r2] */
ble copy_loop
#endif /* CONFIG_SKIP_RELOCATE_UBOOT */
/* Set up the stack */
@初始化堆棧
stack_setup:
ldr r0, _TEXT_BASE /* upper 128 KiB: relocated uboot */
@獲取分配區域起始指針，
sub r0, r0, #CONFIG_SYS_MALLOC_LEN /* malloc area */
@CFG_MALLOC_LEN=128*1024+CFG_ENV_SIZE=128*1024+0x1@0000=192K
sub r0, r0, #CONFIG_SYS_GBL_DATA_SIZE /* bdinfo */
@CFG_GBL_DATA_SIZE 128---size in bytes reserved for initial data 用來存儲開發板信息
#ifdef CONFIG_USE_IRQ
@這裏如果需要使用IRQ, 還有給IRQ保留堆棧空間, 一般不使用.
sub r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
#endif
sub sp, r0, #12 /* leave 3 words for abort-stack */
@該部分將未初始化數據段_bss_start----_bss_end中的數據 @清零
clear_bss:
ldr r0, _bss_start /* find start of bss segment */
ldr r1, _bss_end /* stop here */
mov r2, #0x00000000 /* clear */
clbss_l:str r2, [r0] /* clear loop... */
add r0, r0, #4
cmp r0, r1
ble clbss_l
@跳到階段二C語言中去
ldr pc, _start_armboot
_start_armboot: .word start_armboot
@start_armboot在/lib_arm/中，到這裏因該是第一階段已經完成了吧，下面就要去C語言中執行第二階段了吧
/*
*************************************************************************
*
* CPU_init_critical registers
*
* setup important registers
* setup memory timing
*
*************************************************************************
*/
@CPU初始化
@在“relocate: /* relocate U-Boot to RAM */ ”之前被調用
#ifndef CONFIG_SKIP_LOWLEVEL_INIT
cpu_init_crit:
/*
* flush v4 I/D caches
*/
@初始化CACHES
mov r0, #0
mcr p15, 0, r0, c7, c7, 0 /* flush v3/v4 cache */
mcr p15, 0, r0, c8, c7, 0 /* flush v4 TLB */
/*
* disable MMU stuff and caches
*/
@關閉MMU和CACHES
mrc p15, 0, r0, c1, c0, 0
bic r0, r0, #0x00002300 @ clear bits 13, 9:8 (--V- --RS)
bic r0, r0, #0x00000087 @ clear bits 7, 2:0 (B--- -CAM)
orr r0, r0, #0x00000002 @ set bit 2 (A) Align
orr r0, r0, #0x00001000 @ set bit 12 (I) I-Cache
mcr p15, 0, r0, c1, c0, 0
@對協處理器的操作還是看不懂，暫時先不管吧，有時間研究一下ARM技術手冊的協處理器部分。
/*
* before relocating, we have to setup RAM timing
* because memory timing is board-dependend, you will
* find a lowlevel_init.S in your board directory.
*/
@初始化RAM時鐘，因爲內存是跟開發板密切相關的，所以這部分在/開發板目錄/lowlevel_init.S中實現
mov ip, lr
@保存LR,以便正常返回,注意前面是通過BL跳到cpu_init_crit來的。
@（ARM9有37個寄存器，ARM7有27個）
37個寄存器=7個未分組寄存器（R0～R7）+ 2×（5個分組寄存器R8～R12）+6×2（R13=SP，R14=lr 分組寄存器） + 1(R15=PC) +1(CPSR) + 5(SPSR)
用途和訪問權限：
R0～R7:USR(用戶模式)、fiq（快速中斷模式）、irq（中斷模式）、svc（超級用法模式）、abt、und
R8～R12：R8_usr～R12_usr（usr，irq，svc，abt，und）
R8_fiq～R12_fiq（fiq）
R11=fp
R12=IP(從反彙編上看，fp和ip一般用於存放SP的值)
R13～R14：R13_usr R14_usr(每種模式都有自己的寄存器)
SP ～lr ：R13_fiq R14_fiq
R13_irq R14_irq
R13_svc R14_svc
R13_abt R14_abt
R13_und R14_und
R15(PC)：都可以訪問（即PC的值爲當前指令的地址值加8個字節）
R16 ：（(Current Program Status Register，當前程序狀態寄存器)）
SPSR _fiq,SPSR_irq,SPSR_abt,SPSR_und(USR模式沒有)
#if defined(CONFIG_AT91RM9200EK)
#else
bl lowlevel_init
@在重定向代碼之前，必須初始化內存時序，因爲重定向時需要將@flash中的代碼複製到內存中lowlevel_init在@/board/smdk2410/lowlevel_init.S中。
#endif
mov lr, ip
mov pc, lr
@返回到主程序
#endif /* CONFIG_SKIP_LOWLEVEL_INIT */
/*
*************************************************************************
*
* Interrupt handling
*
*************************************************************************
*/
@這段沒有看明白，不過好像跟移植關係不是很大，先放一放。
@
@ IRQ stack frame.
@
#define S_FRAME_SIZE 72
#define S_OLD_R0 68
#define S_PSR 64
#define S_PC 60
#define S_LR 56
#define S_SP 52
#define S_IP 48
#define S_FP 44
#define S_R10 40
#define S_R9 36
#define S_R8 32
#define S_R7 28
#define S_R6 24
#define S_R5 20
#define S_R4 16
#define S_R3 12
#define S_R2 8
#define S_R1 4
#define S_R0 0
#define MODE_SVC 0x13
#define I_BIT 0x80
/*
* use bad_save_user_regs for abort/prefetch/undef/swi ...
* use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
*/
.macro bad_save_user_regs
sub sp, sp, #S_FRAME_SIZE
stmia sp, {r0 - r12} @ Calling r0-r12
ldr r2, _armboot_start
sub r2, r2, #(CONFIG_STACKSIZE)
sub r2, r2, #(CONFIG_SYS_MALLOC_LEN)
sub r2, r2, #(CONFIG_SYS_GBL_DATA_SIZE+8) @ set base 2 words into abort stack
ldmia r2, {r2 - r3} @ get pc, cpsr
add r0, sp, #S_FRAME_SIZE @ restore sp_SVC
add r5, sp, #S_SP
mov r1, lr
stmia r5, {r0 - r3} @ save sp_SVC, lr_SVC, pc, cpsr
mov r0, sp
.endm
.macro irq_save_user_regs
sub sp, sp, #S_FRAME_SIZE
stmia sp, {r0 - r12} @ Calling r0-r12
add r7, sp, #S_PC
stmdb r7, {sp, lr}^ @ Calling SP, LR
str lr, [r7, #0] @ Save calling PC
mrs r6, spsr
str r6, [r7, #4] @ Save CPSR
str r0, [r7, #8] @ Save OLD_R0
mov r0, sp
.endm
.macro irq_restore_user_regs
ldmia sp, {r0 - lr}^ @ Calling r0 - lr
mov r0, r0
ldr lr, [sp, #S_PC] @ Get PC
add sp, sp, #S_FRAME_SIZE
subs pc, lr, #4 @ return & move spsr_svc into cpsr
.endm
.macro get_bad_stack
ldr r13, _armboot_start @ setup our mode stack
sub r13, r13, #(CONFIG_STACKSIZE)
sub r13, r13, #(CONFIG_SYS_MALLOC_LEN)
sub r13, r13, #(CONFIG_SYS_GBL_DATA_SIZE+8) @ reserved a couple spots in abort stack
str lr, [r13] @ save caller lr / spsr
mrs lr, spsr
str lr, [r13, #4]
mov r13, #MODE_SVC @ prepare SVC-Mode
@ msr spsr_c, r13
msr spsr, r13
mov lr, pc
movs pc, lr
.endm
.macro get_irq_stack @ setup IRQ stack
ldr sp, IRQ_STACK_START
.endm
.macro get_fiq_stack @ setup FIQ stack
ldr sp, FIQ_STACK_START
.endm
/*********************************************************
* exception handlers
********************************************************/
@異常向量處理
@每一個異常向量處其實只放了一條跳轉指令（因爲每個異常向量只 @有4個字節不能放太多的程序），跳到相應的異常處理程序中。
.align 5
undefined_instruction:
get_bad_stack
bad_save_user_regs
bl do_undefined_instruction
.align 5
software_interrupt:
get_bad_stack
bad_save_user_regs
bl do_software_interrupt
.align 5
prefetch_abort:
get_bad_stack
bad_save_user_regs
bl do_prefetch_abort
.align 5
data_abort:
get_bad_stack
bad_save_user_regs
bl do_data_abort
.align 5
not_used:
get_bad_stack
bad_save_user_regs
bl do_not_used
#ifdef CONFIG_USE_IRQ
.align 5
irq:
get_irq_stack
irq_save_user_regs
bl do_irq
irq_restore_user_regs
.align 5
fiq:
get_fiq_stack
/* someone ought to write a more effiction fiq_save_user_regs */
irq_save_user_regs
bl do_fiq
irq_restore_user_regs
#else
.align 5
irq:
get_bad_stack
bad_save_user_regs
bl do_irq
.align 5
fiq:
get_bad_stack
bad_save_user_regs
bl do_fiq
#endif /*CONFIG_USE_IRQ*/
@可知start.S的流程爲：異常向量——上電覆位後進入復位異常向量——跳到啓動代碼處——設置處理器進入管理模式——關閉看門狗——關閉中斷——設置時鐘分頻——關閉MMU和CACHE——進入lowlever_init.S——檢查當前代碼所處的位置，如果在FLASH中就將代碼搬移到RAM中
-----------------------------------------------------分割線---------------------------------------------------
s = getenv ("bootcmd");
debug ("### main_loop: bootcmd=\"%s\"\n", s ? s : "");
if (bootdelay >= 0 && s && !abortboot (bootdelay))
{
run_command (s, 0);
}
2.假設bootcmd = nand read.jffs2 0x30007FC0 kernel; bootm 0x30007FC0
<1> nand read.jffs2 0x30007FC0 kernel
nand read.jffs2 0x30007FC0 kernel;
從nand讀出內核：從哪裏讀？ 從kernel分區
放到哪裏去？-0x30007FC0
下面講解什麼是分區：
就是將nand劃分爲幾個區域，一般如下：
bootloader-》params-》kernel-》root
這些分區的劃分是在/include/configs/mini2440.h中寫死的：
#define MTDPARTS_DEFAULT "mtdparts=nandflash0:250k@0(bootloader)," \
"128k(params)," \
"5m(kernel)," \
"-(root)"
注:@0表示從0地址開始，250k的bootloader分區可能對某些uboot不夠用，這裏只是舉例而已。
將上面的信息換算成十六進制：
# name 大小 在nand上的起始地址
0 bootloader 0x00040000 0x00000000
1 params 0x00020000 0x00040000
2 kernel 0x00200000 0x00060000
3 root 0xfda00000 0x00260000
那麼上面的nand read.jffs2 0x30007FC0 kernel就等價於：
nand read.jffs2 0x30007FC0 0x00060000 0x00200000
注：這裏的read.jffs2並不是指定要什麼特定的格式，而是用read.jffs2不需要塊/頁對齊,所以這個kernel的分區大小可以
隨意定。
<2> bootm 0x30007FC0
關鍵函數do_bootm()
flash上存的內核：uImage
uImage = 頭部+真正的內核
頭部的定義如下：
typedef struct image_header {
uint32_t ih_magic; /* Image Header Magic Number */
uint32_t ih_hcrc; /* Image Header CRC Checksum */
uint32_t ih_time; /* Image Creation Timestamp */
uint32_t ih_size; /* Image Data Size */
uint32_t ih_load; /* Data Load Address */
uint32_t ih_ep; /* Entry Point Address */
uint32_t ih_dcrc; /* Image Data CRC Checksum */
uint8_t ih_os; /* Operating System */
uint8_t ih_arch; /* CPU architecture */
uint8_t ih_type; /* Image Type */
uint8_t ih_comp; /* Compression Type */
uint8_t ih_name[IH_NMLEN]; /* Image Name */
} image_header_t;
我們需要關心的是：
uint32_t ih_load; /* Data Load Address */
uint32_t ih_ep; /* Entry Point Address */
ih_load是加載地址，即內核運行是應該位於的地方
ih_ep是入口地址，即內核的入口地址
這與uboot是類似的，uboot的加載地址是TEXT_BASE = 0x33F80000；入口地址是start.S中的_start。
其實我們把內核中nand讀出來的時候是可以放在內核的任何地方的，如0x31000000，0x32000000等等，只要它不破壞uboot所佔用的內存空間就可以了，如下圖：
從0x33F4DF74-0x30000000都是可以用的。
那麼爲什麼既然設定好了加載地址和入口地址內核還能隨意放呢？
那是因爲uImage有一個頭部！頭部裏有加載地址和入口地址，當我們用bootm xxx的時候，
do_bootm這個函數會先去讀uImage的頭部以獲取該uImage的加載地址和入口地址，當發現該uImage目前所處的內存地址不等於它的加載地址時，該函數會將該uImage移動到它的加載地址上，在代碼中體現如下：
case IH_COMP_NONE:：
if (load != image_start)
{
memmove_wd ((void *)load, (void *)image_start, image_len, CHUNKSZ);
}
另外，當我們的內核正好處於頭部指定的加載地址的話，那麼就不用uboot的do_bootm函數來幫我們搬運內核了，這樣可以節省啓動時間。這就是爲什麼我們一般都下載uImage到
0x30007FC0的原因了！
我們所用的內核加載地址是0x30008000，而頭部的大小爲64個字節，所以將內核拷貝到0x30007FC0時，再加載頭部的64個字節，內核正好位於0x30008000處！
現在總結bootm做了什麼：
1. 讀取頭部
2. 將內核移動到加載地址
3. 啓動內核
具體如何啓動內核？
使用do_bootm_linux()，在/lib_arm/bootm.c定義，因爲我們已經知道入口地址了，所以只需跳到入口地址就可以啓動linux內核了，但是在這之前需要做一件事————uboot傳遞參數給內核！！
現在來分析do_bootm_linux()這個函數：
theKernel = (void (*)(int, int, uint))images->ep;//先是將入口地址賦值給theKernel
theKernel (0, machid, bd->bi_boot_params);//然後是調用thekernel
函數，以0，machid，bd->bi_boot_params作爲參數
下面分析這三個參數：
1.machid就是uboot裏設置好的板子的機器碼，mini2440的是MACH_TYPE_MINI2440 (1999),內核所設置的機器碼和uboot所設置的機器碼必須一致才能啓動內核
2.bd->bi_boot_parmas就是uboot需傳遞給內核的啓動參數所位於的地址
3.0暫時還不知道什麼作用/**********************************************/
那麼uboot傳給內核的啓動參數是在哪裏設置的呢？
其實就是在調用 theKernel (0, machid, bd->bi_boot_params);前面的一小段代碼裏設置的，下面我截取了部分片段：
setup_start_tag (bd);
setup_revision_tag (¶ms);
setup_memory_tags (bd);
setup_commandline_tag (bd, commandline);
setup_initrd_tag (bd, images->rd_start, images->rd_end);
setup_videolfb_tag ((gd_t *) gd);
setup_end_tag (bd);
每一個啓動參數對應一個tag結構體，所謂的設置傳遞參數其實就是初始化這些tag的值，想了解這個結構體以及這些tag的值是如何設置的請看韋東山的書關於uboot移植章節！
下面我們看一下setup_start_tag(bd)這個函數先：
static void setup_start_tag (bd_t *bd)
{
params = (struct tag *) bd->bi_boot_params;
//在board.c中有一句gd->bd->bi_boot_params = 0x30000100，這裏設置了參數存放的位置
params->hdr.tag = ATAG_CORE;
params->hdr.size = tag_size (tag_core);
params->u.core.flags = 0;
params->u.core.pagesize = 0;
params->u.core.rootdev = 0;
params = tag_next (params);
}
我們再來看下setup_commandline_tag (bd, commandline);這個函數：
static void setup_commandline_tag (bd_t *bd, char *commandline)
{
// commandline就是我們的bootargs
char *p;
if (!commandline)
return;
for (p = commandline; *p == ' '; p++);
if (*p == '\0')
return;
params->hdr.tag = ATAG_CMDLINE;
params->hdr.size =
(sizeof (struct tag_header) + strlen (p) + 1 + 4) >> 2;
strcpy (params->u.cmdline.cmdline, p);
params = tag_next (params);
}
Linux內核啓動時就會去讀取這些tag參數