數據庫隱式遊標和顯示遊標

隱式遊標：查詢單行記錄。
Oracle自動在後臺使用的遊標，用戶不參與任何操作！所以對客戶是隱藏的不顯示的！
特徵：
--不能手動的打開，提取，關閉，
--在使用SELECT。。INTO 語句時會自己打開，提取，創建，關閉
通過使用隱式遊標屬性，可以獲得最近執行的SELECT單行語句以及DML語句

顯示遊標：查詢多行記錄。
在PL/SQL如何返回進行多行記錄並族行進行讀取，

顯式遊標使用步驟
定義遊標名稱和SELECT語句
通過OPEN語句打開遊標
通過FETCH語句獲取遊標數據
如果有多行，則在循環語句中使用FETCH語句
關閉遊標

爲什麼要使用遊標變量
遊標變量提供將PL/SQL塊中的多行數據傳遞到外部程序的一種方法。
本質就是傳遞數據所在的內存地址。
遊標變量
遊標就是指向PL/SQL結果集的工作區名稱，而遊標變量就是對這個工作區的引用。
或：遊標變量是一種數據類型，裏面保存的值就是各個具體的遊標 (所對應的內存地址)。

在PL/SQL塊中執行SELECT、INSERT、DELETE和UPDATE語句時，ORACLE會在內存中爲其分配上下文區（Context Area），即緩衝區。遊標是指向該區的一個指針，或是命名一個工作區（Work Area），或是一種結構化數據類型。

在每個用戶會話中，可以同時打開多個遊標，其數量由數據庫初始化參數文件中的OPEN_CURSORS參數定義。

對於不同的SQL語句，遊標的使用情況不同：

SQL語句	遊標
非查詢語句	隱式的
結果是單行的查詢語句	隱式的或顯示的
結果是多行的查詢語句	顯示的

處理顯式遊標

例：

[sql] view plain copy print ?

DECLARE
CURSOR c4(dept_id NUMBER, j_id VARCHAR2) --1、聲明遊標,有參數沒有返回值
IS
SELECT first_name f_name, hire_date FROM employees
WHERE department_id = dept_id AND job_id = j_id;
--基於遊標定義記錄變量，比聲明記錄類型變量要方便，不容易出錯
v_emp_record c4%ROWTYPE;
BEGIN
OPEN c4(90, 'AD_VP'); --2、打開遊標,傳遞參數值
LOOP
FETCH c4 INTO v_emp_record; --3、提取遊標fetch into
IF c4%FOUND THEN
DBMS_OUTPUT.PUT_LINE(v_emp_record.f_name||'的僱傭日期是'
||v_emp_record.hire_date);
ELSE
DBMS_OUTPUT.PUT_LINE('已經處理完結果集了');
EXIT;
END IF;
END LOOP;
CLOSE c4; --4、關閉遊標
END;

DECLARE
   CURSOR c4(dept_id NUMBER, j_id VARCHAR2) --1、聲明遊標,有參數沒有返回值
   IS
      SELECT first_name f_name, hire_date FROM employees
      WHERE department_id = dept_id AND job_id = j_id;

    --基於遊標定義記錄變量，比聲明記錄類型變量要方便，不容易出錯
    v_emp_record c4%ROWTYPE;
BEGIN
   OPEN c4(90, 'AD_VP');             --2、打開遊標,傳遞參數值
   LOOP
      FETCH c4 INTO v_emp_record;    --3、提取遊標fetch into
      IF c4%FOUND THEN
         DBMS_OUTPUT.PUT_LINE(v_emp_record.f_name||'的僱傭日期是'
                            ||v_emp_record.hire_date);
      ELSE
         DBMS_OUTPUT.PUT_LINE('已經處理完結果集了');
         EXIT;
      END IF;
   END LOOP;
   CLOSE c4;                         --4、關閉遊標
END;

退出LOOP或者用：

EXIT WHEN c4%NOTFOUND;

遊標屬性：

Cursor_name%FOUND 布爾型屬性，當最近一次提取遊標操作FETCH成功則爲 TRUE,否則爲FALSE；

Cursor_name%NOTFOUND 布爾型屬性，與%FOUND相反；——注意區別於DO_DATA_FOUND(select into拋出異常)

Cursor_name%ISOPEN 布爾型屬性，當遊標已打開時返回 TRUE；

Cursor_name%ROWCOUNT 數字型屬性，返回已從遊標中讀取的記錄數。

遊標的for循環

PL/SQL語言提供了遊標FOR循環語句，自動執行遊標的OPEN、FETCH、CLOSE語句和循環語句的功能；

當進入循環時，遊標FOR循環語句自動打開遊標，並提取第一行遊標數據；
當程序處理完當前所提取的數據而進入下一次循環時，遊標FOR循環語句自動提取下一行數據供程序處理；
當提取完結果集合中的所有數據行後結束循環，並自動關閉遊標。

