[MSSQL]SQL實現工作日處理函數(標準節假日)

計算兩個日期相差的工作天數

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[f_WorkDay]') and xtype in (N'FN', N'IF', N'TF'))
drop function [dbo].[f_WorkDay]
GO

--計算兩個日期相差的工作天數
CREATE FUNCTION f_WorkDay(
@dt_begin datetime,  --計算的開始日期
@dt_end  datetime    --計算的結束日期
)RETURNS int
AS
BEGIN
 DECLARE @workday int,@i int,@bz bit,@dt datetime
 IF @dt_begin>@dt_end
  SELECT @bz=1,@dt=@dt_begin,@dt_begin=@dt_end,@dt_end=@dt
 ELSE
  SET @bz=0
 SELECT @i=DATEDIFF(Day,@dt_begin,@dt_end)+1,
  @workday=@i/7*5,
  @dt_begin=DATEADD(Day,@i/7*7,@dt_begin)
 WHILE @dt_begin<=@dt_end
 BEGIN
  SELECT @workday=CASE
   WHEN (@@DATEFIRST+DATEPART(Weekday,@dt_begin)-1)%7 BETWEEN 1 AND 5
   THEN @workday+1 ELSE @workday END,
   @dt_begin=@dt_begin+1
 END
 RETURN(CASE WHEN @bz=1 THEN -@workday ELSE @workday END)
END
GO

在指定日期上,增加指定工作天數後的日期

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[f_WorkDayADD]') and xtype in (N'FN', N'IF', N'TF'))
drop function [dbo].[f_WorkDayADD]
GO

--在指定日期上,增加指定工作天數後的日期
CREATE FUNCTION f_WorkDayADD(
@date    datetime,  --基礎日期
@workday int       --要增加的工作日數
)RETURNS datetime
AS
BEGIN
 DECLARE @bz int
 --增加整週的天數
 SELECT @bz=CASE WHEN @workday<0 THEN -1 ELSE 1 END
  ,@date=DATEADD(Week,@workday/5,@date)
  ,@workday=@workday%5
 --增加不是整週的工作天數
 WHILE @workday<>0
  SELECT @date=DATEADD(Day,@bz,@date),
   @workday=CASE WHEN (@@DATEFIRST+DATEPART(Weekday,@date)-1)%7 BETWEEN 1 AND 5
    THEN @workday-@bz ELSE @workday END
 --避免處理後的日期停留在非工作日上
 WHILE (@@DATEFIRST+DATEPART(Weekday,@date)-1)%7 in(0,6)
  SET @date=DATEADD(Day,@bz,@date)
 RETURN(@date)
END