利用PowerDesigner逆向生成數據庫設計文檔（Excel）

原創 逗.你玩 2020-06-14 20:32

首先PowerDesigner->File->Reverse Engineer->Database
在這裏插入圖片描述
選擇相應的數據庫類型，比如MySQL 5.0在這裏插入圖片描述
選擇數據庫連接或者新建一個數據庫連接
在這裏插入圖片描述
選擇目標數據表，然後一直OK在這裏插入圖片描述
接下來就是等待，生成完成。
在這裏插入圖片描述
以上準備工作完成後，接下來就是執行腳本的事情了
選中Tables,然後Tools->Execute Commands->Edit/Run script
在這裏插入圖片描述
運行腳本一（所有表存放在同一個sheet裏）

'******************************************************************************
Option Explicit
   Dim rowsNum
   rowsNum = 0
'-----------------------------------------------------------------------------
' Main function
'-----------------------------------------------------------------------------
' Get the current active model
    Dim Model
    Set Model = ActiveModel
    If (Model Is Nothing) Or (Not Model.IsKindOf(PdPDM.cls_Model)) Then
       MsgBox "The current model is not an PDM model."
    Else
      ' Get the tables collection
      '創建EXCEL APP
      dim beginrow
      DIM EXCEL, SHEET, SHEETLIST
      set EXCEL = CREATEOBJECT("Excel.Application")
      EXCEL.workbooks.add(-4167)'添加工作表
      EXCEL.workbooks(1).sheets(1).name ="表結構"
      set SHEET = EXCEL.workbooks(1).sheets("表結構")
      
      EXCEL.workbooks(1).sheets.add
      EXCEL.workbooks(1).sheets(1).name ="目錄"
      set SHEETLIST = EXCEL.workbooks(1).sheets("目錄")
      ShowTableList Model,SHEETLIST

      ShowProperties Model, SHEET,SHEETLIST
      
      
      EXCEL.workbooks(1).Sheets(2).Select
      EXCEL.visible = true
      '設置列寬和自動換行
      sheet.Columns(1).ColumnWidth = 20 
      sheet.Columns(2).ColumnWidth = 20 
      sheet.Columns(3).ColumnWidth = 20 
      sheet.Columns(4).ColumnWidth = 40 
      sheet.Columns(5).ColumnWidth = 10 
      sheet.Columns(6).ColumnWidth = 10 
      sheet.Columns(1).WrapText =true
      sheet.Columns(2).WrapText =true
      sheet.Columns(4).WrapText =true
      '不顯示網格線
      EXCEL.ActiveWindow.DisplayGridlines = False
      
      
 End If
'-----------------------------------------------------------------------------
' Show properties of tables
'-----------------------------------------------------------------------------
Sub ShowProperties(mdl, sheet,SheetList)
   ' Show tables of the current model/package
   rowsNum=0
   beginrow = rowsNum+1
   Dim rowIndex 
   rowIndex=3
   ' For each table
   output "begin"
   Dim tab
   For Each tab In mdl.tables
      ShowTable tab,sheet,rowIndex,sheetList
      rowIndex = rowIndex +1
   Next
   if mdl.tables.count > 0 then
        sheet.Range("A" & beginrow + 1 & ":A" & rowsNum).Rows.Group
   end if
   output "end"
