*.pro、*.pri、*.prf、*.prl文件介紹和使用

儘管每次和cmake對比起來，我們總是說 qmake 簡單、功能少。但是qmake仍然是一個非常複雜的東西，我想大多人應該和我一樣吧：

• 不是太清楚CONFIG等變量到底如何起作用的
• 用過的qmake內置變量和函數不超過20個

• 看Qt Creator源碼或者QtSolution等庫中自己使用的 *.pro 文件就想看天書一樣

本文只能抓住一條線，簡單介紹一下 *.pro、*.pri、*.prf、*.prl等四種文件：幹嘛用的，如何用的

*.pro

qmake 的工程(project)文件，這個大家肯定都非常熟悉了。那我就不費話了，上例子：

這是一個典型的Qt示例程序的.pro文件(propriprfprl.pro)：

TEMPLATE = app
CONFIG += QT
QT += core gui
TARGET = propriprfprl
SOURCES += main.cpp/
        widget.cpp
HEADERS  += widget.h
FORMS    += widget.ui

• 前面3行是qmake的默認值，我們都可以省略
• TARGET 這行指定工程名，我們也可以省略

*.pri

i 是什麼東西？包含(include)的首字母。類似於C、C++中的頭文件吧，反正就是我們可以吧 *.pro 文件內的一部分單獨放到一個 *.pri 文件內，然後包含進來。

接前面的例子，我們將源文件的設置獨立出來，放到propriprfprl.pri文件內：

SOURCES += main.cpp/
        widget.cpp
HEADERS  += widget.h
FORMS    += widget.ui

這時，我們的 propriprfprl.pro 文件就可以簡化爲：

TEMPLATE = app
CONFIG += QT
QT += core gui

TARGET = propriprfprl
include(propriprfprl.pri)

• 這有什麼用呢？對我們這個例子來說，確實沒什麼用，反而多了一個文件，更麻煩了。
• 可是，如果一個大點的項目，含有多個*.pro文件呢，這些pro需要有些共同的設置或需要的文件，這時就很有必要了。

*.prf

f又是神馬東東？特性(feature)的首字符

• 和pri文件類似，該文件也是要被包含進pro文件的
• 只是：它更隱蔽
• 你經常和它打交道，可能卻一直視而不見

我們這個例子中其實已經用到了，這就是

CONFIG+=QT

當我們在CONFIG中指定一個東西時，qmake就會嘗試去加載相應的feature文件：

• Qt安裝目錄下的 mkspecs/features/qt.prf
• features 文件的文件名必須小寫
• qmake 去哪些目錄下搜索features文件呢？
  • manual中有介紹，此處略
  • 暫時只知道前面提到的 $$QTDIR/mkspecs/features 就可以了

寫一個自己的features文件：propriprfprl.prf

win32:CONFIG += console

• 爲win32的程序添加控制檯，有點多次一舉哈。
• 將該文件放置到我們前面提到的目錄中

然後在pro文件內添加

CONFIG += propriprfprl

看到和 CONFIG += console 同樣的效果了吧？

注：我們也可以使用 load命令來加載prf文件，比如前面的命令可以認爲等價於

load(propriprfprl)

*.prl

l 這個東西容易理解，鏈接(link)的首字符。主要和生成與使用靜態庫密切相關(動態庫也可以有該文件，去Qt安裝目錄下的lib目錄下看看即可)。

• 生成靜態庫時，我們需要使用下列配置(進而生成和庫文件同名的 *.prl 文件)

CONFIG += create_prl

• 當工程的TEMPLATE爲app時，會自動添加如下指令(找庫文件的時候，會嘗試找相應的 *.prl 文件)

CONFIG += link_pri

那麼該文件有什麼用處呢？舉一個大家可能熟悉的例子QextSerialPort1.2這個庫(windows下的情況)：

• 編譯時，需要 setupapi.lib advapi32.lib user32.lib 這幾個庫文件
• 編譯成靜態庫以後，它本身是不包含這3個庫文件信息的

• 於是，當我們使用這個 QextSerialPort 靜態庫，還是需要指定 這幾個庫文件

如果有prl文件呢，該文件就會包含依賴信息了，我們看一下：

QMAKE_PRL_BUILD_DIR = E:/dbzhang800-qextserialport/buildlib
QMAKE_PRO_INPUT = buildlib.pro
QMAKE_PRL_TARGET = qextserialport-1.2
QMAKE_PRL_CONFIG = include_source_dir incredibuild_xge lex yacc warn_on uic resources incremental_off windows release ReleaseBuild Release build_pass qt warn_on release incremental flat link_prl precompile_header autogen_precompile_source copy_dir_files debug_and_release debug_and_release_target embed_manifest_dll embed_manifest_exe stl exceptions rtti mmx 3dnow sse sse2 release ReleaseBuild Release build_pass qt qextserialport-buildlib create_prl qextserialport-uselib qextserialport-static static debug_and_release build_all release ReleaseBuild Release build_pass no_autoqmake staticlib static moc thread
QMAKE_PRL_LIBS = setupapi.lib advapi32.lib user32.lib d://Qt//4.7.0//lib//QtGui4.lib d://Qt//4.7.0//lib//QtCore4.lib