iOS底層探索：NSObject-alloc、init、new 1.alloc的代碼執行流程 2.obj初始化流程 3.重點探究 3.init流程 4. [[X alloc] init] 4.new

我們實例化一個NSObject對象，最常見的代碼就是

NXPerson *person = [[NXPerson alloc] init];

對於調用alloc/init等方法底層究竟發生了什麼，你是否知道呢？今天我們就來一探究竟：

以下調試基於Apple開源的objc4-818.2代碼進行。

1.alloc的代碼執行流程

1.1.首先在上述代碼開始開始位置打第1個斷點，然後運行代碼使得代碼斷在這個斷點。
1.2.然後點擊alloc，跳轉到了[NSObject.mm alloc]，並在這裏設置第2個斷點。
1.3.此時我們觀察Xcode左側的調用棧

仔細看，我們會發現一個奇怪的問題：在main之後，[NSObject.mm alloc]之前，還有兩個方法的調用
1.3.1.調用objc_alloc方法:

id objc_alloc(Class cls){
    return callAlloc(cls, true/*checkNil*/, false/*allocWithZone*/);
}

1.3.2. objc_alloc的內部調用了callAlloc方法:

static ALWAYS_INLINE id callAlloc(Class cls, bool checkNil, bool allocWithZone=false){
   #if __OBJC2__
      if (slowpath(checkNil && !cls)) return nil;
      if (fastpath(!cls->ISA()->hasCustomAWZ())) {
          return _objc_rootAllocWithZone(cls, nil);
     }
   #endif

    // No shortcuts available.
    if (allocWithZone) {
        return ((id(*)(id, SEL, struct _NSZone *))objc_msgSend)(cls, @selector(allocWithZone:), nil);
    }
    return ((id(*)(id, SEL))objc_msgSend)(cls, @selector(alloc));
}

1.3.3.callAlloc內部通過((id(*)(id, SEL))objc_msgSend)(cls, @selector(alloc))調用[NSObject.mm alloc]方法:

+ (id)alloc {
    return _objc_rootAlloc(self);
}

1.3.4. alloc內部調用了_objc_rootAlloc方法：

id _objc_rootAlloc(Class cls){
    return callAlloc(cls, false/*checkNil*/, true/*allocWithZone*/);
}

1.3.5. _objc_rootAlloc內部調用callAlloc方法：

static ALWAYS_INLINE id callAlloc(Class cls, bool checkNil, bool allocWithZone=false){
    #if __OBJC2__
        if (slowpath(checkNil && !cls)) return nil;
        if (fastpath(!cls->ISA()->hasCustomAWZ())) {
            return _objc_rootAllocWithZone(cls, nil);
        }
    #endif

    // No shortcuts available.
    if (allocWithZone) {
        return ((id(*)(id, SEL, struct _NSZone *))objc_msgSend)(cls, @selector(allocWithZone:), nil);
    }
    return ((id(*)(id, SEL))objc_msgSend)(cls, @selector(alloc));
}

1.3.6. callAlloc內部調用了_objc_rootAllocWithZone方法，這裏明確了objc2忽略了allocWithZone，所以這裏以及後續都傳的是nil.

NEVER_INLINE id _objc_rootAllocWithZone(Class cls, malloc_zone_t *zone __unused){
    // allocWithZone under __OBJC2__ ignores the zone parameter
    return _class_createInstanceFromZone(cls, 0, nil, OBJECT_CONSTRUCT_CALL_BADALLOC);
}

1.3.7. _objc_rootAllocWithZone內部調用_class_createInstanceFromZone方法：

static ALWAYS_INLINE id _class_createInstanceFromZone(Class cls, size_t extraBytes, void *zone, int construct_flags = OBJECT_CONSTRUCT_NONE, bool cxxConstruct = true, size_t *outAllocatedSize = nil){
    ASSERT(cls->isRealized());

    // Read class's info bits all at once for performance
    bool hasCxxCtor = cxxConstruct && cls->hasCxxCtor();
    bool hasCxxDtor = cls->hasCxxDtor();
    bool fast = cls->canAllocNonpointer();
    size_t size;

    size = cls->instanceSize(extraBytes);
    if (outAllocatedSize) *outAllocatedSize = size;

    id obj;
    if (zone) {
        obj = (id)malloc_zone_calloc((malloc_zone_t *)zone, 1, size);
    } else {
        obj = (id)calloc(1, size);
    }
    if (slowpath(!obj)) {
        if (construct_flags & OBJECT_CONSTRUCT_CALL_BADALLOC) {
            return _objc_callBadAllocHandler(cls);
        }
        return nil;
    }

    if (!zone && fast) {
        obj->initInstanceIsa(cls, hasCxxDtor);
    } 
    else {
        obj->initIsa(cls);
    }

    if (fastpath(!hasCxxCtor)) {
        return obj;
    }

    construct_flags |= OBJECT_CONSTRUCT_FREE_ONFAILURE;
    return object_cxxConstructFromClass(obj, cls, construct_flags);
}

整個流程一共經歷了7步，在第1.3.7步中返回了obj對象。也就是前面的一些步驟知識一些通用接口，根據環境變量等的不同來獲得第七步所需要的一些參數，接下來我們探究obj初始化初始化的流程

2.obj初始化流程

2.1.obj初始化流程中，我們看到對其進行了聲明, 接下來執行的代碼如下，根據上下問參數可以知道zone參數爲nil，所以就走到了else分支的obj = (id)calloc(1, size)中，calloc函數是一個分配內存的底層函數，第二個參數是size,表示需要開闢的內存空間的大小，第一個參數是1，表示申請一倍於size的大小。

