sfc戰區88的自制連射腳本與金手指

sfc的戰區88這遊戲非常難，經過3天練習現在能打通normal了。

沒有自動連射非常蛋疼，我用AutoHotkey寫了個腳本，設置的射擊鍵是q，按y自動連射，按u取消

AutoHotkey腳本:

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

;SFC模擬器,戰區88自動連發腳本,snes9x模擬器活動時按y開啓自動連發,按u停止

SetTitleMatchMode,RegEx

autoFireOn:=0 ;是否執行自動連發,0表示不執行,1表示執行,此規則與AutoHotkey的判斷規則相同,0或空表示false,其他表示true

gui,add,text,,Script for SFC Area88`nAuto Fire script ;標題文本
;顯示自動連發的狀態,訪問此組件的名稱爲AutoFireStatus,如組件是可訪問變量類型,則綁定變量AutoFireStatus,用命令Gui,Submit,NoHide進行提交更新
gui,add,text,w120 vAutoFireStatus,AutoFire Off 
gui,add,button,,Toggle ;開啓或停止熱鍵,對應腳本爲ButtonToggle
gui,add,button,,Exit ;結束腳本,對應標籤爲ButtonExit
gui,show,w250h150
OutputDebug, sfc area88 ahk debug start!
gosub,_RefreshAutoFireStatus

return

;根據autoFireOn的情況,刷新狀態顯示
_RefreshAutoFireStatus:
if(autoFireOn)
{
	GuiControl,text,AutoFireStatus,AutoFire On
	OutputDebug,AutoFire On
}
else
{
	GuiControl,text,AutoFireStatus,AutoFire Off
	OutputDebug,AutoFire Off
}

return

;關閉窗口時結束腳本
GuiClose:
ExitApp
return

;下面響應gui的命令
ButtonToggle:
autoFireOn:=autoFireOn?0:1
gosub,_RefreshAutoFireStatus
return

ButtonExit:
MsgBox,4,,Exit this Script?
IfMsgBox Yes
{
	ExitApp
}
return

;開始定義熱鍵,只有Snes模擬器活動時有效
#IfWinActive,ahk_class Snes9*

;開啓連射,按下中止熱鍵或窗口轉爲非活動時中止
~y::
autoFireOn:=1
gosub,_RefreshAutoFireStatus
while((autoFireOn)&&(WinActive("ahk_class Snes9X: WndClass")))
{
	send {q DOWN}
	sleep,50
	send {q up}
	sleep,20
}
autoFireOn:=0
gosub,_RefreshAutoFireStatus
return

;中止連射
~u::
autoFireOn:=0
return

#IfWinActive

再記錄一下金手指:

錢(16進制數顯示在畫面中,100爲單位) :
7E00D7 00
7E00D8 00
7E00D9 09
命:
7E00F4 09
子彈:
順序 = [Cluster,Phoenix,Falcon,Bullpup,S.Shell,T.Laser,Bomb,Napalm,Gunpod,
  Ceiling,MegaCrush]
7E00DD 開始,每個一字節,按持有順序,上面是全部持有時的順序
無敵(畫面上看不出來):
7E00F7 01