[轉載]Build a Fluid Website Layout

A fluid web layout uses 100% width (and height) of the browser, floating all the contained elements into certain positions. This is opposed to fix-width layout where contents remain fixed no matter what the browser size is.

This technique is popular in HTML/CSS websites, but this tut will show you how to create a similar fluid layout effect in Flash. Every element will reposition itself with ease animation when the browser resizes.

Author: Makzan

My name is Makzan. I live in Hong Kong, China. I have been a flash developer for 10 years. I enjoy Web Designing and Flash developing. Recently I fall in love with flash/iPhone multiplayer game developing with socket server. You can follow me on Twitter: @makzan or visit my portfolio at FlashDen

Introduction

During the following steps we'll create ActionScript 3 classes which make our flash website fluid. All our display symbols will retain their alignment when the Flash is resized.

The ActionScript classes created in this tutorial can be easily reused in different projects.

Step 1: Background Information of Fluid Layout

As shown in the image below, all the elements which float according to the browser size will be referred to as "fluid objects".

Step 2: Fluid Object Coordinates

Each fluid object will contain alignment parameters. The parameters store the x, y, x offset, y offset value of the object to indicate how it aligns.

Assigning x and y to 0 will make the fluid object align to the top left corner. Assigning x and y to 1 will make the fluid object align to the bottom right corner. Therefore, assignign x and y value between 0 and 1 will float the object at a percentage of the width and height of the browser.

The offset X and Y offset the position of the fluid objects while they align. Offsetting useful when positioning an object whose alignment point is not at the center. The offset is also useful for making margins on the alignment.

Step 3: Create a Directory to Store the Classes

Create a directory called "FluidLayout" in the working directory. This directory will store all classes which relate to the fluid layout classes.

It's a good habit to put the ActionScript class files in directories by category. For example, fluid layout classes will be placed in the "FluidLayout" folder in this case.

Please note that all the directory names, file names and codes are case sensitive.

Step 4: New ActionScript File (FluidObject.as)

Open a new ActionScript file named "FluidObject.as". Save this ActionScript file into the "FluidLayout" directory.

The class FluidObject will store the alignment parameters of the symbols and reposition the symbols when the browser resizes.

Step 5: The Class Skeleton

Let's start coding the FluidObject.as now.

view plaincopy to clipboardprint?

1. package FluidLayout { 
3. /* Add import classes here */
5. public class FluidObject { 
7. /* Declare instance variables here */
9. /* Constructor of the class */
10. public function FluidObject(target:DisplayObject,paramObj:Object) 
11.         { 
12.         } 
14. /* Function that repositions the monitored object */
15. protected function reposition():void
16.         { 
17.         } 
19. /* Function that is called when the RESIZE event is fired */
20. protected function onStageResize(e):void
21.         { 
22.         } 
23.     } 
24. } 

	package FluidLayout {

		/* Add import classes here */

		public class FluidObject {

			/* Declare instance variables here */

			/* Constructor of the class */
			public function FluidObject(target:DisplayObject,paramObj:Object)
			{
			}

			/* Function that repositions the monitored object */
			protected function reposition():void
			{
			}

			/* Function that is called when the RESIZE event is fired */
			protected function onStageResize(e):void
			{
			}
		}
	}

Step 6: Importing Required Classes

Add the following code where you see: /* Add import classes here */

view plaincopy to clipboardprint?

1. /* class needed on resize Event */
2. import flash.events.Event; 
4. /* classes needed for MovieClip and DisplayObject */
5. import flash.display.*; 

	
	/* class needed on resize Event */
	import flash.events.Event;
	
	/* classes needed for MovieClip and DisplayObject */
	import flash.display.*;

Step 7: Declaring Instance Variables

There are three instance variables for this class:

1. "_param" will store the alignment parameters.
2. "_target" will point to the monitored symbol.
3. "_stage" is a copy instance of the flash stage.

There is also a setter for "_param" to enable changing of the alignment parameters. Add the following code where you see: /* Declare instance variables here */

view plaincopy to clipboardprint?

