在點燈科技APP使用esp8266控制舵機

原創

弓长于水

2020-06-16 02:46

最近有點事，一個星期沒有寫博客記錄啦，其實遇到了不少有用的知識和小項目，沒有寫博客記錄慚愧慚愧

廢話不多說，我們進入正題：

這次我們用點燈科技來控制舵機的旋轉

使用的還是我們的Arduino IDE，硬件的需求有esp8266 nodemcu以及一個舵機

1、爲Arduino IDE添加點燈科技的庫文件，具體操作看文章：
小愛同學脫離局域網遠程控制開關？

2、上代碼：

#include <Servo.h> 
#define BLINKER_WIFI
 
#include <Blinker.h>
 
char auth[] = "";   //key
char ssid[] = "";             //wifi名稱
char pswd[] = "";      //wifi密碼
 
// 新建組件對象
BlinkerButton Button1("btn-max");   //位置1 按鈕 數據鍵名
BlinkerButton Button2("btn-min");   //位置2 按鈕 數據鍵名
BlinkerButton Button3("btn-pw");    //循環模式 按鈕 數據鍵名  開關模式
Servo myservo;
BlinkerSlider Slider1("max-num");   //位置1 滑塊 數據鍵名  範圍1-180
BlinkerSlider Slider2("min-num");   //位置2 滑塊 數據鍵名  範圍1-180
BlinkerSlider Slider3("ser-num");   //實時位置 滑塊 數據鍵名  範圍1-180
BlinkerSlider Slider4("time-num");  //循環模式間隔時間 滑塊 數據鍵名 範圍單位毫秒

bool xunhuan_mode = false;

int servo_max,servo_min,ser_num,time_num;
  
void button1_callback(const String & state) {    //位置1按鈕
    BLINKER_LOG("get button state: ", servo_max);
    myservo.write(servo_max);
    Blinker.vibrate();
}
  
void button2_callback(const String & state) {   //位置2按鈕
    BLINKER_LOG("get button state: ", servo_min); 
    myservo.write(servo_min);
    Blinker.vibrate();
}

void button3_callback(const String & state) {    //位置3按鈕  開關模式
   // Blinker.vibrate();
    if(state == "on"){
      xunhuan_mode = true;  
      Button3.print("on");  
      Blinker.delay(100);
    }else if (state == "off"){
      xunhuan_mode = false;
      Button3.print("off");
      Blinker.delay(100);
    }
}


void slider1_callback(int32_t value)
{
    servo_max = value;
    Slider1.color("#1E90FF");
    Slider1.print();
    
    BLINKER_LOG("get slider value: ", value);
}

void slider2_callback(int32_t value)
{
    servo_min = value;
    Slider2.color("#FFF8DC");
    Slider2.print();
    BLINKER_LOG("get slider value: ", value);
}

void slider3_callback(int32_t value)
{
    ser_num = value;
    myservo.write(ser_num);
    Blinker.delay(100);
    BLINKER_LOG("get slider value: ", value);
}


void slider4_callback(int32_t value)
{
    time_num = value;
    Blinker.delay(100);
    BLINKER_LOG("get slider value: ", value);
}

void xunhuan(){
     myservo.write(servo_max);
     Blinker.delay(time_num/2);
     myservo.write(servo_min);
     Blinker.delay(time_num/2);
}

void setup() {

    Serial.begin(115200);    
    BLINKER_DEBUG.stream(Serial);
    Blinker.begin(auth, ssid, pswd);
    Button1.attach(button1_callback);
    Button2.attach(button2_callback);
    Button3.attach(button3_callback);
    Slider1.attach(slider1_callback);
    Slider2.attach(slider2_callback);
    Slider3.attach(slider3_callback);
    Slider4.attach(slider4_callback);
    myservo.attach(5);	//servo.attach():設置舵機數據引腳
    myservo.write(10);	//servo.write():設置轉動角度
    servo_max=70;
    servo_min=120;
    time_num=500;

}

void loop() {

  Blinker.run();
  if(xunhuan_mode==true){
    xunhuan();
  }
    
}

這裏說一下Servo庫

attach()
描述
將Servo變量附加到引腳，注意：在Arduino 0016及之前的版本上，Servo庫僅支持將舵機連接至第9和第10腳上。
語法
servo.attach(pin)
servo.attach(pin, min, max)
參數說明
servo，一個類型爲servo的變量
pin，連接至舵機的引腳編號
min(可選)，舵機爲最小角度（0度）時的脈衝寬度，單位爲微秒，默認爲544
max(可選)，舵機爲最大角度（180度時）的脈衝寬度，單位爲微秒，默認爲2400

write()
描述
向舵機寫入一個數值，來直接控制舵機的軸。在一個標準的舵機中，這將設定齒輪的角度，將齒輪轉到對應的位置。在一個連續旋轉的舵機中，這將設置一個舵機的角度（0作爲全速向一邊，180爲全速向另一邊，在90附近的值爲停止）。
語法
servo.write(angle)
參數說明
servo，一個類型爲servo的變量
angle，寫向舵機的角度，從0到180之間