格式：

FOR index_variable IN cursor_name[(value[, value]…)] LOOP
-- 遊標數據處理代碼
END LOOP;

其中：

index_variable爲遊標FOR 循環語句隱含聲明的索引變量，該變量爲記錄變量，其結構與遊標查詢語句返回的結構集合的結構相同。在程序中可以通過引用該索引記錄變量元素來讀取所提取的遊標數據，index_variable中各元素的名稱與遊標查詢語句選擇列表中所制定的列名相同。如果在遊標查詢語句的選擇列表中存在計算列，則必須爲這些計算列指定別名後才能通過遊標FOR 循環語句中的索引變量來訪問這些列數據。

例：

[sql] view plain copy print ?

DECLARE
CURSOR c_cursor(dept_no NUMBER DEFAULT 10)
IS
SELECT department_name, location_id FROM departments WHERE department_id <= dept_no;
BEGIN
--當dept_no參數值爲30
FOR c1_rec IN c_cursor(30) LOOP
DBMS_OUTPUT.PUT_LINE(c1_rec.department_name||'---'||c1_rec.location_id);
END LOOP;
--使用默認的dept_no參數值10
FOR c1_rec IN c_cursor LOOP
DBMS_OUTPUT.PUT_LINE(c1_rec.department_name||'---'||c1_rec.location_id);
END LOOP;
END;

DECLARE
  CURSOR c_cursor(dept_no NUMBER DEFAULT 10) 
  IS
    SELECT department_name, location_id FROM departments WHERE department_id <= dept_no;
BEGIN
    --當dept_no參數值爲30
    FOR c1_rec IN c_cursor(30) LOOP        
         DBMS_OUTPUT.PUT_LINE(c1_rec.department_name||'---'||c1_rec.location_id);
    END LOOP;
   
    --使用默認的dept_no參數值10
    FOR c1_rec IN c_cursor LOOP       
         DBMS_OUTPUT.PUT_LINE(c1_rec.department_name||'---'||c1_rec.location_id);
    END LOOP;
END;

或者可以在遊標FOR循環語句中使用子查詢

[sql] view plain copy print ?

BEGIN
FOR c1_rec IN(SELECT department_name, location_id FROM departments) LOOP
DBMS_OUTPUT.PUT_LINE(c1_rec.department_name||'---'||c1_rec.location_id);
END LOOP;
END;

BEGIN
    FOR c1_rec IN(SELECT department_name, location_id FROM departments) LOOP 
       DBMS_OUTPUT.PUT_LINE(c1_rec.department_name||'---'||c1_rec.location_id);
    END LOOP;
END;

處理隱式遊標

顯式遊標主要是用於對查詢語句的處理，尤其是在查詢結果爲多條記錄的情況下；

而對於非查詢語句，如修改、刪除操作，則由ORACLE 系統自動地爲這些操作設置遊標並創建其工作區，隱式遊標的名字爲SQL，這是由ORACLE 系統定義的。

對於隱式遊標的操作，如定義、打開、取值及關閉操作，都由ORACLE 系統自動地完成，無需用戶進行處理。用戶只能通過隱式遊標的相關屬性，來完成相應的操作。在隱式遊標的工作區中，所存放的數據是與用戶自定義的顯示遊標無關的、最新處理的一條SQL 語句所包含的數據。

格式調用爲： SQL%

[sql] view plain copy print ?

DECLARE
v_rows NUMBER;
BEGIN
--更新數據
UPDATE employees SET salary = 30000
WHERE department_id = 90 AND job_id = 'AD_VP';
--獲取默認遊標的屬性值
v_rows := SQL%ROWCOUNT;
DBMS_OUTPUT.PUT_LINE('更新了'||v_rows||'個僱員的工資');
--刪除指定僱員；如果部門中沒有僱員，則刪除部門
DELETE FROM employees WHERE department_id=v_deptno;
IF SQL%NOTFOUND THEN
DELETE FROM departments WHERE department_id=v_deptno;
END IF;
END;

DECLARE
   v_rows NUMBER;
BEGIN
   --更新數據
   UPDATE employees SET salary = 30000
     WHERE department_id = 90 AND job_id = 'AD_VP';
   --獲取默認遊標的屬性值
   v_rows := SQL%ROWCOUNT;
   DBMS_OUTPUT.PUT_LINE('更新了'||v_rows||'個僱員的工資');
   
    --刪除指定僱員；如果部門中沒有僱員，則刪除部門
    DELETE FROM employees WHERE department_id=v_deptno;
    IF SQL%NOTFOUND THEN
        DELETE FROM departments WHERE department_id=v_deptno;
    END IF;
END;

更新或刪除當前遊標數據

遊標查詢語句中必須使用FOR UPDATE選項，以便在打開遊標時鎖定遊標結果集合在表中對應數據行的所有列和部分列。