2. /* alignment parameters */
3. protected var _param:Object; 
5. /* target object to be monitored */
6. protected var _target:DisplayObject; 
8. /* stage instance of the flash document */
9. protected var _stage:Stage; 
11. /* Setter for the alignment param */
12. public function set param(value:Object):void { 
13.     _param = value; 
14. this.reposition(); 
15. } 

			
	/* alignment parameters */
	protected var _param:Object;

	/* target object to be monitored */
	protected var _target:DisplayObject;

	/* stage instance of the flash document */
	protected var _stage:Stage;
	
	/* Setter for the alignment param */
	public function set param(value:Object):void {
		_param = value;
		this.reposition();
	}

Step 8: Implementing the Constructor

The constructor will initialize the target monitored symbol and store the given alignment parameters.

view plaincopy to clipboardprint?

1. /* Constructor of the class */
2. public function FluidObject(target:DisplayObject,paramObj:Object) 
3. { 
4. /* Assign the instance variables */
5.     _target = target; 
6.     _param = paramObj; 
7.     _stage = target.stage; 
9. /* add event handler for stage resize */
10.     _stage.addEventListener(Event.RESIZE, onStageResize); 
12. /* reposition the object with the alignment setting applied*/
13. this.reposition(); 
15. } 

	/* Constructor of the class */
	public function FluidObject(target:DisplayObject,paramObj:Object)
	{
		/* Assign the instance variables */
		_target = target;
		_param = paramObj;
		_stage = target.stage;
		
		/* add event handler for stage resize */
		_stage.addEventListener(Event.RESIZE, onStageResize);
		
		/* reposition the object with the alignment setting applied*/
		this.reposition();
		
	}

Step 9: Implementing the Function: reposition()

The repositioning function is in charge of calculating the new x/y position of the monitored fluid object.

view plaincopy to clipboardprint?

1. /* Function that reposition the monitored object */
2. protected function reposition():void
3. { 
4. /* get the current width and height of the flash document */
5. var stageW = _stage.stageWidth; 
6. var stageH = _stage.stageHeight; 
8. /* update the x and y value of the monitored object */
9.     _target.x = (stageW * _param.x) + _param.offsetX; 
10.     _target.y = (stageH * _param.y) + _param.offsetY; 
12. } 

	/* Function that reposition the monitored object */
	protected function reposition():void
	{
		/* get the current width and height of the flash document */
		var stageW = _stage.stageWidth;
		var stageH = _stage.stageHeight;
		
		/* update the x and y value of the monitored object */
		_target.x = (stageW * _param.x) + _param.offsetX;
		_target.y = (stageH * _param.y) + _param.offsetY;
		
	}

Step 10: Implementing the Function: onStageResize

The onStageResize function is an event handler which is called when the browser resizes.

view plaincopy to clipboardprint?

1. /* Function that is called when the RESIZE event is fired */
2. protected function onStageResize(e):void
3. { 
4. /* reposition the target */
5. this.reposition(); 
6. } 

	/* Function that is called when the RESIZE event is fired */
	protected function onStageResize(e):void
	{
		/* reposition the target */
		this.reposition();
	}

Step 11: The Completed Class: FluidObject.as

The finished class FluidObject is finished in this step.

view plaincopy to clipboardprint?

1. package FluidLayout { 
3. /* class needed on resize Event */
4. import flash.events.Event; 
6. /* classes needed for MovieClip and DisplayObject */
7. import flash.display.*; 
9. public class FluidObject { 
11. /* alignment parameters */
12. protected var _param:Object; 
14. /* target object to be monitored */
15. protected var _target:DisplayObject; 
17. /* stage instance of the flash document */
18. protected var _stage:Stage; 
20. /* Setter for the alignment param */
21. public function set param(value:Object):void { 
22.             _param=value; 
23. this.reposition(); 
24.         } 
26. /* Constructor of the class */
27. public function FluidObject(target:DisplayObject,paramObj:Object) 
28.         { 
29. /* Assign the instance variables */
30.             _target = target; 
31.             _param = paramObj; 
32.             _stage = target.stage; 
34. /* add event handler for stage resize */
35.             _stage.addEventListener(Event.RESIZE, onStageResize); 
37. /* reposition the object with the alignment setting applied*/
38. this.reposition(); 
40.         } 
42. /* Function that repositions the monitored object */
43. protected function reposition():void
44.         { 
45. /* get the current width and height of the flash document */
46. var stageW = _stage.stageWidth; 
47. var stageH = _stage.stageHeight; 
49. /* update the x and y value of the monitored object */
50.             _target.x = (stageW * _param.x) + _param.offsetX; 
51.             _target.y = (stageH * _param.y) + _param.offsetY; 
53.         } 
55. /* Function that is called when the RESIZE event is fired */
56. protected function onStageResize(e):void
57.         { 
58. /* reposition the target */
59. this.reposition(); 
60.         } 
62.     } 
64. } 

