下面貼出本工具中用到的關閉本地計算機共享目錄的代碼(與其相對應的創建共享的代碼也整理出來一同貼上)，實際上用這個代碼還可以關閉網絡中其他計算機的共享目錄，但要保證有足夠的權限(至少可以通過網上鄰居正常訪問到對方計算機)。創建或刪除本機的共享目錄，用127.0.0.1就可以了。
代碼如下：
Option Explicit
'共享類型
Private Const STYPE_ALL As Long = -1
Private Const STYPE_DISKTREE As Long = 0
Private Const STYPE_PRINTQ As Long = 1
Private Const STYPE_DEVICE As Long = 2
Private Const STYPE_IPC As Long = 3
Private Const STYPE_SPECIAL As Long = &H80000000
'共享權限
Private Const ACCESS_READ As Long = &H1
Private Const ACCESS_WRITE As Long = &H2
Private Const ACCESS_CREATE As Long = &H4
Private Const ACCESS_EXEC As Long = &H8
Private Const ACCESS_DELETE As Long = &H10
Private Const ACCESS_ATRIB As Long = &H20
Private Const ACCESS_PERM As Long = &H40
Private Const ACCESS_ALL As Long = ACCESS_READ Or ACCESS_WRITE Or ACCESS_CREATE Or ACCESS_EXEC Or ACCESS_DELETE Or ACCESS_ATRIB Or ACCESS_PERM
'共享信息
Private Type SHARE_INFO_2
shi2_netname As Long '共享名
shi2_type As Long '類型
shi2_remark As Long '備註
shi2_permissions As Long '權限
shi2_max_uses As Long '最大用戶
shi2_current_uses As Long '
shi2_path As Long '路徑
shi2_passwd As Long '密碼
End Type
Private Declare Function NetShareAdd Lib "netapi32.dll" (ByVal ServerName As Long, ByVal level As Long, buf As Any, Parmerr As Long) As Long
Private Declare Function NetShareDel Lib "netapi32.dll" (ByVal ServerName As Long, ByVal ShareName As Long, ByVal dword As Long) As Long
'設置共享(返回0 爲成功)
Public Function CreateShare(ByVal ServerName As String, ByVal SharePath As String, ByVal ShareName As String, Optional ByVal Password As String, Optional ByVal Remark As String) As Long
Dim pRemark As Long
Dim pPassword As Long
Dim SHI2 As SHARE_INFO_2
If Len(Remark) > 0 Then pRemark = StrPtr(Remark) '備註
If Len(Password) > 0 Then pPassword = StrPtr(Password) '密碼
'初始化共享信息
With SHI2
.shi2_netname = StrPtr(ShareName)
.shi2_path = StrPtr(SharePath)
.shi2_remark = pRemark
.shi2_type = STYPE_DISKTREE
.shi2_permissions = ACCESS_ALL
.shi2_max_uses = -1
.shi2_passwd = pPassword
End With
'設置共享(用戶名,共享類型,共享信息,)
CreateShare = NetShareAdd(StrPtr(ServerName), 2, SHI2, 0)
End Function
'刪除共享(返回0 表示成功)
Public Function DeleteShare(ByVal ServerName As String, ByVal ShareName As String) As Long
DeleteShare = NetShareDel(StrPtr(ServerName), StrPtr(ShareName), 0)
End Function