以下內容分爲八部分，分別是
一、類型指針的定義
二、無類型指針的定義
三、指針的解除引用
四、取地址（指針賦值）
五、指針運算
六、動態內存分配
七、字符數組的運算
八、函數指針
一、類型指針的定義。對於指向特定類型的指針，在C中是這樣定義的：
int *ptr;
char *ptr;
與之等價的Object Pascal是如何定義的呢？
var
ptr : ^Integer;
ptr : ^char;
其實也就是符號的差別而已。
二、無類型指針的定義。C中有void *類型，也就是可以指向任何類型數據的指針。Object Pascal爲其定義了一個專門的類型：Pointer。於是，
ptr : Pointer;
就與C中的
void *ptr;
等價了。
三、指針的解除引用。要解除指針引用（即取出指針所指區域的值），C 的語法是 (*ptr)，Object Pascal則是 ptr^。
四、取地址（指針賦值）。取某對象的地址並將其賦值給指針變量，C 的語法是
ptr = &Object;
Object Pascal 則是
ptr := @Object;
也只是符號的差別而已。
五、指針運算。在C中，可以對指針進行移動的運算，如：
char a[20];
char *ptr=a;
ptr++;
ptr+=2;
當執行ptr++;時，編譯器會產生讓ptr前進sizeof(char)步長的代碼，之後，ptr將指向a[1]。ptr+=2;這句使得ptr前進兩個sizeof(char)大小的步長。同樣，我們來看一下Object Pascal中如何實現：
var
a : array [1..20] of Char;
ptr : PChar; //PChar 可以看作 ^Char
begin
ptr := @a;
Inc(ptr); // 這句等價於 C 的 ptr++;
Inc(ptr, 2); //這句等價於 C 的 ptr+=2;
end;
只是，Pascal中，只允許對有類型的指針進行這樣的運算，對於無類型指針是不行的。
六、動態內存分配。C中，使用malloc()庫函數分配內存，free()函數釋放內存。如這樣的代碼：
int *ptr, *ptr2;
int i;
ptr = (int*) malloc(sizeof(int) * 20);
ptr2 = ptr;
for (i=0; i<20; i++){
*ptr = i;
ptr++;
}
free(ptr2);
Object Pascal中，動態分配內存的函數是GetMem()，與之對應的釋放函數爲FreeMem()（傳統Pascal中獲取內存的函數是New()和 Dispose()，但New()只能獲得對象的單個實體的內存大小，無法取得連續的存放多個對象的內存塊）。因此，與上面那段C的代碼等價的Object Pascal的代碼爲：
var ptr, ptr2 : ^integer;
i : integer;
begin
GetMem(ptr, sizeof(integer) * 20);
//這句等價於C的 ptr = (int*) malloc(sizeof(int) * 20);
ptr2 := ptr; //保留原始指針位置
for i := 0 to 19 do
begin
ptr^ := i;
Inc(ptr);
end;
FreeMem(ptr2);
end;
對於以上這個例子（無論是C版本的，還是Object Pascal版本的），都要注意一個問題，就是分配內存的單位是字節（BYTE），因此在使用GetMem時，其第二個參數如果想當然的寫成 20，那麼就會出問題了（內存訪問越界）。因爲GetMem(ptr, 20);實際只分配了20個字節的內存空間，而一個整形的大小是四個字節，那麼訪問第五個之後的所有元素都是非法的了（對於malloc()的參數同樣）。
七、字符數組的運算。C語言中，是沒有字符串類型的，因此，字符串都是用字符數組來實現，於是也有一套str打頭的庫函數以進行字符數組的運算，如以下代碼：
char str[15];
char *pstr;
strcpy(str, "teststr");
strcat(str, "_testok");
pstr = (char*) malloc(sizeof(char) * 15);
strcpy(pstr, str);
printf(pstr);
free(pstr);
而在Object Pascal中，有了String類型，因此可以很方便的對字符串進行各種運算。但是，有時我們的Pascal代碼需要與C的代碼交互（比如：用Object Pascal的代碼調用C寫的DLL或者用Object Pascal寫的DLL準備允許用C寫客戶端的代碼）的話，就不能使用String類型了，而必須使用兩種語言通用的字符數組。其實，Object Pascal提供了完全相似C的一整套字符數組的運算函數，以上那段代碼的Object Pascal版本是這樣的：
var str : array [1..15] of char;
pstr : PChar; //Pchar 也就是 ^Char
begin
StrCopy(@str, 'teststr'); //在C中，數組的名稱可以直接作爲數組首地址指針來用
//但Pascal不是這樣的，因此 str前要加上取地址的運算符
StrCat(@str, '_testok');
GetMem(pstr, sizeof(char) * 15);
StrCopy(pstr, @str);
Write(pstr);
FreeMem(pstr);
end;
八、函數指針。在動態調用DLL中的函數時，就會用到函數指針。假設用C寫的一段代碼如下：
typedef int (*PVFN)(int); //定義函數指針類型
int main()
{
HMODULE hModule = LoadLibrary("test.dll");
PVFN pvfn = NULL;
pvfn = (PVFN) GetProcAddress(hModule, "Function1");
pvfn(2);
FreeLibrary(hModule);
}
就我個人感覺來說，C語言中定義函數指針類型的typedef代碼的語法有些晦澀，而同樣的代碼在Object Pascal中卻非常易懂：
type PVFN = Function (para : Integer) : Integer;
var
fn : PVFN;
//也可以直接在此處定義，如：fn : function (para:Integer):Integer;
hm : HMODULE;
begin
hm := LoadLibrary('test.dll');
fn := GetProcAddress(hm, 'Function1');
fn(2);
FreeLibrary(hm);
end;
delphi指針簡單入門:
看一個指針用法的例子：
1 var
2 X, Y: Integer; // X and Y 整數類型
3 P: ^Integer; // P 指向整數類型的指針
4 begin
5 X :=17; // 給 X 賦值
6 P := @X; // 把 x的地址賦給p
7 Y := P^; // 取出p所指向的數值賦給y
8 end;
第二行定義了兩個變量X,y. 第三行聲明瞭p是指向整數類型的指針;意味着p能夠指向x或者y的地址.第五行賦給x值,第六行把x的地址賦給p.最
後通過p指向的變量賦值給y.此時,x和y有相同的值.
操作符@用來取出變量的地址,也可以取出過程和函數的地址.
而符號^有兩個目標,
當它出現在類型定義的前面時如 ^typename 表示指向這種類型的指針;
當它出現在指針變量後邊時 如 point^ 返回指針指向的變量的值;
理解指針比較容易理解面向對象的pascal語言,因爲指針經常在幕後操作.任何要求動態分配大的內存空間的類型可以用指針類型.例如
,long-string變量,實際在使用指針進行操作.另外一些高級的編程技術需要使用指針類型.
有時指針是適應object pascal嚴格的類型限制的唯一方法.同過一個通用的指針類型,通過類型轉換成不同的指針類型,如下面的例子:
type
PInteger = ^Integer;
var
R: Single;
I: Integer;
P: Pointer; //通用的指針
PI: PInteger;
begin
P := @R; //取出R的內存地址
PI := PInteger(P); //把通用類型轉換成指向整數類型的指針
I := PI^;
end;
當然了,實數和整數的存儲格式不同.這種賦值是把原始的二進制數據從R拷貝到I,而不進行轉換.
保留字nil是一個特殊的常量可以賦給任何指針類型,當nil賦給一個指針時,指針什麼也不指向,是一個空指針.
@操作符返回變量的內存中的存儲地址,或者是過程\函數\方法;
1.如果變量,@X返回的是x的地址。如果編譯選項{$T-}沒有打開,着返回的事一個通用的指針,如果編譯選項打開了,着返回的是x的類型對應的指
針.
2.如果是例程(過程\函數),@F返回的是F的入口點，@F的類型是一個指針。
3.當@用在類的方法中時,則方法的名稱必須有類名,例如@TMyclass.Dosomething
指針指向TMyclass的dosomething方法。
當一個過程變量在賦值語句的左邊時，編譯器期望一個過程值在賦值語句的右邊。這種賦值使得左邊的變量可以指向右邊定義的過程或者函數
入口點。換句話說，可以通過該變量來引用聲明的過程或者函數，可以直接使用參數的引用。
var
F: function(X: Integer): Integer;
I: Integer;
function SomeFunction(X: Integer): Integer;
...
F := SomeFunction; // 給f賦值
I := F(4); // 調用所指向的函數
在賦值語句中，左邊變量的類型決定了右邊的過程或者方法指針解釋。
var
F, G: function: Integer;
I: Integer;
function SomeFunction: Integer;
...
F := SomeFunction; // 給f賦值
G := F; // 把F的值拷貝給G
I := G; // 調用函數
第一句獲得函數的入口，第二句將指針複製，第三句獲得函數的返回值。
有時候還可以這樣使用
if F = MyFunction then ...;
在這裏，F的出現導致一個函數調用；編譯器調用F指向的函數，然後調用Myfunction，比較結果。這個規則是無論何時一個過程變量（
procedural variable）出現在一個表達式中，它表示調用所指向的函數或者過程。有時F指向一個過程（沒有返回值），或者f指向一個需要參
數的函數，則前面的語句會產生一個編譯錯誤。要比較F和Myfunction需要用
if @F = @MyFunction then ...;
@F把F轉換成一個包含地址的無類型的指針變量,@myfunction返回myfunction的地址。
獲得一個過程變量的內存地址使用@@。例如，@@F返回F的地址。
@操作符通常把一個無類型的指針值賦給一個過程變量，例如：
var StrComp: function(Str1, Str2: PChar): Integer;
...
@StrComp := GetProcAddress(KernelHandle, 'lstrcmpi');
調用GetProcAddres函數,用strcomp指向這個值
任何過程變量可以賦成nil，表示指證什麼也不指向。但是試圖調用一個nil值的過程變量導致一個錯誤，爲了測試一個過程變量是否可以賦值
，用標準的賦值函數Assigned
if Assigned(OnClick) then OnClick(X);
先到這裏吧,我也是一邊看幫助一邊翻譯的,沒有參考什麼書籍,所以有一些名詞可能不太準確,希望大家多多包涵吧,畢竟本人的英文水平有限啊