End Sub
'-----------------------------------------------------------------------------
' Show table properties
'-----------------------------------------------------------------------------
Sub ShowTable(tab, sheet,rowIndex,sheetList)
   If IsObject(tab) Then
     Dim rangFlag
     rowsNum = rowsNum + 1
      ' Show properties
      Output "================================"
      sheet.cells(rowsNum, 1) =tab.name
      sheet.cells(rowsNum, 1).HorizontalAlignment=3
      sheet.cells(rowsNum, 2) = tab.code
      'sheet.cells(rowsNum, 5).HorizontalAlignment=3
      'sheet.cells(rowsNum, 6) = ""
      'sheet.cells(rowsNum, 7) = "表說明"
      sheet.cells(rowsNum, 3) = tab.comment
      'sheet.cells(rowsNum, 8).HorizontalAlignment=3
      sheet.Range(sheet.cells(rowsNum, 3),sheet.cells(rowsNum, 7)).Merge
      '設置超鏈接，從目錄點擊表名去查看錶結構
      '字段中文名    字段英文名    字段類型    註釋    是否主鍵    是否非空    默認值
      sheetList.Hyperlinks.Add sheetList.cells(rowIndex,2), "","表結構"&"!B"&rowsNum
      rowsNum = rowsNum + 1
      sheet.cells(rowsNum, 1) = "字段中文名"
      sheet.cells(rowsNum, 2) = "字段英文名"
      sheet.cells(rowsNum, 3) = "字段類型"
      sheet.cells(rowsNum, 4) = "註釋"
      sheet.cells(rowsNum, 5) = "是否主鍵"
      sheet.cells(rowsNum, 6) = "是否非空"
      sheet.cells(rowsNum, 7) = "默認值"
      '設置邊框
      sheet.Range(sheet.cells(rowsNum-1, 1),sheet.cells(rowsNum, 7)).Borders.LineStyle = "1"
      'sheet.Range(sheet.cells(rowsNum-1, 4),sheet.cells(rowsNum, 9)).Borders.LineStyle = "1"
      '字體爲10號
      sheet.Range(sheet.cells(rowsNum-1, 1),sheet.cells(rowsNum, 7)).Font.Size=10
            Dim col ' running column
            Dim colsNum
            colsNum = 0
      for each col in tab.columns
        rowsNum = rowsNum + 1
        colsNum = colsNum + 1
          sheet.cells(rowsNum, 1) = col.name
        'sheet.cells(rowsNum, 3) = ""
          'sheet.cells(rowsNum, 4) = col.name
          sheet.cells(rowsNum, 2) = col.code
          sheet.cells(rowsNum, 3) = col.datatype
        sheet.cells(rowsNum, 4) = col.comment
          If col.Primary = true Then
        sheet.cells(rowsNum, 5) = "Y" 
        Else
        sheet.cells(rowsNum, 5) = " " 
        End If
        If col.Mandatory = true Then
        sheet.cells(rowsNum, 6) = "Y" 
        Else
        sheet.cells(rowsNum, 6) = " " 
        End If
        sheet.cells(rowsNum, 7) =  col.defaultvalue
      next
      sheet.Range(sheet.cells(rowsNum-colsNum+1,1),sheet.cells(rowsNum,7)).Borders.LineStyle = "3"       
      'sheet.Range(sheet.cells(rowsNum-colsNum+1,4),sheet.cells(rowsNum,9)).Borders.LineStyle = "3"
      sheet.Range(sheet.cells(rowsNum-colsNum+1,1),sheet.cells(rowsNum,7)).Font.Size = 10
      rowsNum = rowsNum + 2
      
      Output "FullDescription: "       + tab.Name
   End If
   
End Sub
'-----------------------------------------------------------------------------
' Show List Of Table
'-----------------------------------------------------------------------------
Sub ShowTableList(mdl, SheetList)
   ' Show tables of the current model/package
   Dim rowsNo
   rowsNo=1
   ' For each table
   output "begin"
   SheetList.cells(rowsNo, 1) = "主題"
   SheetList.cells(rowsNo, 2) = "表中文名"
   SheetList.cells(rowsNo, 3) = "表英文名"
   SheetList.cells(rowsNo, 4) = "表說明"
   rowsNo = rowsNo + 1
   SheetList.cells(rowsNo, 1) = mdl.name
   Dim tab
   For Each tab In mdl.tables
     If IsObject(tab) Then
         rowsNo = rowsNo + 1
      SheetList.cells(rowsNo, 1) = ""
      SheetList.cells(rowsNo, 2) = tab.name
      SheetList.cells(rowsNo, 3) = tab.code
      SheetList.cells(rowsNo, 4) = tab.comment
     End If
   Next
    SheetList.Columns(1).ColumnWidth = 20 
      SheetList.Columns(2).ColumnWidth = 20 
      SheetList.Columns(3).ColumnWidth = 30 
     SheetList.Columns(4).ColumnWidth = 60 
   output "end"
