mac下运行QWT的example程序

在上篇“mac下安装QWT(Qt5.5.0＋qwt-6.1.2)“中，按默认参数安装QWT的过程是不包括对Example项目的编译的，当我随后额外编译Examples的时候，出现了一些链接问题不能执行，因为Example引用的不是install的路径，需要稍事修改一下“example.pri“文件。

前文中说过，配置qwt项目只需在.pro中加入下行即可：

include(/usr/local/qwt-6.1.2/features/qwt.prf)

因此，我们用它替换掉example.pri里的相关链接语句。

example.pri

修改后的：

#新增
include(/usr/local/qwt-6.1.2/features/qwt.prf)

#删除
#QWT_ROOT = $${PWD}/..
#include( $${QWT_ROOT}/qwtconfig.pri )
#include( $${QWT_ROOT}/qwtbuild.pri )
#include( $${QWT_ROOT}/qwtfunctions.pri )

QWT_OUT_ROOT = $${OUT_PWD}/../..

TEMPLATE     = app

#删除
#INCLUDEPATH += $${QWT_ROOT}/src
#DEPENDPATH  += $${QWT_ROOT}/src

!debug_and_release {

    DESTDIR      = $${QWT_OUT_ROOT}/examples/bin
}
else {
    CONFIG(debug, debug|release) {

        DESTDIR      = $${QWT_OUT_ROOT}/examples/bin_debug
    }
    else {

        DESTDIR      = $${QWT_OUT_ROOT}/examples/bin
    }
}

#删除
#QMAKE_RPATHDIR *= $${QWT_OUT_ROOT}/lib
#qwtAddLibrary($${QWT_OUT_ROOT}/lib, qwt)

greaterThan(QT_MAJOR_VERSION, 4) {

    QT += printsupport
    QT += concurrent
}

contains(QWT_CONFIG, QwtOpenGL ) {

    QT += opengl
}
else {

    DEFINES += QWT_NO_OPENGL
}

contains(QWT_CONFIG, QwtSvg) {

    QT += svg
}
else {

    DEFINES += QWT_NO_SVG
}


win32 {
    contains(QWT_CONFIG, QwtDll) {
        DEFINES    += QT_DLL QWT_DLL
    }
}

修改保存后，打开终端（bash），进入example目录

cd XXX/examples 

用qmake构建

qmake examples.pro

编译

make

完成后，在examples文件夹下进入生成的bin目录，可以运行里面的程序查看了。

比如，运行“realtime“程序：

END.