讓窗體的標題欄不相應鼠標雙擊

還等什麼，讓我們現在開始。

1。新建一個VB6的標準EXE工程，然後添加一個模塊，將下列代碼加入新的模塊中：

Option Explicit
                   
Private Declare Function SetWindowLong Lib "user32" Alias _
        "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex _
        As Long, ByVal dwNewLong As Long) As Long
       
Private Declare Function CallWindowProc Lib "user32" Alias _
        "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal _
        hWnd As Long, ByVal Msg As Long, ByVal wParam As _
        Long, ByVal lParam As Long) As Long
       
Const GWL_WNDPROC = (-4&)

Dim PrevWndProc&

Const WM_NCLBUTTONDBLCLK = &HA3
 
Public Sub Init(hWnd As Long)
  PrevWndProc = SetWindowLong(hWnd, GWL_WNDPROC, AddressOf SubWndProc)
End Sub

Public Sub Terminate(hWnd As Long)
  Call SetWindowLong(hWnd, GWL_WNDPROC, PrevWndProc)
End Sub

Private Function SubWndProc(ByVal hWnd As Long, ByVal Msg As Long, _
                            ByVal wParam As Long, ByVal lParam As Long) _
                            As Long
 
  If Msg = WM_NCLBUTTONDBLCLK Then
     Exit Function
  End If
 
  SubWndProc = CallWindowProc(PrevWndProc, hWnd, Msg, wParam, lParam)
End Function

2。在窗體的Load事件中加入一下代碼：

Private Sub Form_Load()
Call Init(Me.hWnd)
End Sub

3。最後在窗體的Unload事件中加入：

Private Sub Form_Unload(Cancel As Integer)
Call Terminate(Me.hWnd)
End Sub

好啦，可以運行我們創建的這個工程了，現在雙擊窗體的標題欄是不是和以前不一樣啊！

：）

以上程序在Win2000中文版、VB6下編譯運行通過