End Sub

腳本二（一張表對應一個sheet）

Option Explicit   
   Dim rowsNum   
   rowsNum = 0   
'-----------------------------------------------------------------------------   
' Main function   
'-----------------------------------------------------------------------------   
' Get the current active model   
Dim Model   
Set Model = ActiveModel   
If (Model Is Nothing) Or (Not Model.IsKindOf(PdPDM.cls_Model)) Then   
  MsgBox "The current model is not an PDM model."   
Else   
 ' Get the tables collection   
 '創建EXCEL APP   
  
  
Dim beginrow  
 Dim EXCEL, BOOK, SHEET  
 Set EXCEL = CreateObject("Excel.Application")  
 EXCEL.Visible = True  
 Set BOOK = EXCEL.Workbooks.Add(-4167) '新建工作簿  
  
 BOOK.Sheets(1).Name = "表目錄"  
 Set SHEET = EXCEL.workbooks(1).sheets("表目錄")  
  
 ShowProperties Model, SHEET  
 EXCEL.visible = true   
 '設置列寬和自動換行   
 SHEET.Columns(1).ColumnWidth = 10     
 SHEET.Columns(2).ColumnWidth = 30     
 SHEET.Columns(3).ColumnWidth = 50     
 SHEET.Columns(4).ColumnWidth = 30      
 SHEET.Columns(1).WrapText =true   
 SHEET.Columns(2).WrapText =true   
 SHEET.Columns(3).WrapText =true   
 SHEET.Columns(4).WrapText =true 
End If  
  
'-----------------------------------------------------------------------------   
' Show properties of tables   
'-----------------------------------------------------------------------------   
Sub ShowProperties(mdl, sheet)   
   ' Show tables of the current model/package   
   rowsNum=0   
   beginrow = rowsNum+1   
   ' For each table   
   output "begin"   
   Dim tab   
   For Each tab In mdl.tables   
      ShowTable tab,sheet   
   Next   
   if mdl.tables.count > 0 then   
        sheet.Range("A" & beginrow + 1 & ":A" & rowsNum).Rows.Group   
   end if   
   output "end"   
End Sub  
  