id obj;
if (zone) {
       obj = (id)malloc_zone_calloc((malloc_zone_t *)zone, 1, size);
} 
else {
       obj = (id)calloc(1, size);
}

2.2.size的代碼如下，我們根據上下參數可以看到outAllocatedSize參數爲nil，所以if條件就可以不看了。那麼size = cls->instanceSize(extraBytes),這個就是獲取初始化這個對象需要分配的內存大小了。具體怎麼計算的，我們後面再繼續探究，這裏拿到size之後就可以完成對象的初始化了。

size_t size;
size = cls->instanceSize(extraBytes);
if (outAllocatedSize) *outAllocatedSize = size;

打印下size和obj，我們發現打印的只有一個地址，沒有描述信息呀，我們平時打印個對象，都是<NSObject: 0x101315780>這種格式的啊，在繼續探索，我們傳入的NXPerson類並沒有派上用場，也就是他還沒有跟類的信息綁定起來。

2.3.繼續往下，斷點走到了這裏，具體怎麼綁定的我們後面在再進行探究。我們接着再打印下obj,到這裏我們看到了已經有類名相關的信息了

obj->initInstanceIsa(cls, hasCxxDtor);

綜上所屬，類的實例初始化可以分爲三步，第一步通過cls->instanceSize獲得分配的內存大小；第二步通過calloc分配內存空間；第三步通過obj->initInstanceIsa綁定類信息到實例上。完整的流程可以查看下方的流程圖：

3.重點探究

3.1內存大小的計算
調用如下objc_class的方法instanceSize,參數extraBytes = 0,

inline size_t instanceSize(size_t extraBytes) const {
        if (fastpath(cache.hasFastInstanceSize(extraBytes))) {
            return cache.fastInstanceSize(extraBytes);
        }

        size_t size = alignedInstanceSize() + extraBytes;
        // CF requires all objects be at least 16 bytes.
        if (size < 16) size = 16;  
        return size;
    }

再繼續調用cache_t的fastInstanceSize方法,走到這一步size=40，然後再減去FAST_CACHE_ALLOC_DELTA16=0x0008,得到32。值得注意的是align16是表示16字節對齊，算法爲(x + size_t(15)) & ~size_t(15).

<16位對齊也就是在剋皮內存空間的時候，只能開闢16的整數倍大小的內存空間，這樣以16字節爲基礎單位開闢的內存空間，就可以保證在內存連續上的整齊度。採取16字節對齊，是因爲OC的對象中，第一位isa指針，是必然存在的，而且它就佔了8字節，就算你的對象中沒有其他的屬性了，那對象也至少要佔用8位字節。如果以8位字節對齊的話，如果連續的兩塊內存都是沒有屬性的對象，那麼它們的內存空間就會完全的挨在一起，是容易混亂的。採用16字節對齊，按塊讀取效率更高，同時還不容易混亂。

size_t fastInstanceSize(size_t extra) const{
        ASSERT(hasFastInstanceSize(extra));

        if (__builtin_constant_p(extra) && extra == 0) {
            return _flags & FAST_CACHE_ALLOC_MASK16;
        } 
        else {
            size_t size = _flags & FAST_CACHE_ALLOC_MASK;
            // remove the FAST_CACHE_ALLOC_DELTA16 that was added
            // by setFastInstanceSize
            return align16(size + extra - FAST_CACHE_ALLOC_DELTA16);
        }
   }

3.2.設置對象的isa,調用的函數如下

斷點調試發現走到了圖5打斷點的位置，newisa.setClass(cls, this);就是用來設置對象的isa信息(isa中存儲了類的信息)，這樣就把實例和對應的類關聯起來了。

3.init流程

調試中，首先來到了[NsObject.mm init],緊接着調用了_objc_rootInit方法，_objc_rootInit方法中直接返回了obj對象自身。也就是NSObject提供的init方法，底層並沒有做什麼事情，直接返回了對象本身。其實這是爲了給開發者提供一個初始化構造函數，方便開發者直接在init中初始化的對象的相關屬性信息。

- (id)init {
    return _objc_rootInit(self);
}

id _objc_rootInit(id obj){
    return obj;
}

4. [[X alloc] init]

調試過程中你會發現一個很有趣的問題，就是如果你直接NXPerson *person = [[NXPerson alloc] init],這樣調用，實際上會直接來到

id objc_alloc_init(Class cls){
    return [callAlloc(cls, true/*checkNil*/, false/*allocWithZone*/) init];
}

4.new

id
objc_opt_new(Class cls)
{
#if __OBJC2__
    if (fastpath(cls && !cls->ISA()->hasCustomCore())) {
        return [callAlloc(cls, false/*checkNil*/) init];
    }
#endif
    return ((id(*)(id, SEL))objc_msgSend)(cls, @selector(new));
}

+ (id)new {
    return [callAlloc(self, false/*checkNil*/) init];
}

static ALWAYS_INLINE id
callAlloc(Class cls, bool checkNil, bool allocWithZone=false)
{
#if __OBJC2__
    if (slowpath(checkNil && !cls)) return nil;
    if (fastpath(!cls->ISA()->hasCustomAWZ())) {
        return _objc_rootAllocWithZone(cls, nil);
    }
#endif

    // No shortcuts available.
    if (allocWithZone) {
        return ((id(*)(id, SEL, struct _NSZone *))objc_msgSend)(cls, @selector(allocWithZone:), nil);
    }
    return ((id(*)(id, SEL))objc_msgSend)(cls, @selector(alloc));
}

id
_objc_rootAllocWithZone(Class cls, malloc_zone_t *zone __unused)
{
    // allocWithZone under __OBJC2__ ignores the zone parameter
    return _class_createInstanceFromZone(cls, 0, nil,
                                         OBJECT_CONSTRUCT_CALL_BADALLOC);
}