SQL Server 查詢是否死鎖與解決辦法

Sys.SysProcesses 系統表是一個很重要的系統視圖，主要用來定位與解決Sql Server的阻塞和死鎖

視圖中主要的字段：
1. Spid：Sql Servr 會話ID
2. Kpid：Windows 線程ID
3. Blocked：正在阻塞求情的會話 ID。如果此列爲 Null，則標識請求未被阻塞
4. Waittype：當前連接的等待資源編號，標示是否等待資源，0 或 Null表示不需要等待任何資源
5. Waittime：當前等待時間，單位爲毫秒，0 表示沒有等待
6. DBID：當前正由進程使用的數據庫ID
7. UID：執行命令的用戶ID
8. Login_time：客戶端進程登錄到服務器的時間。
9. Last_batch：上次執行存儲過程或Execute語句的時間。對於系統進程，將存儲Sql Server 的啓動時間
10.Open_tran：進程的打開事務個數。如果有嵌套事務，就會大於1
11.Status：進程ID 狀態，dormant = 正在重置回話 ; running = 回話正在運行一個或多個批處理 ; background = 回話正在運行一個後臺任務 ; rollback = 會話正在處理事務回滾 ; pending = 回話正在等待工作現成變爲可用 ; runnable = 會話中的任務在等待獲取 Scheduler 來運行的可執行隊列中 ; spinloop = 會話中的任務正在等待自旋鎖變爲可用 ; suspended = 會話正在等待事件完成
12.Hostname：建立鏈接的客戶端工作站的名稱
13.Program_name：應用程序的名稱，就是連接字符串中配的 Application Name
14.Hostprocess：建立連接的應用程序在客戶端工作站裏的進程ID號
15.Cmd：當前正在執行的命令
16.Loginame：登錄名

應用實例：

1. 檢查數據庫是否發生阻塞

先查找哪個鏈接的 blocked 字段不爲0。如 SPID53的blocked 字段不爲0，而是 52。SPID 52 的 blocked 爲0，就可以得出結論：此時有阻塞發生，53 被 52 阻塞住了。如果你發現一個連接的 blocked 字段的值等於它自己，那說明這個連接正在做磁盤讀寫，它要等自己的 I/O 做完。

2. 查找鏈接在那個數據庫上

檢查 dbid 即可。得到 dbid，可以運行以下查詢得到數據庫的名字：
Select name,dbid from master.sys.sysdatabases

3. 查看此進程執行的SQL 是哪個，查找問題原因
dbcc inputbuffer(spid);

4. KILL 掉當前導致阻塞的SQL
kill　spid

5. sql阻塞進程查詢

select A.SPID as 被阻塞進程,a.CMD AS 正在執行的操作,b.spid AS 阻塞進程號,b.cmd AS 阻塞進程正在執行的操作
from master..sysprocesses a,master..sysprocesses b
where a.blocked<>0 and a.blocked= b.spid

exec sp_who 'active'--查看系統內所有的活動進程 BLK不爲0的爲死鎖

exec sp_lock 60 --返回某個進程對資源的鎖定情況

SELECT object_name(1504685104)--返回對象ID對應的對象名

DBCC INPUTBUFFER (63)--顯示從客戶端發送到服務器的最後一個語句

6. SQL Server簡潔查詢正在運行的進程SQL

SELECT   spid,
         blocked,
         DB_NAME(sp.dbid) AS DBName,
         program_name,
         waitresource,
         lastwaittype,
         sp.loginame,
         sp.hostname,
         a.[Text] AS [TextData],
         SUBSTRING(A.text, sp.stmt_start / 2,
         (CASE WHEN sp.stmt_end = -1 THEN DATALENGTH(A.text) ELSE sp.stmt_end
         END - sp.stmt_start) / 2) AS [current_cmd]
FROM     sys.sysprocesses AS sp OUTER APPLY sys.dm_exec_sql_text (sp.sql_handle) AS A
WHERE    spid > 50
ORDER BY blocked DESC, DB_NAME(sp.dbid) ASC, a.[text];

SqlServer查詢和Kill進程死鎖的語句

查詢死鎖進程語句

select
request_session_id spid, 
OBJECT_NAME(resource_associated_entity_id) tableName 
from
sys.dm_tran_locks 
where
resource_type='OBJECT'

sqlserver檢測死鎖;殺死鎖和進程;查看鎖信息