'-----------------------------------------------------------------------------   
' 數據表查詢   
'-----------------------------------------------------------------------------  
Sub ShowTable(tab, sheet)     
   If IsObject(tab) Then   
     Dim rangFlag  
	  sheet.Range(sheet.cells(1, 1), sheet.cells(1, 4)).Merge
	  sheet.cells(1, 1) = "XX項目數據庫設計說明書" 
	  sheet.Range(sheet.cells(2, 1), sheet.cells(2, 4)).Merge
	  sheet.cells(2, 1) = "表目錄"   
      sheet.cells(3, 1) = "序號"   
      sheet.cells(3, 2) = "表ID"  
      sheet.cells(3, 3) = "表名稱"  
	  sheet.cells(3, 4) = "Sheet頁名"  
      '設置邊框   
      sheet.Range(sheet.cells(3, 1),sheet.cells(3, 4)).Borders.LineStyle = "1"  
      '設置背景顏色  
      sheet.Range(sheet.cells(3, 1),sheet.cells(3, 4)).Interior.Color  = RGB(204,255,204)  
  
      rowsNum = rowsNum + 1 
      sheet.cells(rowsNum+3, 1) = rowsNum   
      sheet.cells(rowsNum+3, 2) = tab.code  
      sheet.cells(rowsNum+3, 3) = tab.name  
	  sheet.Hyperlinks.Add  sheet.cells(rowsNum+3, 3),"",tab.code&"!B1"
	  sheet.cells(rowsNum+3, 4) = tab.code  
      '設置邊框  
      sheet.Range(sheet.cells(rowsNum+3,1),sheet.cells(rowsNum+3,4)).Borders.LineStyle = "2"  
  
      '增加Sheet  
      BOOK.Sheets.Add , BOOK.Sheets(BOOK.Sheets.count)  
      BOOK.Sheets(rowsNum+1).Name = tab.code   
  
      Dim shtn  
      Set shtn = EXCEL.workbooks(1).sheets(tab.code)  
      '設置列寬和換行  
       shtn.Columns(1).ColumnWidth = 20     
       shtn.Columns(2).ColumnWidth = 30     
       shtn.Columns(3).ColumnWidth = 40  
	   shtn.Columns(4).ColumnWidth = 20  
       shtn.Columns(5).ColumnWidth = 20     
       shtn.Columns(6).ColumnWidth = 20     
       shtn.Columns(7).ColumnWidth = 20  
	   shtn.Columns(8).ColumnWidth = 20  
	   shtn.Columns(9).ColumnWidth = 20  
	   shtn.Columns(10).ColumnWidth = 40  
       shtn.Columns(1).WrapText =true   
       shtn.Columns(2).WrapText =true   
       shtn.Columns(3).WrapText =true  
       shtn.Columns(4).WrapText =true   
       shtn.Columns(5).WrapText =true  
       shtn.Columns(6).WrapText =true   
       shtn.Columns(7).WrapText =true   
       shtn.Columns(8).WrapText =true  
       shtn.Columns(9).WrapText =true   
       shtn.Columns(10).WrapText =true  
	   
       '設置列標題  
	   shtn.cells(1, 1) = "表ID"  
       shtn.cells(1, 2) =  tab.code  
       shtn.cells(1, 3) = "表名"
       shtn.cells(1, 4) =  tab.name  	   
       shtn.cells(1, 10) ="回表目錄"  
	   shtn.Hyperlinks.Add  shtn.cells(1, 10),"","表目錄"&"!B"&rowsNum
       shtn.cells(2, 1) = "序號"   
       shtn.cells(2, 2) = "字段名"   
	   shtn.cells(2, 3) = "中文描述" 
	   shtn.cells(2, 4) = "類型" 
	   shtn.cells(2, 5) = "長度" 
	   shtn.cells(2, 6) = "可空" 
	   shtn.cells(2, 7) = "主鍵" 
	   shtn.cells(2, 8) = "默認值"
	   shtn.cells(2, 9) = "字典/外鍵"
	   shtn.cells(2, 10) = "備註"
	   shtn.cells(3, 1) = "No."   
       shtn.cells(3, 2) = "Field Name"   
	   shtn.cells(3, 3) = "Chinese Description" 
	   shtn.cells(3, 4) = "Type" 
	   shtn.cells(3, 5) = "Length" 
	   shtn.cells(3, 6) = "Null" 
	   shtn.cells(3, 7) = "Key" 
	   shtn.cells(3, 8) = "Default Value"
	   shtn.cells(3, 9) = "Dictionary"
	   shtn.cells(3, 10) = "Note"
       '設置邊框   
       shtn.Range(shtn.cells(1, 1),shtn.cells(1, 1)).Borders.LineStyle = "1"  
	   shtn.Range(shtn.cells(1, 3),shtn.cells(1, 3)).Borders.LineStyle = "1"  
       shtn.Range(shtn.cells(2, 1),shtn.cells(2, 10)).Borders.LineStyle = "1"  
	   shtn.Range(shtn.cells(3, 1),shtn.cells(3, 10)).Borders.LineStyle = "1"  
       '設置背景顏色  
       shtn.Range(shtn.cells(1, 1),shtn.cells(1, 1)).Interior.Color  = RGB(204,255,204) 
	   shtn.Range(shtn.cells(1, 3),shtn.cells(1, 3)).Interior.Color  = RGB(204,255,204) 
       shtn.Range(shtn.cells(2, 1),shtn.cells(2, 10)).Interior.Color  = RGB(204,255,204) 
       shtn.Range(shtn.cells(3, 1),shtn.cells(3, 10)).Interior.Color  = RGB(204,255,204) 
      Dim col ' running column   
      Dim colsNum  
      Dim rNum  
      Dim orderNum   	  
      colsNum = 0 
      orderNum=0	  
      rNum = 2   
            for each col in tab.columns   
              rNum = rNum + 1   
			  orderNum=orderNum+1
              colsNum = colsNum + 1   
            shtn.cells(rNum+1, 1) = orderNum 
			shtn.cells(rNum+1, 2) = col.code  
            shtn.cells(rNum+1, 3) = col.name   
            shtn.cells(rNum+1, 4) = col.datatype    
            shtn.cells(rNum+1, 5) = col.length  
			  If col.Mandatory = true Then
             shtn.cells(rNum+1, 6) = "Y" 
             Else
             shtn.cells(rNum+1, 6) = " " 
             End If
			 If col.Primary = true Then
             shtn.cells(rNum+1, 7) = "Y" 
             Else
             shtn.cells(rNum+1, 7) = " " 
             End If
            shtn.cells(rNum+1, 8) = col.defaultvalue 
			 If col.ForeignKey = true Then
             shtn.cells(rNum+1, 9) = "Y" 
             Else
             shtn.cells(rNum+1, 9) = " " 
             End If
            shtn.cells(rNum+1, 10) = col.comment   			
            next   
            shtn.Range(shtn.cells(rNum-colsNum+2,1),shtn.cells(rNum+1,10)).Borders.LineStyle = "2"           
            rNum = rNum + 1   
  
            Output "FullDescription: "       + tab.Name  
  
   End If     
