一篇非常好的csdn上的關於cmake的筆記

一、Cmake 簡介

cmake 是一個跨平臺、開源的構建系統。它是一個集軟件構建、測試、打包於一身的軟件。它使用與平臺和編譯器獨立的配置文件來對軟件編譯過程進行控制。

二、常用命令

1. 指定 cmake 的最小版本

cmake_minimum_required(VERSION 3.4.1)

這行命令是可選的，我們可以不寫這句話，但在有些情況下，如果 CMakeLists.txt 文件中使用了一些高版本 cmake 特有的一些命令的時候，就需要加上這樣一行，提醒用戶升級到該版本之後再執行 cmake。

2. 設置項目名稱

project(demo)

這個命令不是強制性的，但最好都加上。它會引入兩個變量 demo_BINARY_DIR 和 demo_SOURCE_DIR，同時，cmake 自動定義了兩個等價的變量 PROJECT_BINARY_DIR 和 PROJECT_SOURCE_DIR。

3. 設置編譯類型


add_executable(demo demo.cpp) # 生成可執行文件
add_library(common STATIC util.cpp) # 生成靜態庫
add_library(common SHARED util.cpp) # 生成動態庫或共享庫

add_library 默認生成是靜態庫，通過以上命令生成文件名字，

在 Linux 下是：
demo
libcommon.a
libcommon.so
在 Windows 下是：
demo.exe
common.lib
common.dll

4. 指定編譯包含的源文件

4.1 明確指定包含哪些源文件

add_library(demo demo.cpp test.cpp util.cpp)

4.2 搜索所有的 cpp 文件

aux_source_directory(dir VAR) 發現一個目錄下所有的源代碼文件並將列表存儲在一個變量中。


aux_source_directory(. SRC_LIST) # 搜索當前目錄下的所有.cpp文件
add_library(demo ${SRC_LIST})

4.3 自定義搜索規則


file(GLOB SRC_LIST "*.cpp" "protocol/*.cpp")
add_library(demo ${SRC_LIST})
# 或者
file(GLOB SRC_LIST "*.cpp")
file(GLOB SRC_PROTOCOL_LIST "protocol/*.cpp")
add_library(demo ${SRC_LIST} ${SRC_PROTOCOL_LIST})
# 或者
aux_source_directory(. SRC_LIST)
aux_source_directory(protocol SRC_PROTOCOL_LIST)
add_library(demo ${SRC_LIST} ${SRC_PROTOCOL_LIST})

5. 查找指定的庫文件

find_library(VAR name path)查找到指定的預編譯庫，並將它的路徑存儲在變量中。
默認的搜索路徑爲 cmake 包含的系統庫，因此如果是 NDK 的公共庫只需要指定庫的 name 即可。


find_library( # Sets the name of the path variable.
              log-lib
 
              # Specifies the name of the NDK library that
              # you want CMake to locate.
              log )

類似的命令還有 find_file()、find_path()、find_program()、find_package()。

6. 設置包含的目錄


include_directories(
    ${CMAKE_CURRENT_SOURCE_DIR}
    ${CMAKE_CURRENT_BINARY_DIR}
    ${CMAKE_CURRENT_SOURCE_DIR}/include
)

Linux 下還可以通過如下方式設置包含的目錄

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -I${CMAKE_CURRENT_SOURCE_DIR}")

7. 設置鏈接庫搜索目錄


link_directories(
    ${CMAKE_CURRENT_SOURCE_DIR}/libs
)

Linux 下還可以通過如下方式設置包含的目錄

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -L${CMAKE_CURRENT_SOURCE_DIR}/libs")

8. 設置 target 需要鏈接的庫


target_link_libraries( # 目標庫
                       demo
 
                       # 目標庫需要鏈接的庫
                       # log-lib 是上面 find_library 指定的變量名
                       ${log-lib} )

在 Windows 下，系統會根據鏈接庫目錄，搜索xxx.lib 文件，Linux 下會搜索 xxx.so 或者 xxx.a 文件，如果都存在會優先鏈接動態庫（so 後綴）。

8.1 指定鏈接動態庫或靜態庫


target_link_libraries(demo libface.a) # 鏈接libface.a
target_link_libraries(demo libface.so) # 鏈接libface.so

8.2 指定全路徑


