shader篇-渲染紋理

shader篇-渲染紋理

---

背景

Unity爲渲染目標紋理定義了一種專門的紋理類型————渲染紋理。
渲染紋理有2種方式：
1.Project目錄下創建渲染紋理，把攝像機渲染目標設置成該渲染紋理。這樣攝像頭的渲染結果就會實時更新到渲染紋理中，而不會顯示在屏幕上。
2.在屏幕後處理時使用GrabPass命令或OnRenderImage函數來獲取當前屏幕圖像，unity會把這個屏幕圖像放到一張和屏幕分辨率等同的渲染紋理中。

鏡子效果

使用第一種方法
完整代碼

Properties {
        _MainTex ("Main Tex", 2D) = "white" {}
    }
    SubShader {
        Tags { "RenderType"="Opaque" "Queue"="Geometry"}

        Pass {
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            sampler2D _MainTex;

            struct a2v {
                float4 vertex : POSITION;
                float3 texcoord : TEXCOORD0;
            };

            struct v2f {
                float4 pos : SV_POSITION;
                float2 uv : TEXCOORD0;
            };

            v2f vert(a2v v) {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);

                o.uv = v.texcoord;
                //翻轉了x分量的紋理座標
                o.uv.x = 1 - o.uv.x;

                return o;
            }

            fixed4 frag(v2f i) : SV_Target {
                return tex2D(_MainTex, i.uv);
            }

            ENDCG
        }
    } 
    FallBack Off

玻璃效果

使用第二種方法

創建立方體紋理後對紋理進行修改
屬性

Properties {
    _MainTex ("Main Tex", 2D) = "white" {}

    //玻璃的法線紋理
    _BumpMap ("Normal Map", 2D) = "bump" {}
    _Cubemap ("Environment Cubemap", Cube) = "_Skybox" {}

    //控制模擬折射時圖像的扭曲程度
    _Distortion ("Distortion", Range(0, 100)) = 10

    //控制折射程度
    _RefractAmount ("Refract Amount", Range(0.0, 1.0)) = 1.0
}

配置
RenderType設置成queue，確保物體渲染時，其他不透明物體已經渲染到屏幕上

GrabPass定義一個抓取屏幕圖像的pass

SubShader {

    Tags { "Queue"="Transparent" "RenderType"="Opaque" }

    GrabPass { "_RefractionTex" }

    Pass {      
        CGPROGRAM

        #pragma vertex vert
        #pragma fragment frag

        #include "UnityCG.cginc"

        sampler2D _MainTex;
        float4 _MainTex_ST;
        sampler2D _BumpMap;
        float4 _BumpMap_ST;
        samplerCUBE _Cubemap;
        float _Distortion;
        fixed _RefractAmount;
        sampler2D _RefractionTex;

        //紋理紋素大小
        float4 _RefractionTex_TexelSize;

        struct a2v {
            float4 vertex : POSITION;
            float3 normal : NORMAL;
            float4 tangent : TANGENT; 
            float2 texcoord: TEXCOORD0;
        };

        struct v2f {
            float4 pos : SV_POSITION;
            float4 scrPos : TEXCOORD0;
            float4 uv : TEXCOORD1;
            float4 TtoW0 : TEXCOORD2;  
            float4 TtoW1 : TEXCOORD3;  
            float4 TtoW2 : TEXCOORD4; 
        };

頂點着色器

v2f vert (a2v v) {
    v2f o;
    o.pos = UnityObjectToClipPos(v.vertex);

    //得到應被抓取的屏幕圖像的採樣座標
    o.scrPos = ComputeGrabScreenPos(o.pos);

    o.uv.xy = TRANSFORM_TEX(v.texcoord, _MainTex);
    o.uv.zw = TRANSFORM_TEX(v.texcoord, _BumpMap);

    float3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;  
    fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);  
    fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);  
    fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w; 

    o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);  
    o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);  
    o.TtoW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z);  

    return o;
}

片元着色器

fixed4 frag (v2f i) : SV_Target {       
    float3 worldPos = float3(i.TtoW0.w, i.TtoW1.w, i.TtoW2.w);
    fixed3 worldViewDir = normalize(UnityWorldSpaceViewDir(worldPos));


    fixed3 bump = UnpackNormal(tex2D(_BumpMap, i.uv.zw));   

    //對屏幕圖像採樣座標進行偏移，模擬折射效果
    float2 offset = bump.xy * _Distortion * _RefractionTex_TexelSize.xy;
    i.scrPos.xy = offset * i.scrPos.z + i.scrPos.xy;
    fixed3 refrCol = tex2D(_RefractionTex, i.scrPos.xy/i.scrPos.w).rgb;

    //從切線空間變換到世界空間
    bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));

    fixed3 reflDir = reflect(-worldViewDir, bump);
    fixed4 texColor = tex2D(_MainTex, i.uv.xy);
    fixed3 reflCol = texCUBE(_Cubemap, reflDir).rgb * texColor.rgb;

    //利用_RefractAmount屬性對反射和折射顏色進行混合，作爲最後的輸出
    fixed3 finalColor = reflCol * (1 - _RefractAmount) + refrCol * _RefractAmount;

    return fixed4(finalColor, 1);
}

渲染紋理對比GrabPass

GrabPass實現簡單，渲染紋理效率高，在移動設備支持好
GrabPass不會重新渲染場景，需要從CPU讀取後備緩存數據，在移動設備上比較耗時