这是Samsung的S3C44B0（ARM7TDMI）芯片的经典bootloader，转自木瓜老C的注解，很值得参考。
http://blog.chinaunix.net/u1/58640/showart_494549.html
; *******************************************************
; * NAME : 44BINIT.S *
; * Version : 10.JAn.2003 *
; * Description: *
; * C start up codes *
; * Configure memory, Initialize ISR ,stacks *
; * Initialize C-variables *
; * Fill zeros into zero-initialized C-variables *
; * 思瑞讯电子增加注释说明 2007-03-30
; *******************************************************
GET ../inc/option.a
GET ../inc/memcfg.a
;Interrupt Control ;声明符号常量定义寄存器的对应地址
INTPND EQU 0x01e00004
INTMOD EQU 0x01e00008
INTMSK EQU 0x01e0000c
I_ISPR EQU 0x01e00020
I_CMST EQU 0x01e0001c
;Watchdog timer
WTCON EQU 0x01d30000
;Clock Controller
PLLCON EQU 0x01d80000
CLKCON EQU 0x01d80004
LOCKTIME EQU 0x01d8000c
;Memory Controller
REFRESH EQU 0x01c80024
;Pre-defined constants
USERMODE EQU 0x10
FIQMODE EQU 0x11
IRQMODE EQU 0x12
SVCMODE EQU 0x13
ABORTMODE EQU 0x17
UNDEFMODE EQU 0x1b
MODEMASK EQU 0x1f
NOINT EQU 0xc0
;check if tasm.exe is used.
GBLL THUMBCODE ;定义全局逻辑变量THUMBCODE
[ {CONFIG} = 16 ;相当于if (CONFIG==16)
THUMBCODE SETL {TRUE} ;THUMBCODE=TRUE；
CODE32 ;声明为32位指令集，即使用ARM指令进行编译
| ;else
THUMBCODE SETL {FALSE} ;THUMBCODE=FALSE；
]
[ THUMBCODE ;if THUMBCODE=TRUE
CODE32 ;转入32位编译模式
]
;以下位宏定义，任何调用HandlerXXX HANDLER HandleXXX都将被下面的程序展开
;该宏定义的代码用于将对应中断服务程序ISR的入口地址装载到PC中，可称之为“加载程序”
;本初始化程序定义了一个34个字空间的数据区（在文件最后），用于存放相应中断服务程序的首地址。
;每个字空间都有一个标号，以HandleXXX命名。
;在向量中断模式下使用“加载程序”来执行中断服务程序。
;******************************************************************************
;**********向量(矢量)中断和非向量(非矢量)中断模式的概念与区别******************
;（一）www.chinasrx.com
;向量中断模式是当CPU读取位于0x18处的IRQ中断指令的时候，系统自动读取对应于该中断源确定地址上的指令取代0x18处的指令，
;通过跳转指令系统就直接跳转到对应地址函数中，节省了中断处理时间提高了中断处理速度。
;例如 ADC 中断的向量地址为0xC0,则在0xC0处放如下代码：ldr PC,=HandlerADC 当ADC中断产生的时候系统会
;自动跳转到HandlerADC函数中处理中断。
;（二）www.chinasrx.com
;非向量中断模式处理方式是一种传统的中断处理方法，当系统产生中断的时候，系统将INTPND寄存器中对应标志位置位，
;然后跳转到位于0x18处的统一中断函数中；
;该函数通过读取INTPND寄存器中对应标志位来判断中断源，并根据优先级关系再跳到对应中断源的处理代码中处理中断。
MACRO
$HandlerLabel HANDLER $HandleLabel
$HandlerLabel
;由于ADS仅支持FD（满递减）型堆栈
sub sp,sp,#4 ;将堆栈退一个字用于保存下面用到的R0
stmfd sp!,{r0} ;将R0压入堆栈
ldr r0,=$HandleLabel ;将HandleLabel的地址赋给R0
ldr r0,[r0] ;将HandleLabel的地址指向的内容(实际的执行地址)赋给R0
str r0,[sp,#4] ;将对应的中断函数首地址入栈保护
ldmfd sp!,{r0,pc} ;将中断函数的首地址出栈，放入PC中，系统将跳转到对应中断处理函数
MEND
;ARM的系统软件开发中主要包含RO，RW,ZI三个段组成。
;其中RO为代码段；RW为已经初始化的全局变量；ZI是未初始化的全局变量
;（对于GNU来说，依次对.text .data .bss段）
;值得说明的是：
;Bootloader要将RW段复制到RAM中并将ZI段清零；
;编译器要使用下列段来记录各段的起始和结束地址。
; |Image$$RO$$Base| ; RO段起始地址
; |Image$$RO$$Limit| ; RO段结束地址＋1
; |Image$$RW$$Base| ; RW段起始地址
; |Image$$RW$$Limit| ; RW段结束地址＋1
; |Image$$ZI$$Base| ; ZI段起始地址
; |Image$$ZI$$Limit| ; ZI段结束地址＋1
;这些标号的值是通过编译器的设定来确定的，如编译软件中对RO-base和RW-Base的设定
IMPORT |Image$$RO$$Limit| ; ROM代码的结束地址(rom数据的起始地址)
IMPORT |Image$$RW$$Base| ; RAM中需初始化的首地址
IMPORT |Image$$ZI$$Base| ; 需初始化为0的全局变量的首地址
IMPORT |Image$$ZI$$Limit| ; 结束地址
IMPORT Main ;主程序的入口
;以下为代码段
AREA Init,CODE,READONLY
;说明：
;关键字ENTRY告诉编译器保留这段代码。
;从代码看Init段就是要写入0x00地址的原始中断向量，
;因此把这个文件编译生成的44binit.O和Init填入ADS-Linker-Layout页对应项中。
;【这样编译器会把该段代码编译到0X0地址。】
;异常中断向量表【每个表项占4个字节】
;一旦系统运行时有中断发生,即使移植了操作系统,如linux。
;处理器已经把控制权交给了操作系统，一旦发生中断，处理器还是会跳转到从0x0开始执行
;中断向量表中的对应中断。
;具体中断向量布局参考S3C44B0X的数据手册
;例如 ADC 的中断向量为 0x000000c0 下面对应表中第49项位置
;对应向量地址为 0x0+4*(49-1)= 0x000000c0
ENTRY ;ENTRY程序入口标号需要顶格式写，否则出错。
b ResetHandler ;复位异常
b HandlerUndef ;未定义异常
b HandlerSWI ;软件中断异常
b HandlerPabort ;指令预取异常
b HandlerDabort ;数据预取异常
b . ;保留
b HandlerIRQ ;外部中断 外设中断都是在这里扩展的
b HandlerFIQ ;快速中断
;***IMPORTANT NOTE***
;If the H/W vectored interrutp mode is enabled, The above two instructions should
;be changed like below, to work-around with H/W bug of S3C44B0X interrupt controller.
; b HandlerIRQ -> subs pc,lr,#4
; b HandlerIRQ -> subs pc,lr,#4
;说明：原文注明当使用向量中断模式时，需用subs pc,lr,#4来代替前面的语句
; 这是原来S3C44B0X硬件中的一个BUG，后期推出的S3C44B0X已经解决此BUG，但是为了兼容
; 早期的版本，用subs pc,lr,#4替换后也可以正常工作，相当于现在的硬件中两条语句都
; 可以兼容，后期的器件手册中已经注明可以直接采用b HandlerIRQ的方式
;www.chinasrx.com
VECTOR_BRANCH
ldr pc,=HandlerEINT0 ;mGA H/W interrupt vector table
ldr pc,=HandlerEINT1 ;
ldr pc,=HandlerEINT2 ;
ldr pc,=HandlerEINT3 ;
ldr pc,=HandlerEINT4567 ;
ldr pc,=HandlerTICK ;mGA
b .
b .
ldr pc,=HandlerZDMA0 ;mGB
ldr pc,=HandlerZDMA1 ;
ldr pc,=HandlerBDMA0 ;
ldr pc,=HandlerBDMA1 ;
ldr pc,=HandlerWDT ;
ldr pc,=HandlerUERR01 ;mGB
b .
b .
ldr pc,=HandlerTIMER0 ;mGC
ldr pc,=HandlerTIMER1 ;
ldr pc,=HandlerTIMER2 ;
ldr pc,=HandlerTIMER3 ;
ldr pc,=HandlerTIMER4 ;
ldr pc,=HandlerTIMER5 ;mGC
b .
b .
ldr pc,=HandlerURXD0 ;mGD
ldr pc,=HandlerURXD1 ;
ldr pc,=HandlerIIC ;
ldr pc,=HandlerSIO ;
ldr pc,=HandlerUTXD0 ;
ldr pc,=HandlerUTXD1 ;mGD
b .
b .
ldr pc,=HandlerRTC ;mGKA
b . ;
b . ;
b . ;
b . ;
b . ;mGKA
b .
b .
ldr pc,=HandlerADC ;mGKB
b . ;
b . ;
b . ;
b . ;
b . ;mGKB
b .
b .
;0xe0=EnterPWDN
ldr pc,=EnterPWDN
LTORG
;下面是具体的中断处理函数跳转的宏，通过上面的$HandlerLabel的宏定义
;展开后跳转到对应的中断处理函数（ISR）处理中断（对于向量中断）
HandlerFIQ HANDLER HandleFIQ
HandlerIRQ HANDLER HandleIRQ
HandlerUndef HANDLER HandleUndef
HandlerSWI HANDLER HandleSWI
HandlerDabort HANDLER HandleDabort
HandlerPabort HANDLER HandlePabort
HandlerADC HANDLER HandleADC
HandlerRTC HANDLER HandleRTC
HandlerUTXD1 HANDLER HandleUTXD1
HandlerUTXD0 HANDLER HandleUTXD0
HandlerSIO HANDLER HandleSIO
HandlerIIC HANDLER HandleIIC
HandlerURXD1 HANDLER HandleURXD1
HandlerURXD0 HANDLER HandleURXD0
HandlerTIMER5 HANDLER HandleTIMER5
HandlerTIMER4 HANDLER HandleTIMER4
HandlerTIMER3 HANDLER HandleTIMER3
HandlerTIMER2 HANDLER HandleTIMER2
HandlerTIMER1 HANDLER HandleTIMER1
HandlerTIMER0 HANDLER HandleTIMER0
HandlerUERR01 HANDLER HandleUERR01
HandlerWDT HANDLER HandleWDT
HandlerBDMA1 HANDLER HandleBDMA1
HandlerBDMA0 HANDLER HandleBDMA0
HandlerZDMA1 HANDLER HandleZDMA1
HandlerZDMA0 HANDLER HandleZDMA0
HandlerTICK HANDLER HandleTICK
HandlerEINT4567 HANDLER HandleEINT4567
HandlerEINT3 HANDLER HandleEINT3
HandlerEINT2 HANDLER HandleEINT2
HandlerEINT1 HANDLER HandleEINT1
HandlerEINT0 HANDLER HandleEINT0
;One of the following two routines can be used for non-vectored interrupt.
;下面这段程序是用来处理非向量中断，具体判断I_ISPR中各位是否置1 置1表示目前此中断等待响应（每次只能有一位置1），从最高优先级中断位开始判断，检测到等待服务
;中断就将pc置为中断服务函数首地址
IsrIRQ ;using I_ISPR register.
sub sp,sp,#4 ;reserved for PC
stmfd sp!,{r8-r9}
;IMPORTANT CAUTION
;if I_ISPC isn't used properly, I_ISPR can be 0 in this routine.
ldr r9,=I_ISPR
ldr r9,[r9]
mov r8,#0x0
0
movs r9,r9,lsr #1
bcs %F1
add r8,r8,#4
b %B0
1
ldr r9,=HandleADC
add r9,r9,r8
ldr r9,[r9]
str r9,[sp,#8]
ldmfd sp!,{r8-r9,pc}
;****************************************************
;* START *www.chinasrx.com
;****************************************************
;板子上电和复位后，程序开始从位于0x0处执行b ResetHandler ，从而跳转到这里执行程序。
;板子上电复位后，执行以下几个步骤，这里通过标号在注释中加1，2，3....表示，标号表示执行顺序
;1.禁止看门狗，屏蔽所有中断
ResetHandler
ldr r0,=WTCON ;watch dog disable
ldr r1,=0x0
str r1,[r0]
ldr r0,=INTMSK
ldr r1,=0x07ffffff ;all interrupt disable
str r1,[r0]
;2.根据工作频率设置PLL
;这里介绍一下计算公式
; Fpllo=(m*Fin)/(p*2^s)
; m=MDIV+8,p=PDIV+2,s=SDIV
; Fpllo必须大于20Mhz小于66Mhz
; Fpllo*2^s必须小于170Mhz
;如下面的PLLCON设定中的M_DIV P_DIV S_DIV是取自option.h中
;#elif (MCLK==40000000)
;#define PLL_M (0x48)
;#define PLL_P (0x3)
;#define PLL_S (0x2)
;所以m=MDIV+8=80,p=PDIV+2=5,s=SDIV=2
;硬件使用晶振为10Mhz,即Fin=10Mhz
;Fpllo=80*10/5*2^2=40Mhz
;****************************************************
;* Set clock control registers *
;****************************************************
ldr r0,=LOCKTIME
ldr r1,=800 ; count = t_lock * Fin (t_lock=200us, Fin=4MHz) = 800
str r1,[r0]
[ PLLONSTART
ldr r0,=PLLCON ;temporary setting of PLL
ldr r1,=((M_DIV<<12)+(P_DIV<<4)+S_DIV) ;Fin=10MHz,Fout=40MHz
str r1,[r0]
]
ldr r0,=CLKCON
ldr r1,=0x7ff8 ;All unit block CLK enable
str r1,[r0]
;3.设置存储相关寄存器的程序
;主要设置SDRAM,flash ROM 存储器连接和工作时序的程序,以及片选定义的程序
;SMRDATA map在下面的程序中定义
;SMRDATA中涉及的值请参考memcfg.s程序
;具体寄存器各位含义请参考S3C44B0X Specification
;www.chinasrx.com
;****************************************************
;* Set memory control registers *
;****************************************************
ldr r0,=SMRDATA
ldmia r0,{r1-r13}
ldr r0,=0x01c80000 ;BWSCON Address
stmia r0,{r1-r13}
;****************************************************
;* Initialize stacks *
;****************************************************
ldr sp, =SVCStack ;Why?
bl InitStacks
;
;5.设置缺省中断处理函数
;****************************************************
;* Setup IRQ handler *
;****************************************************
ldr r0,=HandleIRQ ;This routine is needed
ldr r1,=IsrIRQ ;if there isn't 'subs pc,lr,#4' at 0x18, 0x1c
str r1,[r0]
;6.将数据段拷贝到RAM中,将ZI数据段清零,跳入C语言的main函数执行。
;到这里Bootloader初步引导结束。拷贝|Image$$RO$$Limit|起始的大小为（|Image$$ZI$$Base|－|Image$$RW$$Base|）
;的数据拷贝到|Image$$RW$$Base|对应的数据单元处。
;********************************************************
;* Copy and paste RW data/zero initialized data *
;********************************************************
LDR r0, =|Image$$RO$$Limit| ; Get pointer to ROM data
LDR r1, =|Image$$RW$$Base| ; and RAM copy
LDR r3, =|Image$$ZI$$Base|
;Zero init base => top of initialised data
CMP r0, r1 ; Check that they are different
BEQ %F1
0
CMP r1, r3 ; Copy init data
LDRCC r2, [r0], #4 ;--> LDRCC r2, [r0] + ADD r0, r0, #4
STRCC r2, [r1], #4 ;--> STRCC r2, [r1] + ADD r1, r1, #4
BCC %B0
1
LDR r1, =|Image$$ZI$$Limit| ; Top of zero init segment
MOV r2, #0
2
CMP r3, r1 ; Zero init
STRCC r2, [r3], #4
BCC %B2
[ :LNOT:THUMBCODE
BL Main ;Don't use main() because ......
;跳入main()函数
B .
]
[ THUMBCODE ;for start-up code for Thumb mode
orr lr,pc,#1
bx lr
CODE16
bl Main ;Don't use main() because ......
b .
CODE32
]
;4.初始化各模式下的堆栈指针
;****************************************************
;* The function for initializing stack *
;****************************************************
InitStacks
;Don't use DRAM,such as stmfd,ldmfd......
;SVCstack is initialized before
;Under toolkit ver 2.50, 'msr cpsr,r1' can be used instead of 'msr cpsr_cxsf,r1'
mrs r0,cpsr
bic r0,r0,#MODEMASK
orr r1,r0,#UNDEFMODE|NOINT
msr cpsr_cxsf,r1 ;UndefMode
ldr sp,=UndefStack
orr r1,r0,#ABORTMODE|NOINT
msr cpsr_cxsf,r1 ;AbortMode
ldr sp,=AbortStack
orr r1,r0,#IRQMODE|NOINT
msr cpsr_cxsf,r1 ;IRQMode
ldr sp,=IRQStack
orr r1,r0,#FIQMODE|NOINT
msr cpsr_cxsf,r1 ;FIQMode
ldr sp,=FIQStack
bic r0,r0,#MODEMASK|NOINT
orr r1,r0,#SVCMODE
msr cpsr_cxsf,r1 ;SVCMode
ldr sp,=SVCStack
;USER mode is not initialized.
mov pc,lr ;The LR register may be not valid for the mode changes.
;
;下面是PWDN模式下的相关寄存器的定义
;****************************************************
;* The function for entering power down mode *
;****************************************************
;void EnterPWDN(int CLKCON);
EnterPWDN
mov r2,r0 ;r0=CLKCON
ldr r0,=REFRESH
ldr r3,[r0]
mov r1, r3
orr r1, r1, #0x400000 ;self-refresh enable
str r1, [r0]
nop ;Wait until self-refresh is issued. May not be needed.
nop ;If the other bus master holds the bus, ...
nop ; mov r0, r0
nop
nop
nop
nop
;enter POWERDN mode
ldr r0,=CLKCON
str r2,[r0]
;wait until enter SL_IDLE,STOP mode and until wake-up
mov r0,#0xff
0 subs r0,r0,#1
bne %B0
;exit from DRAM/SDRAM self refresh mode.
ldr r0,=REFRESH
str r3,[r0]
mov pc,lr
LTORG
;
;
;这是上面提到的对存储寄存器初始化的数据映射表（DATA Map）
SMRDATA DATA
;*****************************************************************
;* Memory configuration has to be optimized for best performance *
;* The following parameter is not optimized. *
;*****************************************************************
;*** memory access cycle parameter strategy ***
; 1) Even FP-DRAM, EDO setting has more late fetch point by half-clock
; 2) The memory settings,here, are made the safe parameters even at 66Mhz.
; 3) FP-DRAM Parameters:tRCD=3 for tRAC, tcas=2 for pad delay, tcp=2 for bus load.
; 4) DRAM refresh rate is for 40Mhz.
DCD 0x11110090 ;Bank0=OM[1:0], Bank1~Bank7=16bit, bank2=8bit;
DCD
((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC))
;GCS0
DCD
((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC))
;GCS1
DCD
((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC))
;GCS2
DCD
((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC))
;GCS3
DCD
((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC))
;GCS4
DCD
((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC))
;GCS5
DCD ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN)) ;GCS6
DCD ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN)) ;GCS7
DCD
((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT)
;REFRESH RFEN=1, TREFMD=0, trp=3clk, trc=5clk, tchr=3clk,count=1019
DCD 0x16 ;SCLK power mode, BANKSIZE 32M/32M
DCD 0x20 ;MRSR6 CL=2clk
DCD 0x20 ;MRSR7
ALIGN
;下面是对RAM区域数据映射表的（DATA Map）的定义
AREA RamData, DATA, READWRITE
;从地址(_ISR_STARTADDRESS-0x500)处保留指定字节数的空间
^ (_ISR_STARTADDRESS-0x500)
UserStack # 256 ;c1(c7)ffa00 ;以地址(_ISR_STARTADDRESS-0x500)起始保留连续256个字节
SVCStack # 256 ;c1(c7)ffb00 ;紧接着保留256个字节
UndefStack # 256 ;c1(c7)ffc00
AbortStack # 256 ;c1(c7)ffd00
IRQStack # 256 ;c1(c7)ffe00
FIQStack # 0 ;c1(c7)fff00
;从地址_ISR_STARTADDRESS处保留指定字节数的空间
^ _ISR_STARTADDRESS ;该值在OPTION.h中定义
HandleReset # 4 ;保留4个连续字节
HandleUndef # 4
HandleSWI # 4
HandlePabort # 4
HandleDabort # 4
HandleReserved # 4
HandleIRQ # 4
HandleFIQ # 4
;Don't use the label 'IntVectorTable',
;because armasm.exe cann't recognize this label correctly.
;the value is different with an address you think it may be.
;IntVectorTable
HandleADC # 4
HandleRTC # 4
HandleUTXD1 # 4
HandleUTXD0 # 4
HandleSIO # 4
HandleIIC # 4
HandleURXD1 # 4
HandleURXD0 # 4
HandleTIMER5 # 4
HandleTIMER4 # 4
HandleTIMER3 # 4
HandleTIMER2 # 4
HandleTIMER1 # 4
HandleTIMER0 # 4
HandleUERR01 # 4
HandleWDT # 4
HandleBDMA1 # 4
HandleBDMA0 # 4
HandleZDMA1 # 4
HandleZDMA0 # 4
HandleTICK # 4
HandleEINT4567 # 4
HandleEINT3 # 4
HandleEINT2 # 4
HandleEINT1 # 4
HandleEINT0 # 4 ;0xc1(c7)fff84
END
------------------------------------------------------------------------------------------------------------------------------------
------------------------------------------------------------------------------------------------------------------------------------
44B0的初始化程序就是初始化各个关键的寄存器，建立中断向量，然后转移到主函数去执行程序。
不过44B0不支持地址映射，所以程序不COPY到RAM种执行。44B0初始化对我们广大
初学者来说，比较难理解的是中断的处理和一些少见的操作符号，44b0的中断子程序地址存放在初始化程序最后就是
HandleADC # 4
HandleRTC # 4
HandleUTXD1 # 4
HandleUTXD0 # 4
HandleSIO # 4
HandleIIC # 4
HandleURXD1 # 4
HandleURXD0 # 4
这一段，它的其实地址是ISR_STARTADDRESS，个人写中断程序的时候，子程序地址被编译器连放在相应的位置。初始化完成后，程序转通过BL Main 转到用户定义的主程序上执行。以下是我个人的一些理解：
GBLL THUMBCODE
[ {CONFIG} = 16
THUMBCODE SETL {TRUE}
CODE32
|
THUMBCODE SETL {FALSE}
]
[ THUMBCODE
CODE32 ;for start-up code for Thumb mode
]
×××××××××××××××××××××××
其中[=IF ，|=ELSE ，]= ENDIF， CODE32 表明以下操作都在ARM状态。这些都是伪操作
这段我理解为设定THUMCODE的值，然后确定，用户的程序是在ARM状态还是THUM状态。不过不管THUMCODE是何值，下面代码都是ARM状态这段没有什么很复杂的，就是这三个[，|，]操作符让我迷惑了半天，翻了半天书才找到解释
MACRO 宏 伪操作
$HandlerLabel HANDLER（宏的名称） $HandleLabel（宏的参数）
$HandlerLabel
sub sp,sp,#4 ;decrement sp(to store jump address)
stmfd sp!,{r0} ;PUSH the work register to stack(lr does't push because it return to original address)
ldr r0,=$HandleLabel;load the address of HandleXXX to r0
ldr r0,[r0] ;load the contents(service routine start address) of HandleXXX
str r0,[sp,#4] ;store the contents(ISR) of HandleXXX to stack
ldmfd sp!,{r0,pc} ;POP the work register and pc(jump to ISR)
MEND
*******************************
这
段当初我觉得比较难理解，不过通过看各种程序，对这段有了一个基本的理解。这个宏的作用是把各个中断程序的地址装入当前的PC，44B0有两种装断模式
一种是没有中断向量表，一种是使用中断向量表的使用中断向量表只能是IRQ方式，当使用中断向量表的时候，中断发生时由44B0的中断控制器自动跳转到相
应的位置。比如在中断向量表的模式下，一个外部中断0发生程序自动跳转到 地址0X20处，0X20地址单元的指令时ldr
pc,=HandlerEINT0因而程序PC跳到HandlerEINT0处，执行这个宏操作，把外部中断的函数的地址赋给PC。
44B0里面定义了一个#define pISR_EINT0 (*(unsigned
*)(_ISR_STARTADDRESS+0x84))
,_ISR_STARTADDRES是中断程序地址的起始地址，_ISR_STARTADDRESS＋0X84是HandleEINT0的地址
例如一个外部中断函数名void EXINT(),程序里执行 pISR_EINT0＝（unsigned)EXIT,就把自己的函数地址赋给了标号为HandleEINT0处的内存单元
IMPORT |Image$$RO$$Limit| ; End of ROM code (=start of ROM data)
IMPORT |Image$$RW$$Base| ; Base of RAM to initialise
IMPORT |Image$$ZI$$Base| ; Base and limit of area
IMPORT |Image$$ZI$$Limit| ; to zero initialise
××××××××××××××××××××××××××××××××××
这段我个人的理解为这些是连接器生成的于输出段相关的符号，是在没有使用SCATTER文件的情况可以调用。
这段指出了在ROM和RAM种的数据的地址，这些地址应该是连接器生成的，不过为什么能调用
连接器生产的符号，我不大明白其中的原因，还希望各位说说自己的理解
IsrIRQ ;using I_ISPR register.
sub sp,sp,#4 ;reserved for PC
stmfd sp!,{r8-r9}
;IMPORTANT CAUTION
;if I_ISPC isn't used properly, I_ISPR can be 0 in this routine.
ldr r9,=I_ISPR
ldr r9,[r9]
mov r8,#0x0
0
movs r9,r9,lsr #1
bcs %F1
add r8,r8,#4
b %B0
1
ldr r9,=HandleADC
add r9,r9,r8
ldr r9,[r9]
str r9,[sp,#8]
ldmfd sp!,{r8-r9,pc}
×××××××××××××××××××××××
这段是没有使用装断向量模式下如何装载中断子程序，因为44B0有30个中断源，所以需要程序处理以确定调用那个中断程序
0，1是局部标号，％B是向后搜索局部标号， %F是向前搜索局部标号 。都是伪操作
I_ISPR寄存器各位表明发生了应该调用那个中断子程序。只能1位置位，其它位为0，比如说串口1发送中断发生，这时I_ISPR的
值为0X04，
ldr r9,=I_ISPR
ldr r9,[r9] 两条指令后，r9的内容为0X4 ,
movs r9,r9,lsr #1 r9内容右移一位
bcs %F1 判断是否把置位是否转移到C位，
add r8,r8,#4 如果没有的R8加4
如
果r9内容为0x04 需要右移3次 ，之后r8的内容为8 然后HandleADC的地址 加上r8的值
就是串口1发送中断的地址，这个地址的内容是中断子程序的地址再说明几个伪操作：^=MAP.
#=field别的方面我觉得比较容易理解了，就不多讲了。
------------------------------------------------------------------------------------------------------------------------------------
------------------------------------------------------------------------------------------------------------------------------------
ARM汇编程序分析过程中，比较难理解的是他的伪操作、宏指令和伪指令。本文是结合44B0X引导程序中出现伪操作、宏指令和伪指令进行总结，便于进一步分析44B0X的引导。
一、GET option.s
功能：引进一个被编译过的文件。
格式：GET filename
其中：fiename 汇编时引入的文件名，可以有路径名。
GET符号在汇编时对宏定义，EQU符号以及存储映射时是很有用的，在引入文件汇编完以后，汇编将从GET符号后开始。在被引入的文件中可能有GET符号再引入其他的文件。GET符号不能用来引入目标文件。
二、INTPND EQU 0x01e00004
功能：对一个数字常量赋予一个符号名。
格式：name EQU expression
其中：name 符号名。Expression 寄存器相关或者程序相关的固定值。
使用EQU定义常量，与C语言中用#define定义一个常量相同。
例：num EQU 2 ； 数字2赋予符号num
三、GBLL THUMBCODE
[ {CONFIG} = 16
THUMBCODE SETL {TRUE}
CODE32
|
THUMBCODE SETL {FALSE}
]
CODE32 ;for start-up code for Thumb mode
]
四、MACRO
$HandlerLabel HANDLER $HandleLabel
$HandlerLabel
sub sp,sp,#4 ;decrement sp(to store jump address)
stmfd sp!,{r0} ;PUSH the work register to stack
ldr r0,=$HandleLabel;load the address of HandleXXX to r0
ldr r0,[r0] ;load the contents(service routine start address) of HandleXXX
str r0,[sp,#4] ;store the contents(ISR) of HandleXXX to stack
ldmfd sp!,{r0,pc} ;POP the work register and pc(jump to ISR)
MEND
功能：标志以下宏的定义。
格式：MACRO
Macro_prototype
MEND
宏表达式的格式如下：
{$label} macroname {$ parameter{,parameter2}…}
其中：
$ label 参数，在宏使用时，被给定的符号替代。
Macroname 宏的名称，并不一定以一条指令或者符号名开始。
$parameter 在宏使用时，被替代的参数，格式为：$parameter=“default value”
在 宏体中，参数如：$parameter和变量一样使用，在被宏引用时，被赋于新值，参数必须用“$”符号加于区别。$label在宏定义内部符号时很有 用，可以看作宏的参数。使用“|”符号作为使用一个参数缺省值的变量，如果使用的是一个空格符串，将省去该变量。在使用内部标志的宏定义中，将内部标志定 义为带后缀的标志，将会很有用。如果在扩展中空间不够，可以作为参数和后继文字之间或者参数之间使用圆点隔开，但在文本和后继参数之间不能使用圆点。宏可 以定义局部变量的范围。宏还可以嵌套使用。
例：
MACRO
$label xmac $p1,$p2
LCLS err
$labell,loopl
BGE $pl
$labell,loop2
BL $p1
BEG $p1
BEG $labell,loop2
MEND
五、$和$$
GBLS STR1
GBLS STR2
STR1 SETS "AAA"
STR2 SETS "BBB$$STR1.CCC" //汇编后STR2的值为bbAAACCC
六、 IMPORT Main ; The main entry of mon program
格式：
IMPORT symbol {[WEAK]}
symbol 引用的符号的名称，他是区分大小写的，[WEAK]指定这个选项后，如果symbol所在的源文件中没有被定义，编译器也不会报错。他和EXTERN作用 相同，不同之处在于，如果本源文件没有实际引用该符号，该符号将不会被加入到本源文件的符号表中。
*****************************************************
七、AREA Init,CODE,READONLY
ENTRY
格式：
Attr 段名属性，下列属性是有效的：
ALIGN=expression
缺省状态下，AOF段将按4个字节对准，expression可以是2~31之间的整数，该段将按2（上标为expression）字节对准。例如，espression等于
COMDEF 通用段定义。该AOF段可能包括代码和数据，但必须与其他段名相区别。
COMMON 通用数据段，无须再注释定义任何代码和数据，通常由链接器初始化为零。
DATA 包含数据，但是不包含指令，缺省为READWRITE
INTERWORK 表明代码段可以适用ARM/Thumb interworking功能。
NOINIT 表明数据段可以初始化为零，只包含指示符。
PIC 表明定位独立段，可以不修改情况下，在任意地址执行。
READONLY 表明该段可读可写。
八、LTORG
ldr r0, =instruction 将地址instruction载入r0
此时编译器将ldr尽可能的转变成mov或mvn指令。 如果转变不成, 将产生一个ldr指令，通过pc相对地址从一块保存常数的内存区读出instruction的值。此内存区既是文本池。一般的, 文本池放在END指令之后的地方。但是, 如果偏移地址大于4k空间, ldr指令会出错(因为ldr的相对偏移地址为12-bit的值). 此时使用LTORG放到会出错的ldr指令附近，以解决此问题。 编译器会收集没有分配的ldr的值放到此文本池中
九、LDR r0,=WTCON ;watch dog disable
LDR r1,=0x0
格式：
LDR{condition} register,=[expression|Label-expression]
其中：
condition 可选的条件代码。
register 读取的寄存器。
expression 数字常量：
如果该数字常量在MOV或MVN指令的范围中，汇编器会产生合适的指令；
如果该数字量不在MOV或MVN指令的范围中，汇编器把该常量于程序后，用程序相关的LDR伪指令读取，PC与该常量的偏移量不得超过4KB。
Label-expression 程序相关的或外部的表达式。汇编器将其存放在程序后的常量库（称为文字池（literal pool））中，用程序相关的LDR伪指令读取，PC与与该常量的偏移量不得超过4KB。
对于不能被MOV和MVN指令所读取的立即数,将其变成常量,进行读取。
将一个程序相关的或外部的表达式读取进寄存器中。
例:
LDR R1, =0xfff
LDR R2, =place
十、DCD 0x11110090
功能： 分配一个或多个字，从4个字节边界开始。
格式：
{label}DCD expression{,expression}…
其中：
expression 可以是：
一个数学表达式；
一个程序相关的表达式。
按4个字节对准时，DCD符号会在第一个字节之前插入3个字节的空字符，如果无须对准的话，可以使用DCDU符号。
例：
datal DCD 1,5,20
data2 DCD mem06
data3 DCD glb+4
十一、ALIGN
格式：
ALIGN {expression {,offset-expression} }
其中：
expression 2(上标为0)到2（上标为31）之间的任意数幂，当前按2（上标为n）字节对准，如果该参数没有指定，ALIGN将按字对准。
Offset-expression 定义expression指定的对准方式的字节偏移量。
在代码段出现数据定义符时，使用ALIGE符号。当在代码段使用数据定义符（DCB，DCW，DCWU，DCDU和%），程序计数器PC并不一定按字对准。
ARM状态下按字对准；
Thumb状态下按半字对准。
在Thumb状态下，可以使用ALIGN2对Thumb代码按半字对准。
使用ALIGN状态下，还可以充分利用一些ARM处理器的Cache，例如，ARM940T有一个每行4字的Cache，使用ALIGN16按16字节对准，从而最大限度使用Cache。
十二、^ _ISR_STARTADDRESS
MAP用于定义一个结构化的内存表（StorageMAP）的首地址。此时，内存表的位置计数器{VAR}（汇编器的内置变量）设置成该地址值。MAP可以用”^”代替。
语法：MAP expr {,base-register}
其中，expr为数字表达式或者是程序中已经定义过的标号。Base-register为一个寄存器。当指令中没有Base-register 时，expr为结构化内存表的首地址。此时，内存表的位置计数器{VAR}设置成该地址值。当指令中包含这一项时，结构化内存表的首地址为expr和 Base-register寄存器内容的和。
使用说明：MAP伪操作和FIELD伪操作配合使用来定义结构化的内存表结构。
MAP fun ;fun就是内存表的首地址
MAP 0x100,R9 ;内存表的首地址为 R9+0x100
十三、HandleReset # 4
HandleUndef # 4
HandleSWI # 4
FIELD 用于定义一个结构化的内存表中的数据域。FIELD 可用“#”代替。
语法：{label} FIELD expr
其中：{label}为可选的。当指令中包含这一项时，label的值为当前内存表的位置计数器{VAR}的值。汇编编译器处理了这条FIELD伪操作后。
Consta FIELD 4 ; //consta 长为4字节，相对位置为0
Constb FIELD 4; //constb长为4字节，相对位置为4
X FIELD 8; // X长为8字节，相对位置为8
Y FIELD 8; // y长为8字节，相对位置为16
String FIELD 16 ;// String为16字节，相对位置为24
Consta FIELD 4 ; //consta 长为4字节，相对位置为0
Constb FIELD 4; //constb长为4字节，相对位置为4
X FIELD 8; // X长为8字节，相对位置为8
Y FIELD 8; // y长为8字节，相对位置为16
String FIELD 16;// String为16字节，相对位置为24
LDR R5，Constb；//相当于LDR R5，[R9，#4]
MAP Data；//内存表的首地址为Datastruc内存单元
Consta FIELD 4 ; //consta 长为4字节，相对位置为0
Constb FIELD 4; //constb长为4字节，相对位置为4
X FIELD 8; // X长为8字节，相对位置为8
Y FIELD 8; // y长为8字节，相对位置为16
String FIELD 16;// String为16字节，相对位置为24
十四、RN
在局部标号中：
%表示引用操作
F指示编译器只向前搜索。
B指示编译器只向后搜索。
A指示编译器搜索宏的所有嵌套层。
T指示编译器搜索宏的当前层次。
若F、B没有指定则先向前搜索，再向后搜索。
若A、T都没有指定则先从当前层到最高层，比当前层低的不再搜索。
------------------------------------------------------------------------------------------------------------------------------------
------------------------------------------------------------------------------------------------------------------------------------
ADS 中的配置：
以一般的 S3C44B0X 的板子为例：
1、 RO： 0x0, RW: 0xC000000 (Debug 模式下是：RO： 0xC000000, RW: ---)
2、 ARM LINKER:
Layout 中指明整个 IMAGE 的入口，这一般和你的程序有关。
Place at beginning of image
1) Object/Symbol: 放程序的初始化的汇编文件，比如 44binit.o 或 boot.o. 你的工程不是有一个 .S
文件吗，比如 44binit.s 或 boot.s 或你自己到的一个文件名，你只要把后缀名改成 .o , 填进去就可以了
2) 还是刚才那个 .s 文件, 你找一下，是不是有以下的代码 IMPORT Main ; The main entry of mon
program AREA Init,CODE,READONLY ;这就是入口的 AREA, 这里的名字叫
Init,也可以是你自己取的名字,把这个名字填到 Section中。
3) ENTRY b ResetHandler
;for debug ;这是debug时ADS停下来的第一条语句。还有，就是确认一个你的程序是否正确固化到Flash中，你可以把工程编译成
.bin 格式的映像。然后通过编程器或 ads 读取 Flash 的内容，与 .bin 文件比较.