- 列表內容
一、 背景
nRF24L01的成本較低，但內部需通過SPI通信，略顯複雜，同時RF過於專用，接入其他系統時需要轉換，不方便。
ESP8266是樂鑫公司推出的廉價、但幾乎全能的WIFI芯片，被各種智能硬件廣泛使用，根據其datasheet，不但支持SPI，也可通過I2C、UART等方式進行通信，尤其是UART，直接支持AT指令，大大簡化開發難度，相當便利。本文即採用AT模式。
ESP8266開發板，TB約12塊左右，右側爲ESP8266，左側爲25Q80BVSIG，1M閃存。
二、接線
1、ESP8266開發板引腳圖
- TX：串口寫
- GND：接地
- CH_PD：高電平爲可用，低電平爲關機
- GPIO2：可懸空
- RST：重置，可懸空
- GPIO0：上拉爲工作模式，下拉爲下載模式，可懸空
- VCC：3.3V（切不可接5V，燒片）
- RX：串口讀
2、接線示意
| ESP8266 | ArduinoMega | ArduinoUuno |
|---|---|---|
| TX | 19（RX1） | 0（RX0) |
| GND | GND | GND |
| CH_PD | 5（自由指定） | 5（自由指定） |
| GPIO2 | - | - |
| RST | - | - |
| GPIO0 | - | - |
| VCC | 3.3V | 3.3V |
| RX | 18（TX1） | 1（TX1） |
ESP8266的串口默認波特率爲115200，mega也可直接接RX0/TX0，
爲調試方便起見，本文中RX0/TX0留做調試窗口，用RX1/TX1和芯片交互。
如果是UNO，如果要看調試信息，只能增加一個軟串口。
三、代碼&運行
雖然可以直接通過串口直接讀寫AT指令，但指令較多，處理繁瑣，
找到有如下的庫對AT指令做了封裝，使用十分便利，推薦。
Git地址爲：
https://github.com/ekstrand/ESP8266wifi.git
具體AT指令及ESP8266相關文檔，可見樂鑫官方站點：
http://espressif.com/zh-hans/support/download/documents
1） ESP8266庫安裝
下載上面的ESP8266的庫後，將其複製到Arduino安裝目錄下的libraries目錄下，啓動ArduinoIDE後,從例子中選擇ESP8266_tcp_cli。
該庫默認支持3個客戶端連接和1個監聽連接，如要增大須修改其頭文件中的如下兩個宏：
define SERVER '4'
define MAX_CONNECTIONS 32） 代碼修改
該庫設計很靈活，設置了3個串口，入串口，出串口和調試串口。
其中入串口和出串口用於AT命令發送和接收，和ESP8266的串口相連，調試串口可顯示具體交互情況（AT指令信息等）原例子中採用的是UNO，因其只有一個硬串口，所以改爲Mega適用，以查看調試信息。
3） 運行
加載運行後，如WIFI設置正常，則可接入WIFI並取得IP，如下：
可看到調試串口輸出的AT指令，已經連接到WIFI，並取得192.168.80.188的IP.
另外，2121端口被也監聽成功。
可用telnet 模擬客戶端，連接建立成功後，輸入數據0～D，hello world。
輸入的數據可從COM監視器中看到對應的AT指令。如下圖：
四、例子代碼解析
從原有例子中刪除了軟串口相關的處理，如下
#include <ESP8266wifi.h>
#define esp8266_reset_pin 5
#define SERVER_PORT "2121"
#define SSID "XXXX"
#define PASSWORD "yourpass"
// 初始化，串口1和ESP8266交互，串口0做調試輸出， pin5做reset
ESP8266wifi wifi(Serial1, Serial1, esp8266_reset_pin, Serial);
void processCommand(WifiMessage msg);
uint8_t wifi_started = false;
// 自定義的應用層命令，可根據自身應用修改
const char RST[] PROGMEM = "RST";
const char IDN[] PROGMEM = "*IDN?";
void setup() {
// 調試串口啓動，波特率可隨意指定
Serial.begin(115200);
// ESP8266默認波特率爲115200（可用AT指令修改）
Serial1.begin(115200);
while (!Serial) // 等待串口初始化成功
;
Serial1.println("Starting wifi"); // 命令
Serial.println("Starting wifi"); // 調試log輸出
wifi.setTransportToTCP(); // TCP模式（默認設置）
wifi.endSendWithNewline(false); // 發送數據自動以\r\n結尾（默認設置）
wifi_started = wifi.begin(); // WIFI啓動
if (wifi_started) { // 如果WIFI初始化成功
wifi.connectToAP(SSID, PASSWORD); // 指定用戶名密碼連接WIFI
wifi.startLocalServer(SERVER_PORT); // 本機（Arduino）監聽2121端口（做服務端）
} else {
// ESP8266 isn't working..
Serial.println("ESP8266 isn't working..");
}
}
void loop() {
static WifiConnection *connections;
// check connections if the ESP8266 is there
if (wifi_started)
wifi.checkConnections(&connections); // 檢查/獲取當前所有連接的狀況
// check for messages if there is a connection
for (int i = 0; i < MAX_CONNECTIONS; i++) { // 默認最大爲3
if (connections[i].connected) {
// See if there is a message
WifiMessage msg = wifi.getIncomingMessage();
if (msg.hasData) { // 如果有數據
processCommand(msg);
}
}
}
}
void processCommand(WifiMessage msg) { // 數據處理函數
char espBuf[MSG_BUFFER_MAX];
int set;
char str[16];
Serial.print(msg.message);
// 以下爲應用層面的處理
sscanf(msg.message, "%15s %d", str, &set);
Serial.print(str);
Serial.println(set);
if ( !strcmp_P(str, IDN) ) {
wifi.send(msg.channel, "ESP8266wifi Example");
}
// Reset system by temp enable watchdog
else if ( !strcmp_P(str, RST) ) {
wifi.send(msg.channel, "SYSTEM RESET...");
// soft reset by reseting PC
asm volatile (" jmp 0");
}
// Unknown command
else {
wifi.send(msg.channel, "ERR");
}
}五、參考URL
詳細參考（英語）：
https://github.com/ekstrand/ESP8266wifi
http://blog.csdn.net/john_yike/article/details/47058857
六、更多文章
ESP8266可以和Arduino配合使用，充當起爲Arduino進行Wifi連接、網絡處理的任務。
但其實esp8266本身對比arduino，功能、性能方面均是有過之而無不及，實有殺雞用牛刀大材小用之感。
更多ESP8266的文章，請見如下：
https://blog.csdn.net/ydogg/article/category/6930257