package FluidLayout {
	
	/* class needed on resize Event */
	import flash.events.Event;
	
	/* classes needed for MovieClip and DisplayObject */
	import flash.display.*;

	public class FluidObject {
		
		/* alignment parameters */
		protected var _param:Object;
		
		/* target object to be monitored */
		protected var _target:DisplayObject;
		
		/* stage instance of the flash document */
		protected var _stage:Stage;
		
		/* Setter for the alignment param */
		public function set param(value:Object):void {
			_param=value;
			this.reposition();
		}
		
		/* Constructor of the class */
		public function FluidObject(target:DisplayObject,paramObj:Object)
		{
			/* Assign the instance variables */
			_target = target;
			_param = paramObj;
			_stage = target.stage;
			
			/* add event handler for stage resize */
			_stage.addEventListener(Event.RESIZE, onStageResize);
			
			/* reposition the object with the alignment setting applied*/
			this.reposition();
			
		}
		
		/* Function that repositions the monitored object */
		protected function reposition():void
		{
			/* get the current width and height of the flash document */
			var stageW = _stage.stageWidth;
			var stageH = _stage.stageHeight;
			
			/* update the x and y value of the monitored object */
			_target.x = (stageW * _param.x) + _param.offsetX;
			_target.y = (stageH * _param.y) + _param.offsetY;
			
		}
		
		/* Function that is called when the RESIZE event is fired */
		protected function onStageResize(e):void
		{
			/* reposition the target */
			this.reposition();
		}

	}

}

Step 12: Time to Create a Flash File

Begin a new Flash Document with ActionScript 3.0 supported and call it "website.fla". Then set the Document class as "Website".

If a dialog box pops up with the message: "A definition for the document class could not be found in the classpath,..." just click "OK" to bypass it. We're going to create that class after drawing the graphic symbols.

