mac下運行QWT的example程序

在上篇“mac下安裝QWT(Qt5.5.0＋qwt-6.1.2)“中，按默認參數安裝QWT的過程是不包括對Example項目的編譯的，當我隨後額外編譯Examples的時候，出現了一些鏈接問題不能執行，因爲Example引用的不是install的路徑，需要稍事修改一下“example.pri“文件。

前文中說過，配置qwt項目只需在.pro中加入下行即可：

include(/usr/local/qwt-6.1.2/features/qwt.prf)

因此，我們用它替換掉example.pri裏的相關鏈接語句。

example.pri

修改後的：

#新增
include(/usr/local/qwt-6.1.2/features/qwt.prf)

#刪除
#QWT_ROOT = $${PWD}/..
#include( $${QWT_ROOT}/qwtconfig.pri )
#include( $${QWT_ROOT}/qwtbuild.pri )
#include( $${QWT_ROOT}/qwtfunctions.pri )

QWT_OUT_ROOT = $${OUT_PWD}/../..

TEMPLATE     = app

#刪除
#INCLUDEPATH += $${QWT_ROOT}/src
#DEPENDPATH  += $${QWT_ROOT}/src

!debug_and_release {

    DESTDIR      = $${QWT_OUT_ROOT}/examples/bin
}
else {
    CONFIG(debug, debug|release) {

        DESTDIR      = $${QWT_OUT_ROOT}/examples/bin_debug
    }
    else {

        DESTDIR      = $${QWT_OUT_ROOT}/examples/bin
    }
}

#刪除
#QMAKE_RPATHDIR *= $${QWT_OUT_ROOT}/lib
#qwtAddLibrary($${QWT_OUT_ROOT}/lib, qwt)

greaterThan(QT_MAJOR_VERSION, 4) {

    QT += printsupport
    QT += concurrent
}

contains(QWT_CONFIG, QwtOpenGL ) {

    QT += opengl
}
else {

    DEFINES += QWT_NO_OPENGL
}

contains(QWT_CONFIG, QwtSvg) {

    QT += svg
}
else {

    DEFINES += QWT_NO_SVG
}


win32 {
    contains(QWT_CONFIG, QwtDll) {
        DEFINES    += QT_DLL QWT_DLL
    }
}

修改保存後，打開終端（bash），進入example目錄

cd XXX/examples 

用qmake構建

qmake examples.pro

編譯

make

完成後，在examples文件夾下進入生成的bin目錄，可以運行裏面的程序查看了。

比如，運行“realtime“程序：

END.