hive HQL

Hive提供了很多的函數，可以在命令行下show functions羅列所有的函數，你會發現這些函數名與mysql的很相近，絕大多數相同的，可通過describe function functionName 查看函數使用方法。

hive支持的數據類型很簡單就INT(4 byte integer),BIGINT(8 byte integer),FLOAT(single precision),DOUBLE(double precision),BOOLEAN,STRING等原子類型，連日期時間類型也不支持，但通過to_date、unix_timestamp、date_diff、date_add、date_sub等函數就能完成mysql同樣的時間日期複雜操作。

如下示例：

select * from tablename where to_date(cz_time) > to_date('2050-12-31');

select * from tablename where unix_timestamp(cz_time) > unix_timestamp('2050-12-31 15:32:28');

分區

hive與mysql分區有些區別，mysql分區是用表結構中的字段來分區(range,list,hash等)，而hive不同，他需要手工指定分區列，這個列是獨立於表結構，但屬於表中一列，在加載數據時手動指定分區。

創建表

hive> CREATE TABLE pokes (foo INT, bar STRING COMMENT 'This is bar'); 

 

創建表並創建索引字段ds

hive> CREATE TABLE invites (foo INT, bar STRING) PARTITIONED BY (ds STRING); 

 

顯示所有表

hive> SHOW TABLES;

 

按正條件（正則表達式）顯示錶，

hive> SHOW TABLES '.*s';

 

表添加一列 

hive> ALTER TABLE pokes ADD COLUMNS (new_col INT);

 

添加一列並增加列字段註釋

hive> ALTER TABLE invites ADD COLUMNS (new_col2 INT COMMENT 'a comment');

 

更改表名

hive> ALTER TABLE events RENAME TO 3koobecaf;

 

刪除列

hive> DROP TABLE pokes;

 

元數據存儲

將本地文件中的數據加載到表中

hive> LOAD DATA LOCAL INPATH './examples/files/kv1.txt' OVERWRITE INTO TABLE pokes; 

 

加載本地數據，同時給定分區信息

hive> LOAD DATA LOCAL INPATH './examples/files/kv2.txt' OVERWRITE INTO TABLE invites PARTITION (ds='2008-08-15');

 

加載DFS數據 ，同時給定分區信息

hive> LOAD DATA INPATH '/user/myname/kv2.txt' OVERWRITE INTO TABLE invites PARTITION (ds='2008-08-15');

The above command will load data from an HDFS file/directory to the table. Note that loading data from HDFS will result in moving the file/directory. As a result, the operation is almost instantaneous. 

 

SQL 操作

按先件查詢

hive> SELECT a.foo FROM invites a WHERE a.ds='';

 

將查詢數據輸出至目錄

hive> INSERT OVERWRITE DIRECTORY '/tmp/hdfs_out' SELECT a.* FROM invites a WHERE a.ds='';

 

將查詢結果輸出至本地目錄

hive> INSERT OVERWRITE LOCAL DIRECTORY '/tmp/local_out' SELECT a.* FROM pokes a;

 

選擇所有列到本地目錄 

hive> INSERT OVERWRITE TABLE events SELECT a.* FROM profiles a;

hive> INSERT OVERWRITE TABLE events SELECT a.* FROM profiles a WHERE a.key < 100; 

hive> INSERT OVERWRITE LOCAL DIRECTORY '/tmp/reg_3' SELECT a.* FROM events a;

hive> INSERT OVERWRITE DIRECTORY '/tmp/reg_4' select a.invites, a.pokes FROM profiles a;

hive> INSERT OVERWRITE DIRECTORY '/tmp/reg_5' SELECT COUNT(1) FROM invites a WHERE a.ds='';

hive> INSERT OVERWRITE DIRECTORY '/tmp/reg_5' SELECT a.foo, a.bar FROM invites a;

hive> INSERT OVERWRITE LOCAL DIRECTORY '/tmp/sum' SELECT SUM(a.pc) FROM pc1 a;

 

將一個表的統計結果插入另一個表中

hive> FROM invites a INSERT OVERWRITE TABLE events SELECT a.bar, count(1) WHERE a.foo > 0 GROUP BY a.bar;

hive> INSERT OVERWRITE TABLE events SELECT a.bar, count(1) FROM invites a WHERE a.foo > 0 GROUP BY a.bar;

JOIN

hive> FROM pokes t1 JOIN invites t2 ON (t1.bar = t2.bar) INSERT OVERWRITE TABLE events SELECT t1.bar, t1.foo, t2.foo;

 

將多表數據插入到同一表中

FROM src

INSERT OVERWRITE TABLE dest1 SELECT src.* WHERE src.key < 100

INSERT OVERWRITE TABLE dest2 SELECT src.key, src.value WHERE src.key >= 100 and src.key < 200

INSERT OVERWRITE TABLE dest3 PARTITION(ds='2008-04-08', hr='12') SELECT src.key WHERE src.key >= 200 and src.key < 300

INSERT OVERWRITE LOCAL DIRECTORY '/tmp/dest4.out' SELECT src.value WHERE src.key >= 300;

 

將文件流直接插入文件

hive> FROM invites a INSERT OVERWRITE TABLE events SELECT TRANSFORM(a.foo, a.bar) AS (oof, rab) USING '/bin/cat' WHERE a.ds > '2008-08-09';

This streams the data in the map phase through the script /bin/cat (like hadoop streaming). Similarly - streaming can be used on the reduce side (please see the Hive Tutorial or examples) 

 

實際示例

創建一個表

CREATE TABLE u_data (

userid INT,

movieid INT,

rating INT,

unixtime STRING)

ROW FORMAT DELIMITED

FIELDS TERMINATED BY '\t'

STORED AS TEXTFILE;

 

下載示例數據文件，並解壓縮

wget http://www.grouplens.org/system/files/ml-data.tar__0.gz

tar xvzf ml-data.tar__0.gz

 

加載數據到表中

LOAD DATA LOCAL INPATH 'ml-data/u.data'

OVERWRITE INTO TABLE u_data;

 

統計數據總量

SELECT COUNT(1) FROM u_data;

 

現在做一些複雜的數據分析

創建一個 weekday_mapper.py: 文件，作爲數據按周進行分割 

import sys

import datetime

for line in sys.stdin:

line = line.strip()

userid, movieid, rating, unixtime = line.split('\t')

 

生成數據的周信息

weekday = datetime.datetime.fromtimestamp(float(unixtime)).isoweekday()

print '\t'.join([userid, movieid, rating, str(weekday)])

 

使用映射腳本

//創建表，按分割符分割行中的字段值

CREATE TABLE u_data_new (

userid INT,

movieid INT,

rating INT,

weekday INT)

ROW FORMAT DELIMITED

FIELDS TERMINATED BY '\t';

 

//將python文件加載到系統

add FILE weekday_mapper.py;

 

將數據按周進行分割

INSERT OVERWRITE TABLE u_data_new

SELECT

TRANSFORM (userid, movieid, rating, unixtime)

USING 'python weekday_mapper.py'

AS (userid, movieid, rating, weekday)

FROM u_data;

SELECT weekday, COUNT(1)

FROM u_data_new

GROUP BY weekday;