The background image will be dark in this tutorial (I've put together my own space-like image using Photoshop). Therefore the background color of the flash document needs to set to black. Click Modify > Document to open the Document Properties dialog and change the background color.

Step 13: Draw the Title Symbol

There will be 5 flash symbols on the stage:

• background
• title
• menu
• middle content
• footer

Let's make the title first. The aim of this tutorial is to create floating symbols in the fluid layout rather then creating fancy website components. The symbols will only contain a text field indicating the purpose only.

For the title symbol, there's a semi-transparent background. In order to fit different widths of the browser, the width of the background need to be large enough.

After having finished drawing the symbol, click Modify > Convert to Symbol (F8). Click the "Advanced" button to show detailed settings for the symbol.

Click "Export for ActionScript" to enable the ActionScript to access this symbol. Then find the "Class" field in the dialog and set the value to "Title" for the title symbol. This means that we've assigned a new Class called "Title" to this symbol. We can use this symbol later in the ActionScript.

Remember to name your symbol for easy recognition before you click OK. If a dialog box pops up with the message "A definition for this class could not be found in the classpath,..." again, just click "OK" to bypass it. Since we'll not add any behavior to the symbol, we'll let Flash create an empty class for us.

Step 14: Draw the Other Symbols

Delete the "title" symbol instance on stage because it will be created by ActionScript later.

We'll use the same method to draw "background", "menu", "middle content" and "footer". The class name of these symbols will be Background, Menu, Middle and Footer accordingly.

The background image can be downloaded from the source files. Other symbols are text-field only.

Step 15: Code the Document Class ActionScript

Create an ActionScript file and named as "Website.as"; this class file should be saved in the same directory as the website.fla file.

This class must also share the same name as that set in the Document Class (refer to Step 12). For example, the Document Class "Website" refers to "Website.as" in the same directory. This ActionScript class will be loaded right after the flash is loaded.

Here is the skeleton of the Document Class:

view plaincopy to clipboardprint?

1. package { 
3. import flash.display.*; 
4. import FluidLayout.*; 
6. public class Website extends MovieClip{ 
8. public function Website() 
9.         { 
10.         }    
11.     } 
12. } 

package {

	import flash.display.*;
	import FluidLayout.*;
	
	public class Website extends MovieClip{
	
		public function Website()
		{
		}	
	}
}

Step 16: Implementing the Constructor

view plaincopy to clipboardprint?

1. package { 
3. import flash.display.*; 
4. import FluidLayout.*; 
6. public class Website extends MovieClip{ 
8. public function Website() 
9.         { 
10. /* Set the Scale Mode of the Stage */
11.             stage.scaleMode = StageScaleMode.NO_SCALE; 
12.             stage.align = StageAlign.TOP_LEFT; 
14. /* Add the symbols to stage */
15. var bg = new Background(); 
16.             addChild(bg); 
18. var title = new Title(); 
19.             addChild(title); 
21. var menu = new Menu(); 
22.             addChild(menu); 
24. var middle = new Middle(); 
25.             addChild(middle); 
27. var footer = new Footer(); 
28.             addChild(footer); 
30. /* Apply the alignment to the background */
31. var bgParam = { 
32.                 x:0, 
33.                 y:0, 
34.                 offsetX: 0, 
35.                 offsetY: 0 
36.             } 
37. new FluidObject(bg,bgParam); 
39. /* Apply the alignment to the title */
40. var titleParam = { 
41.                 x:0, 
42.                 y:0, 
43.                 offsetX:0, 
44.                 offsetY:0 
45.             } 
46. new FluidObject(title,titleParam); 
48. /* Apply the alignment to the menu */
49. var menuParam = { 
50.                 x:1, 
51.                 y:0, 
52.                 offsetX: -menu.width - 20, 
53.                 offsetY: 20 
54.             } 
55. new FluidObject(menu,menuParam); 
57. /* Apply the alignment to the content */
58. var middleParam = { 
59.                 x:0.5, 
60.                 y:0.5, 
61.                 offsetX: -middle.width/2, 
62.                 offsetY: -middle.height/2 
63.             } 
64. new FluidObject(middle,middleParam); 
66. /* Apply the alignment to the footer */
67. var footerParam = { 
68.                 x:1, 
69.                 y:1, 
70.                 offsetX: -footer.width - 10, 
71.                 offsetY: -footer.height -10 
72.             } 
73. new FluidObject(footer,footerParam); 
74.         } 
75.     } 
76. } 

package {

	import flash.display.*;
	import FluidLayout.*;
	
	public class Website extends MovieClip{
		
		public function Website()
		{
			/* Set the Scale Mode of the Stage */
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.align = StageAlign.TOP_LEFT;
			
			/* Add the symbols to stage */
			var bg = new Background();
			addChild(bg);
			
			var title = new Title();
			addChild(title);
		
			var menu = new Menu();
			addChild(menu);
		
			var middle = new Middle();
			addChild(middle);
		
			var footer = new Footer();
			addChild(footer);
			
			/* Apply the alignment to the background */
			var bgParam = {
				x:0,
				y:0,
				offsetX: 0,
				offsetY: 0
			}
			new FluidObject(bg,bgParam);
				
			/* Apply the alignment to the title */
			var titleParam = {
				x:0,
				y:0,
				offsetX:0,
				offsetY:0
			}
			new FluidObject(title,titleParam);
		
			/* Apply the alignment to the menu */
			var menuParam = {
				x:1,
				y:0,
				offsetX: -menu.width - 20,
				offsetY: 20
			}
			new FluidObject(menu,menuParam);
		
			/* Apply the alignment to the content */
			var middleParam = {
				x:0.5,
				y:0.5,
				offsetX: -middle.width/2,
				offsetY: -middle.height/2
			}
			new FluidObject(middle,middleParam);
		
			/* Apply the alignment to the footer */
			var footerParam = {
				x:1,
				y:1,
				offsetX: -footer.width - 10,
				offsetY: -footer.height -10
			}
			new FluidObject(footer,footerParam);
		}
	}
}

Step 17: Ensure All Assets are Ready

Open website.fla in Flash and check again before texting the movie.

There's no need to place the symbols on the stage because the Website.as will create symbol instances from library by using their class names. The linkage class names of the symbols needs to be correct in order for the script to use them. The linkage class name can be checked in the library panel.

Step 18: Ready to View the Result

Click Control > Text Movie or Ctrl(Cmd) + Enter to test the flash website.

Try resizing the window and check if all objects are repositioning to the correct alignment.

Step 19: Further Work

Each FluidObject now needs to have specific x,y,offsetX and offsetY property values. A new Class will be created in the coming steps to simplify the future code when adding new fluid objects.

Step 20: SimpleFluidObject Class

Open a new ActionScript file named "SimpleFluidObject.as". Save this file inside the "FluidLayout" directory because this is part of the FluidLayout package.

This file extends FluidObject class so that it will provides simple alignment by using names like TOP, MIDDLE, BOTTOM_RIGHT instead of specifying the x,y properties.

Here is the skeleton of the class:

view plaincopy to clipboardprint?

1. package FluidLayout { 
3. import flash.events.Event; 
4. import flash.display.*; 
6. public class SimpleFluidObject extends FluidObject{ 
8. public function SimpleFluidObject(target:DisplayObject,paramObj:Object) 
9.         { 
10.         } 
11.     } 
12. } 

package FluidLayout {
	
	import flash.events.Event;
	import flash.display.*;

	public class SimpleFluidObject extends FluidObject{

		public function SimpleFluidObject(target:DisplayObject,paramObj:Object)
		{
		}
	}
}

Step 21: Implementing the Constructor

view plaincopy to clipboardprint?

1. package FluidLayout { 
3. import flash.events.Event; 
4. import flash.display.*; 
6. public class SimpleFluidObject extends FluidObject{ 
8. public function SimpleFluidObject(target:DisplayObject,paramObj:Object) 
9.         { 
10. /* Tell parent class to init the constructor */
11. super(target,paramObj); 
13. /* assign alignment and margin value by the constructor parameters */
14. var alignment = paramObj.alignment; 
15. var margin = paramObj.margin; 
17. /* Preset the alignment and margin value if need */
18. if (alignment == undefined) alignment = "MIDDLE"; 
19. if (margin == undefined) margin = 0; 
21. /* convert the alignment (eg. "TOP", "BOTTOM_RIGHT") to x, y, offsetX and offsetY */
22. var params = new Object(); 
23. switch (alignment){ 
24. case "TOP_LEFT": 
25.                 params = { 
26.                     x:0, 
27.                     y:0, 
28.                     offsetX: margin, 
29.                     offsetY: margin 
30.                     }; 
31. break; 
32. case "TOP": 
33.                 params = { 
34.                     x:.5, 
35.                     y:0, 
36.                     offsetX: -target.width/2, 
37.                     offsetY: margin 
38.                     }; 
39. break; 
40. case "TOP_RIGHT": 
41.                 params = { 
42.                     x:1, 
43.                     y:0, 
44.                     offsetX: -target.width - margin, 
45.                     offsetY: margin 
46.                     }; 
47. break; 
48. case "LEFT": 
49.                 params = { 
50.                     x:0, 
51.                     y:.5, 
52.                     offsetX: margin, 
53.                     offsetY: -target.height/2 
54.                     }; 
55. break; 
56. case "MIDDLE": 
57.                 params = { 
58.                     x:.5, 
59.                     y:.5, 
60.                     offsetX: -target.width/2 - margin/2, 
61.                     offsetY: -target.height/2 - margin/2 
62.                     }; 
63. break; 
64. case "RIGHT": 
65.                 params = { 
66.                     x:1, 
67.                     y:.5, 
68.                     offsetX: -target.width - margin, 
69.                     offsetY: -target.height/2 
70.                     }; 
71. break; 
72. case "BOTTOM_LEFT": 
73.                 params = { 
74.                     x:0, 
75.                     y:1, 
76.                     offsetX: margin, 
77.                     offsetY: -target.height - margin 
78.                     }; 
79. break; 
80. case "BOTTOM": 
81.                 params = { 
82.                     x:.5, 
83.                     y:1, 
84.                     offsetX: -target.width/2, 
85.                     offsetY: -target.height - margin 
86.                     }; 
87. break; 
88. case "BOTTOM_RIGHT": 
89.                 params = { 
90.                     x:1, 
91.                     y:1, 
92.                     offsetX: -target.width - margin, 
93.                     offsetY: -target.height - margin 
94.                     }; 
95. break; 
96.             } 
97.             _param = params;             
100. /* reposition the fluid object to the right position */
101. this.reposition(); 
102.         } 
103.     } 
104. } 

package FluidLayout {
	
	import flash.events.Event;
	import flash.display.*;

	public class SimpleFluidObject extends FluidObject{

		public function SimpleFluidObject(target:DisplayObject,paramObj:Object)
		{
			/* Tell parent class to init the constructor */
			super(target,paramObj);
			
			/* assign alignment and margin value by the constructor parameters */
			var alignment = paramObj.alignment;
			var margin = paramObj.margin;
			
			/* Preset the alignment and margin value if need */
			if (alignment == undefined) alignment = "MIDDLE";
			if (margin == undefined) margin = 0;
			
			/* convert the alignment (eg. "TOP", "BOTTOM_RIGHT") to x, y, offsetX and offsetY */
			var params = new Object();
			switch (alignment){
				case "TOP_LEFT":
				params = {
					x:0,
					y:0,
					offsetX: margin,
					offsetY: margin
					};
				break;
				case "TOP":
				params = {
					x:.5,
					y:0,
					offsetX: -target.width/2,
					offsetY: margin
					};
				break;
				case "TOP_RIGHT":
				params = {
					x:1,
					y:0,
					offsetX: -target.width - margin,
					offsetY: margin
					};
				break;
				case "LEFT":
				params = {
					x:0,
					y:.5,
					offsetX: margin,
					offsetY: -target.height/2
					};
				break;
				case "MIDDLE":
				params = {
					x:.5,
					y:.5,
					offsetX: -target.width/2 - margin/2,
					offsetY: -target.height/2 - margin/2
					};
				break;
				case "RIGHT":
				params = {
					x:1,
					y:.5,
					offsetX: -target.width - margin,
					offsetY: -target.height/2
					};
				break;
				case "BOTTOM_LEFT":
				params = {
					x:0,
					y:1,
					offsetX: margin,
					offsetY: -target.height - margin
					};
				break;
				case "BOTTOM":
				params = {
					x:.5,
					y:1,
					offsetX: -target.width/2,
					offsetY: -target.height - margin
					};
				break;
				case "BOTTOM_RIGHT":
				params = {
					x:1,
					y:1,
					offsetX: -target.width - margin,
					offsetY: -target.height - margin
					};
				break;
			}
			_param = params;			
			

			/* reposition the fluid object to the right position */
			this.reposition();
		}
	}
}

Step 22: New Usage of the Fluid Objects

Refer to the Website.as file and try using the new alignment method to align the fluid objects.

The Old Method to apply alignment to Title:

view plaincopy to clipboardprint?

1. /* Apply the alignment to the title */
2. var titleParam = { 
3.     x:0, 
4.     y:0, 
5.     offsetX:0, 
6.     offsetY:0 
7. } 
8. new FluidObject(title,titleParam); 

/* Apply the alignment to the title */
var titleParam = {
	x:0,
	y:0,
	offsetX:0,
	offsetY:0
}
new FluidObject(title,titleParam);

The New Method to apply alignment to Title:

view plaincopy to clipboardprint?

1. var titleParam = { 
2.     alignment: "TOP_LEFT", 
3.     margin: 0 
4. } 
5. new SimpleFluidObject(title,titleParam); 

var titleParam = {
	alignment: "TOP_LEFT",
	margin: 0
}
new SimpleFluidObject(title,titleParam);

Available alignments:

• TOP_LEFT, TOP, TOP_RIGHT
• LEFT, MIDDLE, RIGHT
• BOTTOM_LEFT, BOTTOM, BOTTOM_RIGHT

Step 23: The Published HTML

Now the fluid alignment works on the "Test Movie" in Flash IDE, but there is one key point to make this work on browser.

Open website.fla. Go to File > Publish Settings and ensure HTML is enabled. Click the HTML tab and change the dimension to "Percent". Ensure the percent is set to 100 on both width and height.

Click "Publish" to publish the website as "website.swf" and "website.html" files.

Now open the "website.html" file with your favorite text editor and add the following code in the header. Adding the code right after the tag would be a good choice.

These CSS styles eliminate the gap between the top left side of the HTML and the SWF file.

view plaincopy to clipboardprint?

2. body{ 
3. margin:0; 
4. padding:0; 
5. } 
6.  

Step 24: Advanced Technique: Adding Easing

An easing effect can be applied when the browser resizes so that the objects will move to the correct position with an ease out effect.

Open "FluidObject.as". Add the following lines after "import flash.display.*;". These lines will import the tweening animation class to give the code ability to ease the objects.

view plaincopy to clipboardprint?

1. /* classes needed for Easing Animation */
2. import fl.transitions.Tween; 
3. import fl.transitions.easing.*; 

	/* classes needed for Easing Animation */
	import fl.transitions.Tween;
	import fl.transitions.easing.*;

Then find the following lines in the "FluidObject.as" file. They are within the "reposition" function.

1. _target.x=stageW*_param.x+_param.offsetX; 
2. _target.y=stageH*_param.y+_param.offsetY; 

	_target.x=stageW*_param.x+_param.offsetX;
	_target.y=stageH*_param.y+_param.offsetY;

Replace them with the following code:

view plaincopy to clipboardprint?

1. /* set the duration of the easing animation (seconds) */
2. var duration = 0.5; 
4. /* declare the new X/Y value */
5. var newX = _target.x; 
6. var newY = _target.y; 
8. /* calculate the new X value based on the stage Width */
9. if (_param.x != undefined){ 
10.     newX = (stageW * _param.x) + _param.offsetX; 
11. } 
13. /* calculate the new Y value based on the stage Height */
14. if (_param.y != undefined){ 
15.     newY = (stageH * _param.y) + _param.offsetY; 
16. } 
18. /* Tell flash to tween the target object to the new X/Y position */
19. new Tween(_target, "x",Strong.easeOut,_target.x,newX,duration,true); 
20. new Tween(_target, "y",Strong.easeOut,_target.y,newY,duration,true); 

	/* set the duration of the easing animation (seconds) */
	var duration = 0.5;
	
	/* declare the new X/Y value */
	var newX = _target.x;
	var newY = _target.y;
	
	/* calculate the new X value based on the stage Width */
	if (_param.x != undefined){
		newX = (stageW * _param.x) + _param.offsetX;
	}
	
	/* calculate the new Y value based on the stage Height */
	if (_param.y != undefined){
		newY = (stageH * _param.y) + _param.offsetY;
	}
	
	/* Tell flash to tween the target object to the new X/Y position */
	new Tween(_target, "x",Strong.easeOut,_target.x,newX,duration,true);
	new Tween(_target, "y",Strong.easeOut,_target.y,newY,duration,true);

Test the movie, the objects will be easing when the browser resizes (see example below).

Conclusion

We've just created two classes which are in charge of the floating fluid objects. We also created an example to align different objects on stage by using the classes. This example is only a sample case; you can use your imagination to play with the alignments. For example, a symbol may be interactive and its alignment may change from top to bottom when the user clicks on it.

The file structure should be the same as below after you finish this tutorial. Specifically, the FluidObject.as and SimpleFluidObject.as should be in the "FluidLayout" directory in order to work.

Enjoy the Fluid Layout!