--檢測死鎖
--如果發生死鎖了，我們怎麼去檢測具體發生死鎖的是哪條SQL語句或存儲過程？
--這時我們可以使用以下存儲過程來檢測，就可以查出引起死鎖的進程和SQL語句。SQL Server自帶的系統存儲過程sp_who和sp_lock也可以用來查找阻塞和死鎖, 但沒有這裏介紹的方法好用。
use master
go
create procedure sp_who_lock
as
begin
declare @spid int,@bl int,
 @intTransactionCountOnEntry int,
  @intRowcount int,
  @intCountProperties int,
  @intCounter int
 create table #tmp_lock_who (
 id int identity(1,1),
 spid smallint,
 bl smallint)
 IF @@ERROR<>0 RETURN @@ERROR
 insert into #tmp_lock_who(spid,bl) select 0 ,blocked
 from (select * from sysprocesses where blocked>0 ) a 
 where not exists(select * from (select * from sysprocesses where blocked>0 ) b 
 where a.blocked=spid)
 union select spid,blocked from sysprocesses where blocked>0
 IF @@ERROR<>0 RETURN @@ERROR 
-- 找到臨時表的記錄數
 select @intCountProperties = Count(*),@intCounter = 1
 from #tmp_lock_who
 IF @@ERROR<>0 RETURN @@ERROR 
 if @intCountProperties=0
 select '現在沒有阻塞和死鎖信息' as message
-- 循環開始
while @intCounter <= @intCountProperties
begin
-- 取第一條記錄
 select @spid = spid,@bl = bl
 from #tmp_lock_who where Id = @intCounter 
 begin
 if @spid =0 
   select '引起數據庫死鎖的是: '+ CAST(@bl AS VARCHAR(10)) + '進程號,其執行的SQL語法如下'
 else
   select '進程號SPID：'+ CAST(@spid AS VARCHAR(10))+ '被' + '進程號SPID：'+ CAST(@bl AS VARCHAR(10)) +'阻塞,其當前進程執行的SQL語法如下'
 DBCC INPUTBUFFER (@bl )
 end
-- 循環指針下移
 set @intCounter = @intCounter + 1
end
drop table #tmp_lock_who
return 0
end
--殺死鎖和進程
--如何去手動的殺死進程和鎖？最簡單的辦法，重新啓動服務。但是這裏要介紹一個存儲過程，通過顯式的調用，可以殺死進程和鎖。
use master
go
if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_killspid]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_killspid]
GO
create proc p_killspid
@dbname varchar(200) --要關閉進程的數據庫名
as
 declare @sql nvarchar(500) 
 declare @spid nvarchar(20)
 declare #tb cursor for
  select spid=cast(spid as varchar(20)) from master..sysprocesses where dbid=db_id(@dbname)
 open #tb
 fetch next from #tb into @spid
 while @@fetch_status=0
 begin
  exec('kill '+@spid)
  fetch next from #tb into @spid
 end
 close #tb
 deallocate #tb
go
--用法 
exec p_killspid 'newdbpy'
--查看鎖信息
--如何查看系統中所有鎖的詳細信息？在企業管理管理器中，我們可以看到一些進程和鎖的信息，這裏介紹另外一種方法。
--查看鎖信息
create table #t(req_spid int,obj_name sysname)
declare @s nvarchar(4000)
 ,@rid int,@dbname sysname,@id int,@objname sysname
declare tb cursor for
 select distinct req_spid,dbname=db_name(rsc_dbid),rsc_objid
 from master..syslockinfo where rsc_type in(4,5)
open tb
fetch next from tb into @rid,@dbname,@id
while @@fetch_status=0
begin
 set @s='select @objname=name from ['+@dbname+']..sysobjects where id=@id'
 exec sp_executesql @s,N'@objname sysname out,@id int',@objname out,@id
 insert into #t values(@rid,@objname)
 fetch next from tb into @rid,@dbname,@id
end
close tb
deallocate tb
select 進程id=a.req_spid
 ,數據庫=db_name(rsc_dbid)
 ,類型=case rsc_type when 1 then 'NULL 資源（未使用）'
  when 2 then '數據庫'
  when 3 then '文件'
  when 4 then '索引'
  when 5 then '表'
  when 6 then '頁'
  when 7 then '鍵'
  when 8 then '擴展盤區'
  when 9 then 'RID（行 ID)'
  when 10 then '應用程序'
 end
 ,對象id=rsc_objid
 ,對象名=b.obj_name
 ,rsc_indid
 from master..syslockinfo a left join #t b on a.req_spid=b.req_spid
go
drop table #t

SQL Server 查詢是否死鎖與解決辦法

SQL Server 查詢是否死鎖與解決辦法

認知提升的方法

螞蟻面試：Springcloud核心組件的底層原理，你知道多少？

C#開源的兩款功能強大的錄屏神器

如何給gif改變顏色

SQL Server 查詢是否死鎖與解決辦法

Winform窗體SendKeys類

C# WinForm 無鋸齒透明異形窗體

ECharts 提示框（tooltip）

https://yachay.unat.edu.pe/blog/index.php?comment_area=format_blog&comment_component=blog&comment_co

linux以太網驅動總結