target_link_libraries(demo ${CMAKE_CURRENT_SOURCE_DIR}/libs/libface.a)
target_link_libraries(demo ${CMAKE_CURRENT_SOURCE_DIR}/libs/libface.so)

8.3 指定鏈接多個庫


target_link_libraries(demo
    ${CMAKE_CURRENT_SOURCE_DIR}/libs/libface.a
    boost_system.a
    boost_thread
    pthread)

9. 設置變量

9.1 set 直接設置變量的值


set(SRC_LIST main.cpp test.cpp)
add_executable(demo ${SRC_LIST})

9.2 set 追加設置變量的值


set(SRC_LIST main.cpp)
set(SRC_LIST ${SRC_LIST} test.cpp)
add_executable(demo ${SRC_LIST})

9.3 list 追加或者刪除變量的值


set(SRC_LIST main.cpp)
list(APPEND SRC_LIST test.cpp)
list(REMOVE_ITEM SRC_LIST main.cpp)
add_executable(demo ${SRC_LIST})

10. 條件控制

10.1 if…elseif…else…endif

邏輯判斷和比較：
if (expression)：expression 不爲空（0,N,NO,OFF,FALSE,NOTFOUND）時爲真
if (not exp)：與上面相反
if (var1 AND var2)
if (var1 OR var2)
if (COMMAND cmd)：如果 cmd 確實是命令並可調用爲真
if (EXISTS dir) if (EXISTS file)：如果目錄或文件存在爲真
if (file1 IS_NEWER_THAN file2)：當 file1 比 file2 新，或 file1/file2 中有一個不存在時爲真，文件名需使用全路徑
if (IS_DIRECTORY dir)：當 dir 是目錄時爲真
if (DEFINED var)：如果變量被定義爲真
if (var MATCHES regex)：給定的變量或者字符串能夠匹配正則表達式 regex 時爲真，此處 var 可以用 var 名，也可以用 ${var}
if (string MATCHES regex)

數字比較：
if (variable LESS number)：LESS 小於
if (string LESS number)
if (variable GREATER number)：GREATER 大於
if (string GREATER number)
if (variable EQUAL number)：EQUAL 等於
if (string EQUAL number)

字母表順序比較：
if (variable STRLESS string)
if (string STRLESS string)
if (variable STRGREATER string)
if (string STRGREATER string)
if (variable STREQUAL string)
if (string STREQUAL string)
示例：


if(MSVC)
    set(LINK_LIBS common)
else()
    set(boost_thread boost_log.a boost_system.a)
endif()
target_link_libraries(demo ${LINK_LIBS})
# 或者
if(UNIX)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -fpermissive -g")
else()
    add_definitions(-D_SCL_SECURE_NO_WARNINGS
    D_CRT_SECURE_NO_WARNINGS
    -D_WIN32_WINNT=0x601
    -D_WINSOCK_DEPRECATED_NO_WARNINGS)
endif()
 
if(${CMAKE_BUILD_TYPE} MATCHES "debug")
    ...
else()
    ...
endif()

10.2 while…endwhile


while(condition)
    ...
endwhile()

10.3 foreach…endforeach


foreach(loop_var RANGE start stop [step])
    ...
endforeach(loop_var)

start 表示起始數，stop 表示終止數，step 表示步長，示例：


foreach(i RANGE 1 9 2)
    message(${i})
endforeach(i)
# 輸出：13579

11. 打印信息


message(${PROJECT_SOURCE_DIR})
message("build with debug mode")
message(WARNING "this is warnning message")
message(FATAL_ERROR "this build has many error") # FATAL_ERROR 會導致編譯失敗

12. 包含其它 cmake 文件


include(./common.cmake) # 指定包含文件的全路徑
include(def) # 在搜索路徑中搜索def.cmake文件
set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake) # 設置include的搜索路徑

三、常用變量

1. 預定義變量

PROJECT_SOURCE_DIR：工程的根目錄
PROJECT_BINARY_DIR：運行 cmake 命令的目錄，通常是 ${PROJECT_SOURCE_DIR}/build
PROJECT_NAME：返回通過 project 命令定義的項目名稱
CMAKE_CURRENT_SOURCE_DIR：當前處理的 CMakeLists.txt 所在的路徑
CMAKE_CURRENT_BINARY_DIR：target 編譯目錄
CMAKE_CURRENT_LIST_DIR：CMakeLists.txt 的完整路徑
CMAKE_CURRENT_LIST_LINE：當前所在的行
CMAKE_MODULE_PATH：定義自己的 cmake 模塊所在的路徑，SET(CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)，然後可以用INCLUDE命令來調用自己的模塊
EXECUTABLE_OUTPUT_PATH：重新定義目標二進制可執行文件的存放位置
LIBRARY_OUTPUT_PATH：重新定義目標鏈接庫文件的存放位置