End Sub

等待生成完成
在這裏插入圖片描述
參考1：https://blog.csdn.net/Bin594505536/article/details/50517573
參考2：https://www.cnblogs.com/shangshen/p/10062285.html

發表評論
所有評論
還沒有人評論，想成為第一個評論的人麼? 請在上方評論欄輸入並且點擊發布.
相關文章

如何用Flask中的Blueprints構建大型Web應用

本文分享自華爲雲社區《構建大型Web應用Flask中的Blueprints指南》，作者： 檸檬味擁抱。 什麼是Blueprints？ Blueprints是Flask中的一種模式，用於將應用程序分解爲可重用的模塊。每個藍圖實際上是一個包含

原創 2024-03-27 11:15:44

sybase powerdesigner 16.5註冊碼

sybase powerdesigner 16.5安裝之後一段時間就會過期，破解辦法是：將pdflm16.dll文件覆蓋原來的即可。 pdflm16.dll文件下載地址：鏈接：https://pan.baidu.com/s/1kWySpRT

原創 2021-10-25 21:27:07

PDMan的延續->CHINER[元數建模]-實時功能介紹-動態更新

chiner,發音:[kaɪˈnər] [CHINER元數建模-3.0]，發起於2018年，幾經磨難，匠心打造，浴火重生。做一款豐富數據庫生態的，獨立於具體數據庫之外的，數據庫關係模型設計平臺。 > 元數建模平臺，使用React+Elect

原創 2021-09-18 09:15:17

PDMan的最新版-CHINER[元數建模]升級至v3.2.1：最好用的國產開源數據庫建模平臺

chiner,發音:[kaɪˈnər] 1 背景說明 從尋找PowerDesigner的替代品爲出發點，我們推出了PDMan，幾經磨練，歷時三年，點滴積累，醞釀，最終脫胎換骨，自7月17日”CHINER元數建“模公開發布以來，我們共公開

原創 2021-09-08 09:15:01

PDMan的最新版-CHINER[元數建模]升級至v3.2：最好用的國產開源數據庫建模平臺

chiner,發音:[kaɪˈnər] 1 背景說明 從尋找PowerDesigner的替代品爲出發點，我們推出了PDMan，幾經磨練，歷時三年，點滴積累，醞釀，最終脫胎換骨，自7月17日”CHINER元數建“模公開發布以來，我們共公開

