flex 開發卡片主類一

1. package code
2. {
3.     /**
4.      * 產品開發基本類
5.      */
6.     import flash.display.Bitmap;
7.     import flash.display.BitmapData;
8.     import flash.display.Loader;
9.     import flash.events.Event;
10.     import flash.events.MouseEvent;
11.     import flash.geom.Matrix;
12.     import flash.net.URLRequest;
13.     
14.     import module.TextEditview;
15.     import module.photEditview;
16.     
17.     import mx.containers.Canvas;
18.     import mx.controls.Image;
19.     import mx.controls.TextArea;
20.     import mx.core.Container;
21.     import mx.managers.PopUpManager;
22.     import mx.rpc.events.ResultEvent;
23.     import mx.rpc.http.mxml.HTTPService;  
25.     
26.     public class ProductHandlerBasic extends Container
27.     {
28.         /*當前所編輯產品*/
29.         private var _currentStage:Container ;
30.         private var _productID:Number ;
31.         /*所保存作品的ID，如果此產品沒保存過這爲-1*/
32.         private var _recordID:Number=-1 ;  ; 
33.         /*用戶選擇的模板圖片，在進入操作頁面之前，用戶需要選擇模板*/
34.         private var _defaulModuleUrl:String  ;
35.         
36.         /*保存產品所以頁面的內容，例如模板，照片，文字。以xml到形式存放*/
37.         private var _productDataContent:XML ;
38.         
39.         /*產品信息數據,每個型號所對應的價格，名稱等等*/
40.         private var _productInfo:XML ;
41.         
42.         public var _testTextArea:TextArea ;
43.          
44.         /*當前主題的所有數據座標數據*/
45.         private var _photoCoordinateData:XML ; 
46.         
47.         private var _httpservice:HTTPService ;
48.         
49.         /*照片在模板上的位置(順序)*/
50.         private var _currentphotoNum:Number =0 ; ;
51.         /*每一張的順序，如:上一張,下一張*/
52.         private var _currentpageNum:Number =0 ;
53.         /*當前頁面內容數據，由版式,照片文件組成*/
54.         private var _currentpageData:XML ;
55.         /*當前頁面的座標數據*/
56.         private var _currentcoordinateData:XMLList ;
57.         /*顯示模板，照片及一些操作*/
58.         private var _userstage:Canvas ;
59.         /*當前的模板圖片*/
60.         private var _backgroundImage:Image= new Image() ;
61.         /*產品innerNumber*/
62.        
63.         private var _productInnerNum:Number = 0 ;
64.         public function ProductHandlerBasic()
65.         {
66.             _httpservice = new HTTPService();
67.             _httpservice.showBusyCursor = true ; 
68.             _httpservice.method = "post" ;
69.             _httpservice.url = "/HttpServiceSlt";
70.             _httpservice.resultFormat="xml";
71.             _httpservice.addEventListener(ResultEvent.RESULT,createEditProudctContent);
72.             
73.             /*加入事件監聽，照片切換及照片編輯時,要用到此*/
74.             _backgroundImage.addEventListener(MouseEvent.CLICK,photoClickHandler);
75.             _backgroundImage.addEventListener(MouseEvent.DOUBLE_CLICK,photoDoubleClickHandler);
76.             _backgroundImage.doubleClickEnabled = true ; 
77.         }
78.         /**
79.          * 作品封面圖片地址
80.          */
81.         public function get previewURL():String{
82.             return _productInfo.product.(@id==_productID).previewURL ;
83.         }
84.         /**
85.          * 產品單價
86.          */ 
87.         public function get price():Number{
88.             return _productInfo.product.(@id==_productID).price ;
89.         }
90.         /**
91.          * 價格單位 
92.          */ 
93.         public function get unit():String{
94.             return _productInfo.product.(@id==_productID).unit ;
95.         }
96.         /**
97.          * 得到型號的總頁數
98.          */ 
99.         public function get pages():Number{ 
100.             return _productInfo.product.(@id==_productID)..label.length();
101.         }
102.           
103.         /**
104.          * 增加郵票或信封的價格
105.          */    
106.         public function get stepPrice():Number{
107.             return _productInfo.product.(@id==_productID)..stepprice;
108.         }
109.         /**
110.          * 複合價格。例如加上信封和郵票的價格。
111.          * 計算方法：基價+步價*innernumber
112.          */ 
113.         public function get duplexPrice():Number{
114.              
115.             return Math.round((this.productInnerNum*stepPrice+price)*100)/100 ;
116.         } 
117.         
118.         /**
119.          * 獲取型號下的主題信息.包括名稱,數量等等.
120.          */    
121.         public function get mbClass():XMLList{ 
122.             return _productInfo.product.(@id==_productID)..subject;
123.         }
124.         
125.         /**
126.          * 型號。如：明星片,長賀卡
127.          * 
128.          */ 
129.         public function get typename():String{
130.             return _productInfo.product.(@id==_productID).file ;
131.         }
132.         
133.         public function get productInnerNum():Number{
134.               
135.             return _productDataContent.innernumber;
136.         }
137.         public function set productInnerNum(p:Number):void{
138.             _productDataContent.innernumber = p;
139.         }
140.         
141.         /**
142.          * 產品所屬類別
143.          */ 
144.         public function get classid():String{
145.             return _productInfo.classid.@id ;
146.         }
147.         
148.         public function set currentStage(c:Container):void{
149.             this._currentStage = c ;
150.         }
151.         public function get currentStage():Container{
152.             return this._currentStage ;
153.         }
154.         public function set productID(p:Number):void{
155.             this._productID = p ;
156.         }
157.         public function get productID():Number{
158.             return this._productID ;
159.         }
160.         public function set recordID(r:Number):void{
161.             this._recordID= r ;
162.         }
163.         public function get recordID():Number{
164.             return this._recordID ;
165.         } 
166.         public function set defaulModuleUrl(url:String):void{
167.             this._defaulModuleUrl = url ;
168.         }  
169.         public function get defaulModuleUrl():String{
170.             return this._defaulModuleUrl ;
171.         }   
172.         public function set productInfo(info:XML):void{
173.             this._productInfo = info ;
174.         }    
175.         public function get productInfo():XML{
176.             return this._productInfo ;
177.         }   
178.         public function set httpservice(h:HTTPService):void{
179.             this._httpservice = h ;
180.         }   
181.         public function get httpservice():HTTPService{
182.             return this._httpservice ;
183.         }
184.         public function set photoCoordinateData(p:XML):void{
185.             this._photoCoordinateData = p ;
186.         }
187.         public function get photoCoordinateData():XML{
188.             return this._photoCoordinateData ;
189.         }
190.         public function set userstage(s:Canvas):void{
191.             this._userstage = s ;
192.         }  
193.         public function get userstage():Canvas{
194.             return this._userstage ;
195.         }
196.         public function set currentpageNum(c:Number):void{
197.             this._currentpageNum = c ;
198.         }
199.         public function get currentpageNum():Number{
200.             return this._currentpageNum ;
201.         } 
202.         public function set currentphotoNum(p:Number):void{
203.             this.currentphotoNum = p ;
204.         } 
205.         public function get currentphotoNum():Number{
206.             return this._currentphotoNum ;
207.         }
208.         public function set productDataContent(p:XML):void{
209.             this.productDataContent = p ;
210.         } 
211.         public function get productDataContent():XML{
212.             return this._productDataContent ;
213.         }
214.         
215.         /**
216.          * 模板單擊處理,檢測鼠標的位置計算出，具體單擊的照片
217.          */
218.         private function photoClickHandler(e:MouseEvent):void{
219.             var img :Image = null ;
220.         
221.             for(var i:int=0;i<this._currentcoordinateData.pic.length();i++){
222.                 img =  this._userstage.getChildAt(i) as Image ;
223.                 revertPhotoAlpha();
224.                 if(img.hitTestPoint(mouseX,mouseY)){   
225.                     this._currentphotoNum = i ;//當前照片的號碼
226.                     img.alpha = 0.5 ;
227.                     break ;
228.                 }
229.             }    
230.         }
231.         
232.         /**
233.          * 雙擊照片，彈出照片編輯窗口
234.          */ 
235.         private function photoDoubleClickHandler(e:MouseEvent):void{
236.             var img_ :Image = null ;
237.             for(var i:int=0;i<this._currentcoordinateData.pic.length();i++){
238.                 img_ =  this._userstage.getChildAt(i) as Image ;
239.                 revertPhotoAlpha();
240.                 if(img_.hitTestPoint(mouseX,mouseY)){   
241.                     this._currentphotoNum = i ;
242.                     this.revertPhotoAlpha() ;
243.                     var url_:String =     this._productDataContent.item[_currentpageNum]..img[i].@url ;
244.                     var x_  :Number =     this._productDataContent.item[_currentpageNum]..img[i].@x ;
245.                     var y_  :Number =     this._productDataContent.item[_currentpageNum]..img[i].@y ;
246.                     var w_  :Number =     this._productDataContent.item[_currentpageNum]..img[i].@width ;
247.                     var h_  :Number =     this._productDataContent.item[_currentpageNum]..img[i].@height ;
248.                     
249.                     /*照片編輯框*/
250.                     var photoEdit_:photEditview = new photEditview();
251.                     photoEdit_.producthandlerBase = this ;  
252.                     PopUpManager.addPopUp(photoEdit_,this._currentStage,true);
253.                     photoEdit_.initphotoEditParams(img_,url_,x_,y_,w_,h_);           
254.                     break ;
255.                 } 
256.             }   
257.         }
258.         
259.         /**
260.          * 恢復照片透明度。用戶單擊照片，改變單擊的照片的透明度 ,以此來做標識 。
261.          * 當用戶切換照片時，恢復照片透明度，再改變所選照片的透明度。
262.          */ 
263.         private function revertPhotoAlpha():void{
264.             var img:Image = null ;
265.             for(var i:int=0;i<this._currentcoordinateData.pic.length();i++){
266.                 img =  this._userstage.getChildAt(i) as Image ;
267.                 if(img.alpha==0.5){
268.                     img.alpha = 1 ; 
269.                     break ; 
270.                 }    
271.             }
272.         }
274.         /**
275.          * 生成默認的產品內容，沒過型號都不相同，所以動態生成。
276.          * 如果產品已經保存過的話，內容從服務端加載過來
277.          */    
278.         public function createProductContent():void{
279.             if(this._recordID==-1){
280.                 this.createNewProudctContent() ;    
281.                 return ;            
282.             }
283.             //編輯產品
284.             var params:Object = new Object() ;
285.             params.methodName = "getProductContent" ;
286.             params.random= Math.random() ; 
287.             params.pid= this._recordID ; 
288.             //this._testTextArea.text = "recordid=="+this._recordID ; 
289.             this._httpservice.send(params) ;    
290.         }   
291.           
292.         /*創建默認產品數據結構*/
293.         private function createNewProudctContent():void{
294.             _productDataContent = <wdxc></wdxc> ; 
295.             /*得到此種型號的產品有多少頁數*/
296.             var xmllist_t:XML = new XML(this._productInfo.product.(@id==_productID));       
297.             var count:Number = xmllist_t.count ;
298.   
299.             for(var i:int=0;i<count;i++){ 
300.                 /*每一張記錄節點*/
301.                 var itemNode:XML  = <item></item>;
302.                 var photoNode:XML =<photo></photo>;
303.                 for(var j:int=0;j<13;j++){
304.                     photoNode.appendChild(<img url="" x="-1" y="" width="" height=""/>);
305.                 }  
306.                   
307.                 /*豪華摺疊卡沒辦法,這能這樣*/ 
308.                 if(this._productID==598){               
309.                     itemNode.appendChild(<bs>{_defaulModuleUrl.replace(".gif","_"+(i+1)+".gif")}</bs>);
310.                 }else{
311.                     itemNode.appendChild(<bs>{this._defaulModuleUrl}</bs>);
312.                 }
313.                 itemNode.appendChild(photoNode) ;  
314.                 itemNode.appendChild(<txt><info></info></txt>);
315.                 _productDataContent.appendChild(itemNode);      
316.                  
317.             }   
318.             _productDataContent.appendChild(<innernumber>0</innernumber>);  
319.             //創建是否需要郵票和信封組件
320.             createOtherCom();
321.             this.initCurrentPageInfoToStage(true);
322.         }
323.         /**如果產品已經保存，將從productRecord表中，加載數據。
324.          * 而不是用訂單表中取得信息【編輯產品時】
325.          */    
326.         private function createEditProudctContent(e:ResultEvent):void{ 
327.             _productDataContent = new XML(e.result);
328.             createOtherCom(); 
329.             this.initCurrentPageInfoToStage(false);
330.         }   
331.         private var _defaultText:String = "單擊此處輸入文字" ;
332.          
333.         /**
334.          * 初始化當前參數信息
335.          * 1：加載模板圖片
336.          * 2：加載對應的圖片
337.          * @param recompute 
338.          * 左邊是否重新計算
339.          */
340.         public function initCurrentPageInfoToStage(recompute:Boolean):void{
341.                
342.             this._currentphotoNum =  0 ;  
343.             
344.             /*得到當前頁的數據信息.*/      
345.             _currentpageData = new XML(this._productDataContent.item[this._currentpageNum]) ;
346.         
347.             this._userstage.removeAllChildren();
348.              
349.             /*根據圖片在模板那的座標,生成容器，可單擊圖片而放入容器中*/
350.             for(var i:int=0;i<getCurrentPhotoCount(_currentpageNum);i++){
351.                 var img1_t:Image = new Image() ;
352.                 this._userstage.addChild(img1_t);
353.                 img1_t.name="img_"+i;
354.                 
355.                 img1_t.x = _currentcoordinateData.pic[i].@x ;
356.                 img1_t.y = _currentcoordinateData.pic[i].@y ;
357.                 img1_t.width = _currentcoordinateData.pic[i].@width ;
358.                 img1_t.height = _currentcoordinateData.pic[i].@height ; 
359.                 img1_t.scaleContent = true ;   
360.                 
361.                 /*加載圖片到模板相應的位置*/  
362.                 this.loadphotoToStage(img1_t,i,recompute,_productDataContent.item[_currentpageNum].photo.img[i].@url);          
363.   
364.             }           
365.             _backgroundImage.source = (this._productDataContent.item[this._currentpageNum].bs).toString(); 
366.             this._userstage.addChild(_backgroundImage);  
367.             /*加入用戶輸入的文字信息*/
368.             for(var k:int=0;k<_currentcoordinateData.txt.length();k++){
369.                 var textInfo_:TextArea = new TextArea() ;
370.                 textInfo_.alpha = 0 ;
371.                  
372.                 textInfo_.setStyle("fontSize","12"); 
373.                 textInfo_.name = "txt_"+k ;
374.                 textInfo_.x = _currentcoordinateData.txt[k].@x ;
375.                 textInfo_.y = _currentcoordinateData.txt[k].@y  ; 
376.                 textInfo_.width= _currentcoordinateData.txt[k].@width ;
377.                 textInfo_.height = _currentcoordinateData.txt[k].@height ;  
378.                 textInfo_.editable = false ;
379.                 if(_productDataContent.item[_currentpageNum].txt.info[k]==""||
380.                     _productDataContent.item[_currentpageNum].txt.info[k]==null){
381.                     textInfo_.text = _defaultText ;
382.                 }else{
383.                     textInfo_.htmlText = _productDataContent.item[_currentpageNum].txt.info[k] ;
384.                 }  
385.                   
386.                 textInfo_.addEventListener(MouseEvent.CLICK,openTextEditview) ;
387.                 this._userstage.addChild(textInfo_); 
388.             }    
389.         }
390.         
391.         /**
392.          * 打開文字編輯窗口
393.          * 
394.          */ 
395.         public function openTextEditview(e:MouseEvent):void{
396.             var textInfo_:TextArea = TextArea(e.currentTarget);
397.             var tev_ :TextEditview = new TextEditview() ;
398.             PopUpManager.addPopUp(tev_,_currentStage,true,null);
399.             tev_.targetLabelName = textInfo_.name ;
400.             tev_.phander = this ;
401.             var n_:Number = textInfo_.name.split("_")[1]; ;
402.             
403.             /*打開文字編輯窗口*/
404.             tev_.my_rte.htmlText =_productDataContent.item[_currentpageNum].txt.info[n_] ;
405.             tev_.my_rte.width = textInfo_.width ;
406.             tev_.my_rte.height =textInfo_.height ;
407.             tev_.my_rte.maxWidth = textInfo_.width ;
408.             tev_.my_rte.maxHeight = textInfo_.height ;
409.         
410.             tev_.x = 100  ;  
411.             tev_.y = 100  ; 
412.         } 
413.         /**
414.         * 文字編輯完畢保存用戶輸入的文字 。
415.         * 
416.         */ 
417.         
418.         public function saveUserInputText(html_:String,txt_:String,labelname_:String):void{
419.             
420.             var lab_:TextArea = this._userstage.getChildByName(labelname_) as TextArea;
421.              
422.             if(txt_==null||txt_.length==0||txt_==""){
423.                lab_.text= _defaultText ;
424.            } else{ 
425.                 lab_.htmlText = html_ ;  
426.                 var n_:Number = labelname_.split("_")[1]; ;
427.                 _productDataContent.item[_currentpageNum].txt.info[n_] = html_ ;
428.                 
429.            }
430.         }
431.         
432.         /**
433.          * 當前模板最大能填充照片的張數。 自動填充照片時，需要用此 。
434.          */ 
435.         public function getCurrentPhotoCount(num_:Number):Number{
436.             /*得到當前的模板名稱，通過此查詢其座標數據*/ 
437.             var a1:Array = this._productDataContent.item[num_].bs.split("/"); 
438.             var picname:String = a1[a1.length-1];
439.             
440.                        
441.             /*得到當前的座標數據.例如:<pic x="98" y="10" width="112" height="111"/>*/
442.             _currentcoordinateData=_photoCoordinateData.subject.mb.(@picname==picname);
443.             
444.             return  this._currentcoordinateData.pic.length();       
445.         }
446.         
447.         /**
448.          * 當前模板文字輸入框座標個數。
449.          */ 
450.         public function getCurrentTextCount(num_:Number):Number{
451.             /*得到當前的模板名稱，通過此查詢其座標數據*/ 
452.             var a1:Array = this._productDataContent.item[num_].bs.split("/"); 
453.             var picname:String = a1[a1.length-1];
454.             
455.                        
456.             /*得到當前的座標數據.例如:<pic x="98" y="10" width="112" height="111"/>*/
457.             _currentcoordinateData=_photoCoordinateData.subject.mb.(@picname==picname);
458.             
459.             return  this._currentcoordinateData.txt.length();       
460.         }
461.         
462.         /**
463.          * 加載圖片到舞臺上,圖片顯示區域由模板框大小決定。模板的最大邊爲準。
464.          * 用戶照片顯示區域的座標.照片編輯對照片裁剪的座標，首次沒有座標,則
465.          * 取用戶圖片的中心位置如果用戶已經裁剪，則有座標,根據座標裁剪圖片。
466.          * @param img:當前操作的圖片對象。相冊列表中所選擇的照片將在此顯示
467.          * @param num:當前圖片在模板上的順序號碼。 
468.          * @param recompute 座標是否需要重新計算。如：改變模板時,許重算 
469.          * @param targerurl 用戶在相冊列表選擇的圖片地址。
470.          * 
471.         */    
472.         public function loadphotoToStage(targetimg:Image,num:Number,recompute:Boolean,targerurl:String):void{
474.             if(targerurl==null||targerurl==""){
475.                 return ;
476.             }           
477.             /*把當前的所操作的圖片地址放入產品內容xml中*/   
478.             //this._testTextArea.text ="url=="+targerurl+"targerurl.length"+targerurl.length;    
479.             /*得到當前的對象的.以在匿名函數中使用*/       
480.             var ph_t:ProductHandlerBasic = this ;
482.             var loader_t:Loader = new Loader();   
483.               
484.             loader_t.contentLoaderInfo.addEventListener(Event.COMPLETE,function(e:Event):void{
485.                 /*從產品內容數據中取得裁剪框在圖片上的座標*/
486.                 var width1:Number=0 ;
487.                 var height1:Number=0;
488.                 var x1:Number =0 ; 
489.                 var y1:Number =0 ; 
490.                 x1 = ph_t._productDataContent.item[ph_t._currentpageNum]..img[num].@x ;
491.                 y1 = ph_t._productDataContent.item[ph_t._currentpageNum]..img[num].@y ;
492.                 width1 = ph_t._productDataContent.item[ph_t._currentpageNum]..img[num].@width ;
493.                 height1 = ph_t._productDataContent.item[ph_t._currentpageNum]..img[num].@height ;
495.                 /*圖片原始數據*/
496.                 var oldbitmap_t:Bitmap = new Bitmap() ;
497.                 var l:Loader = e.target.loader as Loader;  
498.                 var oldbitmap_tdata:BitmapData = new  BitmapData (l.width,l.height) ;
499.                 oldbitmap_tdata.draw(l); 
500.                 /*是否需要重新計算座標*/
501.                 if(recompute||x1==-1){ 
502.                     /*計算出模板中圖片框的比例。根據此比例才能算出裁剪框的最大值*/
503.                     var scale_t:Number =targetimg.width/targetimg.height ;
504.                     /*根據比例求出高*/
505.                     var h2:Number = l.width/scale_t ;                   
506.                     if(h2<=l.height){
507.                         height1 = h2 ; 
508.                         width1 = l.width ;
509.                     }else{    
510.                         height1 = l.height ; 
511.                         width1 = height1*scale_t ;
512.                     }
513.                      /*裁剪框在照片的座標*/
514.                     x1 = (l.width-width1)/2 ; 
515.                     y1 = (l.height-height1)/2;      
516.                
517.                     ph_t._productDataContent.item[ph_t._currentpageNum]..img[num].@x = x1 ;  
518.                     ph_t._productDataContent.item[ph_t._currentpageNum]..img[num].@y = y1 ; 
519.                     ph_t._productDataContent.item[ph_t._currentpageNum]..img[num].@width = width1 ;  
520.                     ph_t._productDataContent.item[ph_t._currentpageNum]..img[num].@height =height1 ; 
521.                     ph_t._productDataContent.item[ph_t._currentpageNum]..img[num].@url = targerurl ;
522.                       
523.                 } 
524.                 /*存放從原始圖片數據裏裁剪出來的圖片數據*/
525.                 var newbitmap_t:BitmapData  = new BitmapData(width1,height1);
526.                 //座標轉化，把座標移到裁剪區域的位置，寬度和高度在cutbitmapdata裏指定。  
527.                 var matrix:Matrix = new Matrix(1, 0, 0, 1, -x1, -y1);   
528.                 newbitmap_t.draw(oldbitmap_tdata, matrix);    
530.                 oldbitmap_t.bitmapData = newbitmap_t ;    
531.                 targetimg.source = oldbitmap_t ; 
532.    
533.                 targetimg.scaleContent  = true ;
534.                 ph_t._currentphotoNum++ ;
536.                 }); 
537.                 
538.             loader_t.load(new URLRequest(targerurl)); 
539.         } 
540.         /**
541.          * 更換模板,改變之後重新導入當前頁面信息
542.          * 先改變內容數據，再重新加載
543.          */ 
544.         public function moduleChange(url:String):void{
545.              
546.             //豪華摺疊卡一次換3張
547.             if(this.typename=="replicatecard"){
548.                 
549.                 this._productDataContent.item[0].bs = url.replace(".gif","_1.gif") ;
550.                 this._productDataContent.item[1].bs = url.replace(".gif","_2.gif") ;
551.                 this._productDataContent.item[2].bs = url.replace(".gif","_3.gif") ;                
552.                 
553.             } else{
554.                 this._productDataContent.item[this._currentpageNum].bs = url ;
555.             }
556.             
557.             initCurrentPageInfoToStage(true);
558.         }
559.         /**
560.          * 單擊相冊照片，按順序填充照片到模板相應的位置 。
561.          * @param url :被單擊照片url
562.          */  
563.         public function albumPhotoClickHandler(url:String):void{
564.     
565.             //======當前模板的圖片個數  
566.             var t:Number = _currentcoordinateData.pic.length();
567.            
568.             if(this._currentphotoNum>t-1){
569.                 this._currentphotoNum = 0 ;
570.             }    
571.              
572.             
573.             var img:Image = this._userstage.getChildByName("img_"+this._currentphotoNum) as Image ;
574.             if(img==null){
575.                 return ;
576.             }
577.             
578.             this.loadphotoToStage(img,this._currentphotoNum,true,url);
579.         }
581.         /**
582.          * 保存當前頁數據,如：圖片座標
583.          * @param p1_  當前頁號碼
584.          * @param p2_  當前照片號碼
585.          * @param x_   起點座標 
586.          * @param y    
587.          * @param w_
588.          * @param h_
589.         
590.          */   
591.         public function saveCurrentPageData(p1_:Number,p2_:Number,url_:String,x_:Number,y_:Number,w_:Number,h_:Number):void{
592.             _productDataContent.item[p1_]..img[p2_].@x =x_ ;    
593.             _productDataContent.item[p1_]..img[p2_].@y =y_ ; 
594.             _productDataContent.item[p1_]..img[p2_].@width =w_ ;
595.             _productDataContent.item[p1_]..img[p2_].@height =h_ ;
596.             _productDataContent.item[p1_]..img[p2_].@url=url_ ;
597.                                         
598.         } 
599.         
600.         
601.         /**
602.          * 創建其他額外的組件,此處初始化信封和郵件列表
603.          */ 
604.         public function createOtherCom():void{
605.             //card.MAIN.right_id.sendAlbumInfoRequest();
606.   
607.             if(this.productInnerNum==1){
608.                 
609.                 card.MAIN.radbut1.selected = true ; 
610.             }else{
611.                 card.MAIN.radbut2.selected = true ;
612.             } 
613.             card.MAIN.header_id.recomputePrice();
614.             card.MAIN.right_id.initAlbum();
615.         }
617.     }
618. }