2. 環境變量

使用環境變量

 $ENV{Name}

寫入環境變量

 set(ENV{Name} value) # 這裏沒有“$”符號

3. 系統信息

CMAKE_MAJOR_VERSION：cmake 主版本號，比如 3.4.1 中的 3
CMAKE_MINOR_VERSION：cmake 次版本號，比如 3.4.1 中的 4
CMAKE_PATCH_VERSION：cmake 補丁等級，比如 3.4.1 中的 1
CMAKE_SYSTEM：系統名稱，比如 Linux-2.6.22
CMAKE_SYSTEM_NAME：不包含版本的系統名，比如 Linux
CMAKE_SYSTEM_VERSION：系統版本，比如 2.6.22
CMAKE_SYSTEM_PROCESSOR：處理器名稱，比如 i686
UNIX：在所有的類 UNIX 平臺下該值爲 TRUE，包括 OS X 和 cygwin
WIN32：在所有的 win32 平臺下該值爲 TRUE，包括 cygwin

4. 主要開關選項

BUILD_SHARED_LIBS：這個開關用來控制默認的庫編譯方式，如果不進行設置，使用 add_library 又沒有指定庫類型的情況下，默認編譯生成的庫都是靜態庫。如果 set(BUILD_SHARED_LIBS ON) 後，默認生成的爲動態庫
CMAKE_C_FLAGS：設置 C 編譯選項，也可以通過指令 add_definitions() 添加
CMAKE_CXX_FLAGS：設置 C++ 編譯選項，也可以通過指令 add_definitions() 添加

add_definitions(-DENABLE_DEBUG -DABC) # 參數之間用空格分隔

四、項目示例

1. 簡單項目（單個源文件）

一個經典的 C 程序，如何通過 cmake 來編譯呢？

1.1 新建文件 main.c


#include <stdio.h>
int main() {
    printf("Hello World!\n");
    return 0;
}

1.2 新建文件 CMakeLists.txt（命名必須是 CMakeLists.txt，注意大小寫和不要漏字母）


project(HELLO)
add_executable(hello main.c)

1.3 編譯和運行

新建一個 build 文件夾，目錄情況如下：

爲什麼要新建一個 build 文件夾？
一般我們採用 cmake 的 out-of-source 方式來構建（即生成的中間產物和源代碼分離），這樣做可以讓生成的文件和源文件不會弄混，且目錄結構看起來也會清晰明瞭。所以推薦使用這種方式，至於這個文件夾的命名並無限制，我們習慣命名爲 build。

依次執行以下命令：


cd build
cmake ..

首先進入到 build 目錄，然後就是 cmake .. 命令，另外要注意將 cmake 配置到環境變量中去纔可直接使用，否則需要使用絕對路徑，.. 表示上一級目錄，cmake 會在上一級目錄下找到 CMakeLists.txt 文件並編譯，並生成如下圖所示的一些中間文件：

直接執行 make 命令，生成可執行程序，如下圖：

運行程序，如下所示：運行程序，如下所示：

2. 複雜項目（多個目錄，多個源文件，多個項目）

目錄結構如下：

demo 根目錄下的 CMakeLists.txt 文件如下：


cmake_minimum_required (VERSION 2.8)
project(demo)
aux_source_directory(. DIR_SRCS)
# 添加math子目錄
add_subdirectory(math)
# 指定生成目標
add_executable(demo ${DIR_SRCS})
# 添加鏈接庫
target_link_libraries(demo MathFunctions)

math 目錄下的 CMakeLists.txt 文件如下：


aux_source_directory(. DIR_LIB_SRCS)
# 生成鏈接庫
add_library(MathFunctions ${DIR_LIB_SRCS})

3. 自定義編譯選項