原創 2021-08-22 21:16:46

C# Winform應用系統如何快速開發？看完這篇文章就懂了

在實際的業務中，往往還有很多需要使用Winform來開發應用系統的，如一些HIS、MIS、MES等系統，由於Winform開發出來的系統界面友好，響應快速，開發效率高等各方面原因，還有一些原因是獨立的WInform應用系統方便部署使用，可以

原創 2021-07-05 09:28:09

解決PowerDesigner複製字段修改聯動的問題【轉】

解決PowerDesigner複製字段修改聯動的問題【轉】 參考文章： （1）解決PowerDesigner複製字段修改聯動的問題【轉】 （2）https://www.cnblogs.com/hanyun/archive/2012/05/

javail 2021-06-11 21:16:41

PowerDesigner表字段變大寫的VB腳本，高級技能Get!

高級用法，字段字母全部變爲大寫，不用手動一個一個改 Option Explicit ValidationMode = True InteractiveMode = im_Batch Dim mdl ' the current mo

原創 2021-04-09 09:30:02

Bootstrap4+MySQL前後端綜合實訓-Day04-AM【新聞管理手機端頁面+數據庫操作(PowerDesigner 圖形化數據庫設計軟件、SQLyog軟件)】

【Bootstrap4前端框架+MySQL數據庫】前後端綜合實訓【10天課程 博客彙總表 詳細筆記】 目   錄 W3C標準盒子模型和IE盒子模型的區別 Bootstrap4——新聞管理手機端頁面 菜鳥教程——Bootstrap4 網格

osc_zriqiio6 2021-01-30 10:43:37

Oracle數據反向導入到pdm

一、前置條件 已存在oracle數據庫 已安裝PowerDesigner數據庫建模工具 二、在PowerDesigner中創建jdbc數據庫連接 點擊 “File>Reverse Engineer>Database” 選擇數據

zw965 2021-01-30 10:25:51

powerdesigner16 因分辨率而消失的 右側懸浮菜單

powerdesigner16 因分辨率而消失的 右側懸浮菜單 使分辨率可用 新電腦分辨率有點高並不一定是好事兒，很可能會帶來許多意想不到的麻煩，安裝好powerdesigner16 之後因分辨率太高，它跟Eclipse一樣，圖標和文字

osc_u3rhqm7a 2021-01-30 10:14:13

MSSQL系列之之十三 數據庫設計

第二章 數據庫設計          需要掌握的內容是：一：數據庫設計的必要性；二：數據庫設計的步驟；三：繪製E-R圖；四：規範化設計數據庫。         數據庫步驟：                   一：收集信息；      

osc_61i1fz2h 2021-01-30 09:54:56

如何編寫自己的數據訪問層

概述     在二開（族庫、算量等）或者大部分管理軟件的開發中，多數系統架構是基於數據庫設計的，那麼怎麼設計數據訪問層呢？ 一、設計框架 圖中分成三塊： 1、左邊的xxxServices爲app公開訪問數據接口； 2、中間紅色部分爲底

osc_7eqzxl4g 2021-01-30 09:42:07

MSSQL系列之一數據模型

第一章 數據模型 目標: 1.數據庫的概念 2.數據庫管理系統是什麼？RDBMS是什麼? DBMS:database Management System RDBMS:Relationship DBMS 基於對象的邏輯模型: 3.E-R圖是

osc_oa6qrgun 2021-01-30 09:26:18

Workbench——免費的官方MySQL客戶端，再也不用找Navicat破解版了

點擊上方 IT牧場 ，選擇 置頂或者星標 技術乾貨每日送達 在MySQL的客戶端工具中，大部分小夥伴都會選擇Navicat，但是Navicat是收費的，對個人來說，破解版固然好用，但是在公司中使用，就會涉及風險了。 但是現在有了官方的M

大目 2021-01-30 09:24:27