使用存儲過程發送郵件

CREATE OR REPLACE PROCEDURE PROCSENDEMAIL(P_TXT       VARCHAR2,
                                          P_SUB       VARCHAR2,
                                          P_SENDOR    VARCHAR2,
                                          P_RECEIVER  VARCHAR2,
                                          P_SERVER    VARCHAR2,
                                          P_PORT      NUMBER DEFAULT 25,
                                          P_NEED_SMTP INT DEFAULT 0,
                                          P_USER      VARCHAR2 DEFAULT NULL,
                                          P_PASS      VARCHAR2 DEFAULT NULL,
                                          P_FILENAME  VARCHAR2 DEFAULT NULL,
                                          P_ENCODE    VARCHAR2 DEFAULT 'bit 7')
  AUTHID CURRENT_USER IS
  L_CRLF          VARCHAR2(2) := UTL_TCP.CRLF;
  L_SENDORADDRESS VARCHAR2(4000);
  L_SPLITE        VARCHAR2(10) := '++';
  BOUNDARY            CONSTANT VARCHAR2(256) := '-----BYSUK';
  FIRST_BOUNDARY      CONSTANT VARCHAR2(256) := '--' || BOUNDARY || L_CRLF;
  LAST_BOUNDARY       CONSTANT VARCHAR2(256) := '--' || BOUNDARY || '--' ||
                                                L_CRLF;
  MULTIPART_MIME_TYPE CONSTANT VARCHAR2(256) := 'multipart/mixed; boundary="' ||
                                                BOUNDARY || '"';
  L_FIL                 BFILE;
  L_FILE_LEN            NUMBER;
  L_MODULO              NUMBER;
  L_PIECES              NUMBER;
  L_FILE_HANDLE         UTL_FILE.FILE_TYPE;
  L_AMT                 BINARY_INTEGER := 672 * 3; /* ensures proper format;   2016 */
  L_FILEPOS             PLS_INTEGER := 1; /* pointer for the file */
  L_CHUNKS              NUMBER;
  L_BUF                 RAW(2100);
  L_DATA                RAW(2100);
  L_MAX_LINE_WIDTH      NUMBER := 54;
  L_DIRECTORY_BASE_NAME VARCHAR2(100) := 'DIR_FOR_SEND_MAIL';
  L_LINE                VARCHAR2(1000);
  L_MESG                VARCHAR2(32767);
  /* 以上部分是發送大二進制附件時用到的變量 */
  TYPE ADDRESS_LIST IS TABLE OF VARCHAR2(100) INDEX BY BINARY_INTEGER;
  MY_ADDRESS_LIST ADDRESS_LIST;
  TYPE ACCT_LIST IS TABLE OF VARCHAR2(100) INDEX BY BINARY_INTEGER;
  MY_ACCT_LIST ACCT_LIST;


  FUNCTION GET_FILE(P_FILE VARCHAR2, P_GET INT) RETURN VARCHAR2 IS
    --p_get=1 表示返回目錄
    --p_get=2 表示返回文件名
    L_FILE VARCHAR2(1000);
  BEGIN
    IF INSTR(P_FILE, '') > 0 THEN
      --windows
      IF P_GET = 1 THEN
        L_FILE := SUBSTR(P_FILE, 1, INSTR(P_FILE, '', -1) - 1);
      ELSIF P_GET = 2 THEN
        L_FILE := SUBSTR(P_FILE, - (LENGTH(P_FILE) - INSTR(P_FILE, '', -1)));
      END IF;
    ELSIF INSTR(P_FILE, '/') > 0 THEN
      --linux/unix
      IF P_GET = 1 THEN
        L_FILE := SUBSTR(P_FILE, 1, INSTR(P_FILE, '/', -1) - 1);
      ELSIF P_GET = 2 THEN
        L_FILE := SUBSTR(P_FILE,
                         - (LENGTH(P_FILE) - INSTR(P_FILE, '/', -1)));
      END IF;
    END IF;
    RETURN L_FILE;
  END;


  PROCEDURE DROP_DIRECTORY(P_DIRECTORY_NAME VARCHAR2) IS
  BEGIN
    EXECUTE IMMEDIATE 'drop directory ' || P_DIRECTORY_NAME;
  EXCEPTION
    WHEN OTHERS THEN
      NULL;
  END;


  PROCEDURE CREATE_DIRECTORY(P_DIRECTORY_NAME VARCHAR2, P_DIR VARCHAR2) IS
  BEGIN
    EXECUTE IMMEDIATE 'create directory ' || P_DIRECTORY_NAME || ' as ''' ||
                      P_DIR || '''';
    EXECUTE IMMEDIATE 'grant read,write on directory ' || P_DIRECTORY_NAME ||
                      ' to public';
  EXCEPTION
    WHEN OTHERS THEN
      RAISE;
  END;


  
  PROCEDURE P_SPLITE_STR(P_STR VARCHAR2, P_SPLITE_FLAG INT DEFAULT 1) IS
    L_ADDR VARCHAR2(254) := '';
    L_LEN  INT;
    L_STR  VARCHAR2(4000);
    J      INT := 0; --表示郵件地址或者附件的個數
  BEGIN
    /*處理接收郵件地址列表,包括去空格、將;轉換爲,等*/
    L_STR := TRIM(RTRIM(REPLACE(REPLACE(P_STR, ';', ','), ' ', ''), ','));
    L_LEN := LENGTH(L_STR);
    FOR I IN 1 .. L_LEN LOOP
      IF SUBSTR(L_STR, I, 1) <> ',' THEN
        L_ADDR := L_ADDR || SUBSTR(L_STR, I, 1);
      ELSE
        J := J + 1;
        IF P_SPLITE_FLAG = 1 THEN
          --表示處理郵件地址
          --前後需要加上'<>',否則很多郵箱將不能發送郵件
          L_ADDR := '<' || L_ADDR || '>';
          --調用郵件發送過程
          MY_ADDRESS_LIST(J) := L_ADDR;
        ELSIF P_SPLITE_FLAG = 2 THEN
          --表示處理附件名稱
          MY_ACCT_LIST(J) := L_ADDR;
        END IF;
        L_ADDR := '';
      END IF;
      IF I = L_LEN THEN
        J := J + 1;
        IF P_SPLITE_FLAG = 1 THEN
          --調用郵件發送過程
          L_ADDR := '<' || L_ADDR || '>';
          MY_ADDRESS_LIST(J) := L_ADDR;
        ELSIF P_SPLITE_FLAG = 2 THEN
          MY_ACCT_LIST(J) := L_ADDR;
        END IF;
      END IF;
    END LOOP;
  END;


  
  PROCEDURE WRITE_DATA(P_CONN   IN OUT NOCOPY UTL_SMTP.CONNECTION,
                       P_NAME   IN VARCHAR2,
                       P_VALUE  IN VARCHAR2,
                       P_SPLITE VARCHAR2 DEFAULT ':',
                       P_CRLF   VARCHAR2 DEFAULT L_CRLF) IS
  BEGIN
    /* utl_raw.cast_to_raw 對解決中文亂碼問題很重要*/
    UTL_SMTP.WRITE_RAW_DATA(P_CONN,
                            UTL_RAW.CAST_TO_RAW(CONVERT(P_NAME || P_SPLITE ||
                                                        P_VALUE || P_CRLF,
                                                        'ZHS16GBK')));
  END;


  
  PROCEDURE END_BOUNDARY(CONN IN OUT NOCOPY UTL_SMTP.CONNECTION,
                         LAST IN BOOLEAN DEFAULT FALSE) IS
  BEGIN
    UTL_SMTP.WRITE_DATA(CONN, UTL_TCP.CRLF);
    IF (LAST) THEN
      UTL_SMTP.WRITE_DATA(CONN, LAST_BOUNDARY);
    END IF;
  END;


  
  PROCEDURE ATTACHMENT(CONN         IN OUT NOCOPY UTL_SMTP.CONNECTION,
                       MIME_TYPE    IN VARCHAR2 DEFAULT 'text/plain',
                       INLINE       IN BOOLEAN DEFAULT TRUE,
                       FILENAME     IN VARCHAR2 DEFAULT 't.txt',
                       TRANSFER_ENC IN VARCHAR2 DEFAULT '7 bit',
                       DT_NAME      IN VARCHAR2 DEFAULT '0') IS
 
    L_FILENAME VARCHAR2(1000);
  BEGIN
    --寫附件頭
    UTL_SMTP.WRITE_DATA(CONN, FIRST_BOUNDARY);
    --設置附件格式
    WRITE_DATA(CONN, 'Content-Type', MIME_TYPE);
    --如果文件名稱非空,表示有附件
    DROP_DIRECTORY(DT_NAME);
    --創建directory
    CREATE_DIRECTORY(DT_NAME, GET_FILE(FILENAME, 1));
    --得到附件文件名稱
    L_FILENAME := GET_FILE(FILENAME, 2);
    IF (INLINE) THEN
      WRITE_DATA(CONN,
                 'Content-Disposition',
                 'inline; filename="' || L_FILENAME || '"');
    ELSE
      WRITE_DATA(CONN,
                 'Content-Disposition',
                 'attachment; filename="' || L_FILENAME || '"');
    END IF;
    --設置附件的轉換格式
    IF (TRANSFER_ENC IS NOT NULL) THEN
      WRITE_DATA(CONN, 'Content-Transfer-Encoding', TRANSFER_ENC);
    END IF;
 
    UTL_SMTP.WRITE_DATA(CONN, UTL_TCP.CRLF);
 
    --begin 貼附件內容
    IF TRANSFER_ENC = 'bit 7' THEN
      --如果是文本類型的附件
      BEGIN
        L_FILE_HANDLE := UTL_FILE.FOPEN(DT_NAME, L_FILENAME, 'r'); --打開文件
        --把附件分成多份,這樣可以發送超過32K的附件
        LOOP
          UTL_FILE.GET_LINE(L_FILE_HANDLE, L_LINE);
          L_MESG := L_LINE || L_CRLF;
          WRITE_DATA(CONN, '', L_MESG, '', '');
        END LOOP;
        UTL_FILE.FCLOSE(L_FILE_HANDLE);
        END_BOUNDARY(CONN);
      EXCEPTION
        WHEN OTHERS THEN
          UTL_FILE.FCLOSE(L_FILE_HANDLE);
          END_BOUNDARY(CONN);
          NULL;
      END; --結束文本類型附件的處理
 
    ELSIF TRANSFER_ENC = 'base64' THEN
      --如果是二進制類型的附件
      BEGIN
        --把附件分成多份,這樣可以發送超過32K的附件
        L_FILEPOS  := 1; --重置offset,在發送多個附件時,必須重置
        L_FIL      := BFILENAME(DT_NAME, L_FILENAME);
        L_FILE_LEN := DBMS_LOB.GETLENGTH(L_FIL);
        L_MODULO   := MOD(L_FILE_LEN, L_AMT);
        L_PIECES   := TRUNC(L_FILE_LEN / L_AMT);
        IF (L_MODULO <> 0) THEN
          L_PIECES := L_PIECES + 1;
        END IF;
        DBMS_LOB.FILEOPEN(L_FIL, DBMS_LOB.FILE_READONLY);
        DBMS_LOB.READ(L_FIL, L_AMT, L_FILEPOS, L_BUF);
        L_DATA := NULL;
        FOR I IN 1 .. L_PIECES LOOP
          L_FILEPOS  := I * L_AMT + 1;
          L_FILE_LEN := L_FILE_LEN - L_AMT;
          L_DATA     := UTL_RAW.CONCAT(L_DATA, L_BUF);
          L_CHUNKS   := TRUNC(UTL_RAW.LENGTH(L_DATA) / L_MAX_LINE_WIDTH);
          IF (I <> L_PIECES) THEN
            L_CHUNKS := L_CHUNKS - 1;
          END IF;
          UTL_SMTP.WRITE_RAW_DATA(CONN, UTL_ENCODE.BASE64_ENCODE(L_DATA));
          L_DATA := NULL;
          IF (L_FILE_LEN < L_AMT AND L_FILE_LEN > 0) THEN
            L_AMT := L_FILE_LEN;
          END IF;
          DBMS_LOB.READ(L_FIL, L_AMT, L_FILEPOS, L_BUF);
        END LOOP;
        DBMS_LOB.FILECLOSE(L_FIL);
        END_BOUNDARY(CONN);
      EXCEPTION
        WHEN OTHERS THEN
          DBMS_LOB.FILECLOSE(L_FIL);
          END_BOUNDARY(CONN);
          RAISE;
      END; --結束處理二進制附件
 
    END IF; --結束處理附件內容
    DROP_DIRECTORY(DT_NAME);
  END; --結束過程ATTACHMENT


  
  PROCEDURE P_EMAIL(P_SENDORADDRESS2   VARCHAR2, --發送地址
                    P_RECEIVERADDRESS2 VARCHAR2) --接受地址
   IS
    L_CONN UTL_SMTP.CONNECTION; --定義連接
  BEGIN
    /*初始化郵件服務器信息,連接郵件服務器*/
    L_CONN := UTL_SMTP.OPEN_CONNECTION(P_SERVER, P_PORT);
    UTL_SMTP.HELO(L_CONN, P_SERVER);
    /* smtp服務器登錄校驗 */
    IF P_NEED_SMTP = 1 THEN
      UTL_SMTP.COMMAND(L_CONN, 'AUTH LOGIN', '');
      UTL_SMTP.COMMAND(L_CONN,
                       UTL_RAW.CAST_TO_VARCHAR2(UTL_ENCODE.BASE64_ENCODE(UTL_RAW.CAST_TO_RAW(P_USER))));
      UTL_SMTP.COMMAND(L_CONN,
                       UTL_RAW.CAST_TO_VARCHAR2(UTL_ENCODE.BASE64_ENCODE(UTL_RAW.CAST_TO_RAW(P_PASS))));
    END IF;
 
    /*設置發送地址和接收地址*/
    UTL_SMTP.MAIL(L_CONN, P_SENDORADDRESS2);
    UTL_SMTP.RCPT(L_CONN, P_RECEIVERADDRESS2);
 
    /*設置郵件頭*/
    UTL_SMTP.OPEN_DATA(L_CONN);
 
    WRITE_DATA(L_CONN, 'Date', TO_CHAR(SYSDATE, 'yyyy-mm-dd hh24:mi:ss'));
    /*設置發送人*/
    WRITE_DATA(L_CONN, 'From', P_SENDOR);
    /*設置接收人*/
    WRITE_DATA(L_CONN, 'To', P_RECEIVER);
    /*設置郵件主題*/
    WRITE_DATA(L_CONN, 'Subject', P_SUB);
 
    WRITE_DATA(L_CONN, 'Content-Type', MULTIPART_MIME_TYPE);
    UTL_SMTP.WRITE_DATA(L_CONN, UTL_TCP.CRLF);
    UTL_SMTP.WRITE_DATA(L_CONN, FIRST_BOUNDARY);
    WRITE_DATA(L_CONN, 'Content-Type', 'text/plain;charset=gb2312');
    --單獨空一行,否則,正文內容不顯示
    UTL_SMTP.WRITE_DATA(L_CONN, UTL_TCP.CRLF);
    /* 設置郵件正文
      把分隔符還原成chr(10)。這主要是爲了shell中調用該過程,如果有多行,則先把多行的內容合併成一行,並用 l_splite分隔
      然後用 l_crlf替換chr(10)。這一步是必須的,否則將不能發送郵件正文有多行的郵件
    */
    WRITE_DATA(L_CONN,
               '',
               REPLACE(REPLACE(P_TXT, L_SPLITE, CHR(10)), CHR(10), L_CRLF),
               '',
               '');
    END_BOUNDARY(L_CONN);
 
    --如果文件名稱不爲空,則發送附件
    IF (P_FILENAME IS NOT NULL) THEN
      --根據逗號或者分號拆分附件地址
      P_SPLITE_STR(P_FILENAME, 2);
      --循環發送附件(在同一個郵件中)
      FOR K IN 1 .. MY_ACCT_LIST.COUNT LOOP
        ATTACHMENT(CONN         => L_CONN,
                   FILENAME     => MY_ACCT_LIST(K),
                   TRANSFER_ENC => P_ENCODE,
                   DT_NAME      => L_DIRECTORY_BASE_NAME || TO_CHAR(K));
      END LOOP;
    END IF;
 
    /*關閉數據寫入*/
    UTL_SMTP.CLOSE_DATA(L_CONN);
    /*關閉連接*/
    UTL_SMTP.QUIT(L_CONN);
 
    /*異常處理*/
  EXCEPTION
    WHEN OTHERS THEN
      NULL;
      RAISE;


  END;
BEGIN
  L_SENDORADDRESS := '<' || P_SENDOR || '>';
  P_SPLITE_STR(P_RECEIVER); --處理郵件地址
  FOR K IN 1 .. MY_ADDRESS_LIST.COUNT LOOP
    P_EMAIL(L_SENDORADDRESS, MY_ADDRESS_LIST(K));
  END LOOP;
  /*處理郵件地址,根據逗號分割郵件*/
EXCEPTION
  WHEN OTHERS THEN
    RAISE;
END;


exec PROCSENDEMAIL('郵件內容','郵件主題','發件人','收件人','郵件服務器ip地址',25,1,'用戶名','密碼','','base64');

exec PROCSENDEMAIL('neirong','zhuti','[email protected]','[email protected]','smtp.vip.com',25,1,'[email protected]','password','','base64');

發表評論
所有評論
還沒有人評論,想成為第一個評論的人麼? 請在上方評論欄輸入並且點擊發布.
相關文章