如果另一個會話已對活動集中的行加了鎖，那麼SELECT FOR UPDATE操作一直等待到其它的會話釋放這些鎖後才繼續自己的操作；對於這種情況，當加上NOWAIT子句時，如果這些行真的被另一個會話鎖定，則OPEN立即返回並給出：

ORA-0054 ：resource busy and acquire with nowait specified.

[sql] view plain copy print ?

DECLARE
V_deptno employees.department_id%TYPE :=&p_deptno;
CURSOR emp_cursor
IS
SELECT employees.employee_id, employees.salary
FROM employees WHERE employees.department_id=v_deptno
FOR UPDATE NOWAIT; --1、for update
BEGIN
FOR emp_record IN emp_cursor LOOP
IF emp_record.salary < 1500 THEN
UPDATE employees SET salary=1500
WHERE CURRENT OF emp_cursor; --2、WHERE CURRENT OF cursor_name子句
END IF;
END LOOP;
END;

DECLARE 
    V_deptno employees.department_id%TYPE :=&p_deptno;
    CURSOR emp_cursor 
  IS 
  SELECT employees.employee_id, employees.salary 
    FROM employees WHERE employees.department_id=v_deptno
  FOR UPDATE NOWAIT;                    --1、for update
BEGIN
    FOR emp_record IN emp_cursor LOOP
      IF emp_record.salary < 1500 THEN
        UPDATE employees SET salary=1500
            WHERE CURRENT OF emp_cursor; --2、WHERE CURRENT OF cursor_name子句
      END IF;
    END LOOP;
END;

動態遊標

與遊標一樣，動態遊標（遊標變量）也是一個指向多行查詢結果集合中當前數據行的指針。但與遊標不同的是，遊標變量是動態的，而遊標是靜態的。

遊標只能與指定的查詢相連，即固定指向一個查詢的內存處理區域，而遊標變量則可與不同的查詢語句相連，它可以指向不同查詢語句的內存處理區域（但不能同時指向多個內存處理區域，在某一時刻只能與一個查詢語句相連），只要這些查詢語句的返回類型兼容即可。

[sql] view plain copy print ?

DECLARE
--定義一個遊標數據類型
TYPE emp_cursor_type IS REF CURSOR;
--聲明一個遊標變量
c1 EMP_CURSOR_TYPE;
--聲明兩個記錄變量
v_emp_record employees%ROWTYPE;
v_reg_record regions%ROWTYPE;
BEGIN
OPEN c1 FOR SELECT * FROM employees WHERE department_id = 20;
LOOP
FETCH c1 INTO v_emp_record;
EXIT WHEN c1%NOTFOUND;
DBMS_OUTPUT.PUT_LINE(v_emp_record.first_name||'的僱傭日期是'
||v_emp_record.hire_date);
END LOOP;
--將同一個遊標變量對應到另一個SELECT語句
OPEN c1 FOR SELECT * FROM regions WHERE region_id IN（1，2）;
LOOP
FETCH c1 INTO v_reg_record;
EXIT WHEN c1%NOTFOUND;
DBMS_OUTPUT.PUT_LINE(v_reg_record.region_id||'表示'
||v_reg_record.region_name);
END LOOP;
CLOSE c1;
END;

DECLARE
   --定義一個遊標數據類型
   TYPE emp_cursor_type IS REF CURSOR;
   --聲明一個遊標變量
   c1 EMP_CURSOR_TYPE;
   --聲明兩個記錄變量
   v_emp_record employees%ROWTYPE;
   v_reg_record regions%ROWTYPE;

BEGIN
   OPEN c1 FOR SELECT * FROM employees WHERE department_id = 20;
   LOOP
      FETCH c1 INTO v_emp_record;
      EXIT WHEN c1%NOTFOUND;
      DBMS_OUTPUT.PUT_LINE(v_emp_record.first_name||'的僱傭日期是'
                            ||v_emp_record.hire_date);
   END LOOP;
   --將同一個遊標變量對應到另一個SELECT語句
   OPEN c1 FOR SELECT * FROM regions WHERE region_id IN（1，2）;
   LOOP
      FETCH c1 INTO v_reg_record;
      EXIT WHEN c1%NOTFOUND;
      DBMS_OUTPUT.PUT_LINE(v_reg_record.region_id||'表示'
                            ||v_reg_record.region_name);
   END LOOP;
   CLOSE c1;
END;

數據庫隱式遊標和顯示遊標

處理顯式遊標

遊標的for循環

處理隱式遊標

更新或刪除當前遊標數據

動態遊標

數據庫隱式遊標和顯示遊標

char與varchar

in與exist

java.io.fileinputstream cannot be cast to java.io.file

Error: PL/SQL: ORA-00980: 同義詞轉換不再有效

Mac下配置sublime實現LaTeX

https://yachay.unat.edu.pe/blog/index.php?comment_area=format_blog&comment_component=blog&comment_co

linux以太網驅動總結