cmake 允許爲項目增加編譯選項，從而可以根據用戶的環境和需求選擇最合適的編譯方案。
例如，可以將 MathFunctions 庫設爲一個可選的庫，如果該選項爲 ON ，就使用該庫定義的數學函數來進行運算，否則就調用標準庫中的數學函數庫。
修改根目錄下的 CMakeLists.txt 文件如下：


# CMake 最低版本號要求
cmake_minimum_required (VERSION 2.8)
# 項目信息
project (Demo)
# 加入一個配置頭文件，用於處理 CMake 對源碼的設置
configure_file (
    "${PROJECT_SOURCE_DIR}/config.h.in"
    "${PROJECT_BINARY_DIR}/config.h"
    )
# 是否使用自己的 MathFunctions 庫
option (USE_MYMATH
        "Use provided math implementation" ON)
# 是否加入 MathFunctions 庫
if (USE_MYMATH)
    include_directories ("${PROJECT_SOURCE_DIR}/math")
    add_subdirectory (math)
    set (EXTRA_LIBS ${EXTRA_LIBS} MathFunctions)
endif (USE_MYMATH)
# 查找當前目錄下的所有源文件
# 並將名稱保存到 DIR_SRCS 變量
aux_source_directory(. DIR_SRCS)
# 指定生成目標
add_executable(Demo ${DIR_SRCS})
target_link_libraries (Demo ${EXTRA_LIBS})

configure_file 命令用於加入一個配置頭文件 config.h ，這個文件由 cmake 從 config.h.in 生成，通過這樣的機制，將可以通過預定義一些參數和變量來控制代碼的生成。
option 命令添加了一個 USE_MYMATH 選項，並且默認值爲 ON 。根據 USE_MYMATH 變量的值來決定是否使用我們自己編寫的 MathFunctions 庫。

修改 main.cc 文件，讓其根據 USE_MYMATH 的預定義值來決定是否調用標準庫還是MathFunctions 庫：


#include "config.h"
#ifdef USE_MYMATH
    #include "math/MathFunctions.h"
#else
    #include <math.h>
#endif
 
int main(int argc, char *argv[])
{
    if (argc < 3){
        printf("Usage: %s base exponent \n", argv[0]);
        return 1;
    }
    double base = atof(argv[1]);
    int exponent = atoi(argv[2]);
 
#ifdef USE_MYMATH
    printf("Now we use our own Math library. \n");
    double result = power(base, exponent);
#else
    printf("Now we use the standard library. \n");
    double result = pow(base, exponent);
#endif
    printf("%g ^ %d is %g\n", base, exponent, result);
    return 0;
}

編寫 config.h.in 文件
注意 main.cc 的第一行，這裏引用了一個 config.h 文件，這個文件預定義了 USE_MYMATH 的值。但我們並不直接編寫這個文件，爲了方便從 CMakeLists.txt 中導入配置，我們編寫一個 config.h.in 文件，內容如下：

#cmakedefine USE_MYMATH

這樣 cmake 會自動根據 CMakeLists.txt 配置文件中的設置自動生成 config.h 文件。

其它：

NDK 學習系列：Android NDK 從入門到精通（彙總篇）

一篇非常好的csdn上的關於cmake的筆記

一、Cmake 簡介

二、常用命令

1. 指定 cmake 的最小版本

2. 設置項目名稱

3. 設置編譯類型

4. 指定編譯包含的源文件

5. 查找指定的庫文件

6. 設置包含的目錄

7. 設置鏈接庫搜索目錄

8. 設置 target 需要鏈接的庫

9. 設置變量

10. 條件控制

11. 打印信息

12. 包含其它 cmake 文件

三、常用變量

1. 預定義變量

2. 環境變量

3. 系統信息

4. 主要開關選項

四、項目示例

1. 簡單項目（單個源文件）

2. 複雜項目（多個目錄，多個源文件，多個項目）

3. 自定義編譯選項

【面試準備】又一次失敗的面試經歷，題目離譜～資深軟件測試工程師

dotnet 8 版本與銀河麒麟V10和UOS系統的 glibc 兼容性

js同步語法

一篇非常好的csdn上的關於cmake的筆記

關於zend內存管理的學習

c++ 模板顯示實參的參數類型推斷

linux排查dll錯誤的一次總結

https://yachay.unat.edu.pe/blog/index.php?comment_area=format_blog&comment_component=blog&comment_co

linux以太網驅動總結