ARM編譯器一般都支持彙編語言的程序設計和C/C++語言的程序設計，以及兩者的混合編程。本章介紹ARM程序設計的一些基本概念，如ARM彙編語言的僞指令、彙編語言的語句格式和彙編語言的程序結構等，同時介紹C/C＋＋和彙編語言的混合編程等問題。
本章的主要內容：
－ ARM編譯器所支持的僞指令
－ 彙編語言的語句格式
－ 彙編語言的程序結構
－ 相關的程序示例
4.1 ARM彙編器所支持的僞指令
在ARM彙編語言程序裏，有一些特殊指令助記符，這些助記符與指令系統的助記符不同，沒有相對應的操作碼，通常稱這些特殊指令助記符爲僞指令，他們所完成的操作稱爲僞操作。僞指令在源程序中的作用是爲完成彙編程序作各種準備工作的，這些僞指令僅在彙編過程中起作用，一旦彙編結束，僞指令的使命就完成。
在ARM的彙編程序中，有如下幾種僞指令：符號定義僞指令、數據定義僞指令、彙編控制僞指令、宏指令以及其他僞指令。
4.1.1符號定義（Symbol Definition）僞指令
符號定義僞指令用於定義ARM彙編程序中的變量、對變量賦值以及定義寄存器的別名等操作。常見的符號定義僞指令有如下幾種：
— 用於定義全局變量的GBLA、GBLL和GBLS。
— 用於定義局部變量的LCLA、LCLL和LCLS。
— 用於對變量賦值的SETA、SETL、SETS。
— 爲通用寄存器列表定義名稱的RLIST。
1、 GBLA、GBLL和GBLS
語法格式：
GBLA（GBLL或GBLS） 全局變量名
GBLA、GBLL和GBLS僞指令用於定義一個ARM程序中的全局變量，並將其初始化。其中：
GBLA僞指令用於定義一個全局的數字變量，並初始化爲0；
GBLL僞指令用於定義一個全局的邏輯變量，並初始化爲F（假）；
GBLS僞指令用於定義一個全局的字符串變量，並初始化爲空；
由於以上三條僞指令用於定義全局變量，因此在整個程序範圍內變量名必須唯一。
使用示例：
GBLA Test1 ；定義一個全局的數字變量，變量名爲Test1
Test1 SETA 0xaa ；將該變量賦值爲0xaa
GBLL Test2 ；定義一個全局的邏輯變量，變量名爲Test2
Test2 SETL {TRUE} ；將該變量賦值爲真
GBLS Test3 ；定義一個全局的字符串變量，變量名爲Test3
Test3 SETS “Testing” ；將該變量賦值爲“Testing”
2、 LCLA、LCLL和LCLS
語法格式：
LCLA（LCLL或LCLS） 局部變量名
LCLA、LCLL和LCLS僞指令用於定義一個ARM程序中的局部變量，並將其初始化。其中：
LCLA僞指令用於定義一個局部的數字變量，並初始化爲0；
LCLL僞指令用於定義一個局部的邏輯變量，並初始化爲F（假）；
LCLS僞指令用於定義一個局部的字符串變量，並初始化爲空；
以上三條僞指令用於聲明局部變量，在其作用範圍內變量名必須唯一。
使用示例：
LCLA Test4 ；聲明一個局部的數字變量，變量名爲Test4
Test3 SETA 0xaa ；將該變量賦值爲0xaa
LCLL Test5 ；聲明一個局部的邏輯變量，變量名爲Test5
Test4 SETL {TRUE} ；將該變量賦值爲真
LCLS Test6 ；定義一個局部的字符串變量，變量名爲Test6
Test6 SETS “Testing” ；將該變量賦值爲“Testing”
3、 SETA、SETL和SETS
語法格式：
變量名 SETA（SETL或SETS） 表達式
僞指令SETA、SETL、SETS用於給一個已經定義的全局變量或局部變量賦值。
SETA僞指令用於給一個數學變量賦值；
SETL僞指令用於給一個邏輯變量賦值；
SETS僞指令用於給一個字符串變量賦值；
其中，變量名爲已經定義過的全局變量或局部變量，表達式爲將要賦給變量的值。
使用示例：
LCLA Test3 ；聲明一個局部的數字變量，變量名爲Test3
Test3 SETA 0xaa ；將該變量賦值爲0xaa
LCLL Test4 ；聲明一個局部的邏輯變量，變量名爲Test4
Test4 SETL {TRUE} ；將該變量賦值爲真
4、 RLIST
語法格式：
名稱 RLIST {寄存器列表}
RLIST僞指令可用於對一個通用寄存器列表定義名稱，使用該僞指令定義的名稱可在ARM指令LDM/STM中使用。在LDM/STM指令中，列表中的寄存器訪問次序爲根據寄存器的編號由低到高，而與列表中的寄存器排列次序無關。
使用示例：
RegList RLIST {R0-R5，R8，R10} ；將寄存器列表名稱定義爲RegList，可在ARM指令LDM/STM中通過該名稱訪問寄存器列表。
4.1.2數據定義（Data Definition）僞指令
數據定義僞指令一般用於爲特定的數據分配存儲單元，同時可完成已分配存儲單元的初始化。常見的數據定義僞指令有如下幾種：
— DCB 用於分配一片連續的字節存儲單元並用指定的數據初始化。
— DCW（DCWU） 用於分配一片連續的半字存儲單元並用指定的數據初始化。
— DCD（DCDU） 用於分配一片連續的字存儲單元並用指定的數據初始化。
— DCFD（DCFDU）用於爲雙精度的浮點數分配一片連續的字存儲單元並用指定的數據初始化。
— DCFS（DCFSU） 用於爲單精度的浮點數分配一片連續的字存儲單元並用指定的數據初始化。
— DCQ（DCQU） 用於分配一片以8字節爲單位的連 續的存儲單元並用指定的數據初始化。
— SPACE 用於分配一片連續的存儲單元
— MAP 用於定義一個結構化的內存表首地址
— FIELD 用於定義一個結構化的內存表的數據域
1、 DCB
語法格式：
標號 DCB 表達式
DCB僞指令用於分配一片連續的字節存儲單元並用僞指令中指定的表達式初始化。其中，表達式可以爲0～255的數字或字符串。DCB也可用“=”代替。
使用示例：
Str DCB “This is a test！” ；分配一片連續的字節存儲單元並初始化。
2、 DCW（或DCWU）
語法格式：
標號 DCW（或DCWU） 表達式
DCW（或DCWU）僞指令用於分配一片連續的半字存儲單元並用僞指令中指定的表達式初始化。其中，表達式可以爲程序標號或數字表達式。。
用DCW分配的字存儲單元是半字對齊的，而用DCWU分配的字存儲單元並不嚴格半字對齊。
使用示例：
DataTest DCW 1，2，3 ；分配一片連續的半字存儲單元並初始化。
3、 DCD（或DCDU）
語法格式：
標號 DCD（或DCDU） 表達式
DCD（或DCDU）僞指令用於分配一片連續的字存儲單元並用僞指令中指定的表達式初始化。其中，表達式可以爲程序標號或數字表達式。DCD也可用“&”代替。
用DCD分配的字存儲單元是字對齊的，而用DCDU分配的字存儲單元並不嚴格字對齊。
使用示例：
DataTest DCD 4，5，6 ；分配一片連續的字存儲單元並初始化。
4、 DCFD（或DCFDU）
語法格式：
標號 DCFD（或DCFDU） 表達式
DCFD（或DCFDU）僞指令用於爲雙精度的浮點數分配一片連續的字存儲單元並用僞指令中指定的表達式初始化。每個雙精度的浮點數佔據兩個字單元。
用DCFD分配的字存儲單元是字對齊的，而用DCFDU分配的字存儲單元並不嚴格字對齊。
使用示例：
FDataTest DCFD 2E115，-5E7 ；分配一片連續的字存儲單元並初始化爲指定的雙精度數。
5、 DCFS（或DCFSU）
語法格式：
標號 DCFS（或DCFSU） 表達式
DCFS（或DCFSU）僞指令用於爲單精度的浮點數分配一片連續的字存儲單元並用僞指令中指定的表達式初始化。每個單精度的浮點數佔據一個字單元。
用DCFS分配的字存儲單元是字對齊的，而用DCFSU分配的字存儲單元並不嚴格字對齊。
使用示例：
FDataTest DCFS 2E5，-5E－7 ；分配一片連續的字存儲單元並初始化爲指定的單精度數。
6、 DCQ(或DCQU）
語法格式：
標號 DCQ（或DCQU） 表達式
DCQ（或DCQU）僞指令用於分配一片以8個字節爲單位的連續存儲區域並用僞指令中指定的表達式初始化。
用DCQ分配的存儲單元是字對齊的，而用DCQU分配的存儲單元並不嚴格字對齊。
使用示例：
DataTest DCQ 100 ；分配一片連續的存儲單元並初始化爲指定的值。
7、 SPACE
語法格式：
標號 SPACE 表達式
SPACE僞指令用於分配一片連續的存儲區域並初始化爲0。其中，表達式爲要分配的字節數。SPACE也可用“％”代替。
使用示例：
DataSpace SPACE 100 ；分配連續100字節的存儲單元並初始化爲0。
8、 MAP
語法格式：
MAP 表達式{，基址寄存器}
MAP僞指令用於定義一個結構化的內存表的首地址。MAP也可用“＾”代替。
表達式可以爲程序中的標號或數學表達式，基址寄存器爲可選項，當基址寄存器選項不存在時，表達式的值即爲內存表的首地址，當該選項存在時，內存表的首地址爲表達式的值與基址寄存器的和。
MAP僞指令通常與FIELD僞指令配合使用來定義結構化的內存表。
使用示例：
MAP 0x100，R0 ；定義結構化內存表首地址的值爲0x100＋R0。
9、 FILED
語法格式：
標號 FIELD 表達式
FIELD僞指令用於定義一個結構化內存表中的數據域。FILED也可用“#”代替。
表達式的值爲當前數據域在內存表中所佔的字節數。
FIELD僞指令常與MAP僞指令配合使用來定義結構化的內存表。MAP僞指令定義內存表的首地址，FIELD僞指令定義內存表中的各個數據域，並可以爲每個數據域指定一個標號供其他的指令引用。
注意MAP和FIELD僞指令僅用於定義數據結構，並不實際分配存儲單元。
使用示例：
MAP 0x100 ；定義結構化內存表首地址的值爲0x100。
A FIELD 16 ；定義A的長度爲16字節，位置爲0x100
B FIELD 32 ；定義B的長度爲32字節，位置爲0x110
S FIELD 256 ；定義S的長度爲256字節，位置爲0x130
4.1.3彙編控制（Assembly Control）僞指令
彙編控制僞指令用於控制彙編程序的執行流程，常用的彙編控制僞指令包括以下幾條：
— IF、ELSE、ENDIF
— WHILE、WEND
— MACRO、MEND
— MEXIT
1、 IF、ELSE、ENDIF
語法格式：
IF 邏輯表達式
指令序列1
ELSE
指令序列2
ENDIF
IF、ELSE、ENDIF僞指令能根據條件的成立與否決定是否執行某個指令序列。當IF後面的邏輯表達式爲真，則執行指令序列1，否則執行指令序列2。其中，ELSE及指令序列2可以沒有，此時，當IF後面的邏輯表達式爲真，則執行指令序列1，否則繼續執行後面的指令。
IF、ELSE、ENDIF僞指令可以嵌套使用。
使用示例：
GBLL Test ；聲明一個全局的邏輯變量，變量名爲Test
……
IF Test = TRUE
指令序列1
ELSE
指令序列2
ENDIF
2、 WHILE、WEND
語法格式：
WHILE 邏輯表達式
指令序列
WEND
WHILE、WEND僞指令能根據條件的成立與否決定是否循環執行某個指令序列。當WHILE後面的邏輯表達式爲真，則執行指令序列，該指令序列執行完畢後，再判斷邏輯表達式的值，若爲真則繼續執行，一直到邏輯表達式的值爲假。
WHILE、WEND僞指令可以嵌套使用。
使用示例：
GBLA Counter ；聲明一個全局的數學變量，變量名爲Counter
Counter SETA 3 ；由變量Counter控制循環次數
……
WHILE Counter < 10
指令序列
WEND
3、 MACRO、MEND
語法格式：
$標號 宏名 $參數1，$參數2，……
指令序列
MEND
MACRO、MEND僞指令可以將一段代碼定義爲一個整體，稱爲宏指令，然後就可以在程序中通過宏指令多次調用該段代碼。其中，$標號在宏指令被展開時，標號會被替換爲用戶定義的符號，
宏指令可以使用一個或多個參數，當宏指令被展開時，這些參數被相應的值替換。
宏指令的使用方式和功能與子程序有些相似，子程序可以提供模塊化的程序設計、節省存儲空間並提高運行速度。但在使用子程序結構時需要保護現場，從而增加了系統的開銷，因此，在代碼較短且需要傳遞的參數較多時，可以使用宏指令代替子程序。
包含在MACRO和MEND之間的指令序列稱爲宏定義體，在宏定義體的第一行應聲明宏的原型（包含宏名、所需的參數），然後就可以在彙編程序中通過宏名來調用該指令序列。在源程序被編譯時，彙編器將宏調用展開，用宏定義中的指令序列代替程序中的宏調用，並將實際參數的值傳遞給宏定義中的形式參數。
MACRO、MEND僞指令可以嵌套使用。
4、 MEXIT
語法格式：
MEXIT
MEXIT用於從宏定義中跳轉出去。
4.1.4其他常用的僞指令
還有一些其他的僞指令，在彙編程序中經常會被使用，包括以下幾條：
— AREA
— ALIGN
— CODE16、CODE32
— ENTRY
— END
— EQU
— EXPORT（或GLOBAL）
— IMPORT
— EXTERN
— GET（或INCLUDE）
— INCBIN
— RN
— ROUT
1、 AREA
語法格式：
AREA 段名 屬性1，屬性2，……
AREA僞指令用於定義一個代碼段或數據段。其中，段名若以數字開頭，則該段名需用“|”括起來，如|1_test|。
屬性字段表示該代碼段（或數據段）的相關屬性，多個屬性用逗號分隔。常用的屬性如下：
— CODE屬性：用於定義代碼段，默認爲READONLY。
— DATA屬性：用於定義數據段，默認爲READWRITE。
— READONLY屬性：指定本段爲只讀，代碼段默認爲READONLY。
— READWRITE屬性：指定本段爲可讀可寫，數據段的默認屬性爲READWRITE。
— ALIGN屬性：使用方式爲ALIGN 表達式。在默認時，ELF（可執行連接文件）的代碼段和數據段是按字對齊的，表達式的取值範圍爲0～31，相應的對齊方式爲2表達式次方。
— COMMON屬性：該屬性定義一個通用的段，不包含任何的用戶代碼和數據。各源文件中同名的COMMON段共享同一段存儲單元。
一個彙編語言程序至少要包含一個段，當程序太長時，也可以將程序分爲多個代碼段和數據段。
使用示例：
AREA Init，CODE，READONLY
指令序列
；該僞指令定義了一個代碼段，段名爲Init，屬性爲只讀
2、 ALIGN
語法格式：
ALIGN {表達式{，偏移量}}
ALIGN僞指令可通過添加填充字節的方式，使當前位置滿足一定的對其方式|。其中，表達式的值用於指定對齊方式，可能的取值爲2的冪，如1、2、4、8、16等。若未指定表達式，則將當前位置對齊到下一個字的位置。偏移量也爲一個數字表達式，若使用該字段，則當前位置的對齊方式爲：2的表達式次冪＋偏移量。
使用示例：
AREA Init，CODE，READONLY，ALIEN＝3 ；指定後面的指令爲8字節對齊。
指令序列
END
3、 CODE16、CODE32
語法格式：
CODE16（或CODE32）
CODE16僞指令通知編譯器，其後的指令序列爲16位的Thumb指令。
CODE32僞指令通知編譯器，其後的指令序列爲32位的ARM指令。
若在彙編源程序中同時包含ARM指令和Thumb指令時，可用CODE16僞指令通知編譯器其後的指令序列爲16位的Thumb指令，CODE32僞指令通知編譯器其後的指令序列爲32位的ARM指令。因此，在使用ARM指令和Thumb指令混合編程的代碼裏，可用這兩條僞指令進行切換，但注意他們只通知編譯器其後指令的類型，並不能對處理器進行狀態的切換。
使用示例：
AREA Init，CODE，READONLY
……
CODE32 ；通知編譯器其後的指令爲32位的ARM指令
LDR R0，＝NEXT＋1 ；將跳轉地址放入寄存器R0
BX R0 ；程序跳轉到新的位置執行，並將處理器切換到Thumb工作狀態
……
CODE16 ；通知編譯器其後的指令爲16位的Thumb指令
NEXT LDR R3，＝0x3FF
……
END ；程序結束
4、 ENTRY
語法格式：
ENTRY
ENTRY僞指令用於指定彙編程序的入口點。在一個完整的彙編程序中至少要有一個ENTRY（也可以有多個，當有多個ENTRY時，程序的真正入口點由鏈接器指定），但在一個源文件裏最多只能有一個ENTRY（可以沒有）。
使用示例：
AREA Init，CODE，READONLY
ENTRY ；指定應用程序的入口點
……
5、 END
語法格式：
END
END僞指令用於通知編譯器已經到了源程序的結尾。
使用示例：
AREA Init，CODE，READONLY
……
END ；指定應用程序的結尾
6、 EQU
語法格式：
名稱 EQU 表達式{，類型}
EQU僞指令用於爲程序中的常量、標號等定義一個等效的字符名稱，類似於C語言中的＃define。其中EQU可用“*”代替。
名稱爲EQU僞指令定義的字符名稱，當表達式爲32位的常量時，可以指定表達式的數據類型，可以有以下三種類型：
CODE16、CODE32和DATA
使用示例：
Test EQU 50 ；定義標號Test的值爲50
Addr EQU 0x55，CODE32 ；定義Addr的值爲0x55，且該處爲32位的ARM指令。
7、 EXPORT（或GLOBAL）
語法格式：
EXPORT 標號{[WEAK]}
EXPORT僞指令用於在程序中聲明一個全局的標號，該標號可在其他的文件中引用。EXPORT可用GLOBAL代替。標號在程序中區分大小寫，[WEAK]選項聲明其他的同名標號優先於該標號被引用。
使用示例：
AREA Init，CODE，READONLY
EXPORT Stest ；聲明一個可全局引用的標號Stest
……
END
8、 IMPORT
語法格式：
IMPORT 標號{[WEAK]}
IMPORT僞指令用於通知編譯器要使用的標號在其他的源文件中定義，但要在當前源文件中引用，而且無論當前源文件是否引用該標號，該標號均會被加入到當前源文件的符號表中。
標號在程序中區分大小寫，[WEAK]選項表示當所有的源文件都沒有定義這樣一個標號時，編譯器也不給出錯誤信息，在多數情況下將該標號置爲0，若該標號爲B或BL指令引用，則將B或BL指令置爲NOP操作。
使用示例：
AREA Init，CODE，READONLY
IMPORT Main ；通知編譯器當前文件要引用標號Main，但Main在其他源文件中定義
……
END
9、 EXTERN
語法格式：
EXTERN 標號{[WEAK]}
EXTERN僞指令用於通知編譯器要使用的標號在其他的源文件中定義，但要在當前源文件中引用，如果當前源文件實際並未引用該標號，該標號就不會被加入到當前源文件的符號表中。
標號在程序中區分大小寫，[WEAK]選項表示當所有的源文件都沒有定義這樣一個標號時，編譯器也不給出錯誤信息，在多數情況下將該標號置爲0，若該標號爲B或BL指令引用，則將B或BL指令置爲NOP操作。
使用示例：
AREA Init，CODE，READONLY
EXTERN Main ；通知編譯器當前文件要引用標號Main，但Main在其他源文件中定義
……
END
10、 GET（或INCLUDE）
語法格式：
GET 文件名
GET僞指令用於將一個源文件包含到當前的源文件中，並將被包含的源文件在當前位置進行彙編處理。可以使用INCLUDE代替GET。
彙編程序中常用的方法是在某源文件中定義一些宏指令，用EQU定義常量的符號名稱，用MAP和FIELD定義結構化的數據類型，然後用GET僞指令將這個源文件包含到其他的源文件中。使用方法與C語言中的“include”相似。
GET僞指令只能用於包含源文件，包含目標文件需要使用INCBIN僞指令
使用示例：
AREA Init，CODE，READONLY
GET a1.s ；通知編譯器當前源文件包含源文件a1.s
GE T C：/a2.s ；通知編譯器當前源文件包含源文件C：/ a2.s
……
END
11、 INCBIN
語法格式：
INCBIN 文件名
INCBIN僞指令用於將一個目標文件或數據文件包含到當前的源文件中，被包含的文件不作任何變動的存放在當前文件中，編譯器從其後開始繼續處理。
使用示例：
AREA Init，CODE，READONLY
INCBIN a1.dat ；通知編譯器當前源文件包含文件a1.dat
INCBIN C：/a2.txt ；通知編譯器當前源文件包含文件C：/a2.txt
……
END
12、 RN
語法格式：
名稱 RN 表達式
RN僞指令用於給一個寄存器定義一個別名。採用這種方式可以方便程序員記憶該寄存器的功能。其中，名稱爲給寄存器定義的別名，表達式爲寄存器的編碼。
使用示例：
Temp RN R0 ；將R0定義一個別名Temp
13、 ROUT
語法格式：
{名稱} ROUT
ROUT僞指令用於給一個局部變量定義作用範圍。在程序中未使用該僞指令時，局部變量的作用範圍爲所在的AREA，而使用ROUT後，局部變量的作爲範圍爲當前ROUT和下一個ROUT之間。
4.2 彙編語言的語句格式
ARM（Thumb）彙編語言的語句格式爲：
{標號} {指令或僞指令} {；註釋}
在彙編語言程序設計中，每一條指令的助記符可以全部用大寫、或全部用小寫，但不用許在一條指令中大、小寫混用。
同時，如果一條語句太長，可將該長語句分爲若干行來書寫，在行的末尾用“/”表示下一行與本行爲同一條語句。
4.2.1在彙編語言程序中常用的符號
在彙編語言程序設計中，經常使用各種符號代替地址、變量和常量等，以增加程序的可讀性。儘管符號的命名由編程者決定，但並不是任意的，必須遵循以下的約定：
— 符號區分大小寫，同名的大、小寫符號會被編譯器認爲是兩個不同的符號。
— 符號在其作用範圍內必須唯一。
— 自定義的符號名不能與系統的保留字相同。
— 符號名不應與指令或僞指令同名。
1、 程序中的變量
程序中的變量是指其值在程序的運行過程中可以改變的量。ARM（Thumb）彙編程序所支持的變量有數字變量、邏輯變量和字符串變量。
數字變量用於在程序的運行中保存數字值，但注意數字值的大小不應超出數字變量所能表示的範圍。
邏輯變量用於在程序的運行中保存邏輯值，邏輯值只有兩種取值情況：真或假。
字符串變量用於在程序的運行中保存一個字符串，但注意字符串的長度不應超出字符串變量所能表示的範圍。
在ARM（Thumb）彙編語言程序設計中，可使用GBLA、GBLL、GBLS僞指令聲明全局變量，使用LCLA、LCLL、LCLS僞指令聲明局部變量，並可使用SETA、SETL和SETS對其進行初始化。
2、 程序中的常量
程序中的常量是指其值在程序的運行過程中不能被改變的量。ARM（Thumb）彙編程序所支持的常量有數字常量、邏輯常量和字符串常量。
數字常量一般爲32位的整數，當作爲無符號數時，其取值範圍爲0～232-1，當作爲有符號數時，其取值範圍爲-231～231-1。
邏輯常量只有兩種取值情況：真或假。
字符串常量爲一個固定的字符串，一般用於程序運行時的信息提示。
3、 程序中的變量代換
程序中的變量可通過代換操作取得一個常量。代換操作符爲“$”。
如果在數字變量前面有一個代換操作符“$”，編譯器會將該數字變量的值轉換爲十六進制的字符串，並將該十六進制的字符串代換“$”後的數字變量。
如果在邏輯變量前面有一個代換操作符“$”，編譯器會將該邏輯變量代換爲它的取值（真或假）。
如果在字符串變量前面有一個代換操作符“$”，編譯器會將該字符串變量的值代換“$”後的字符串變量。
使用示例：
LCLS S1 ；定義局部字符串變量S1和S2
LCLS S2
S1 SETS “Test！”
S2 SETS “This is a $S1” ；字符串變量S2的值爲“This is a Test！”
4.2.2彙編語言程序中的表達式和運算符
在彙編語言程序設計中，也經常使用各種表達式，表達式一般由變量、常量、運算符和括號構成。常用的表達式有數字表達式、邏輯表達式和字符串表達式，其運算次序遵循如下的優先級：
— 優先級相同的雙目運算符的運算順序爲從左到右。
— 相鄰的單目運算符的運算順序爲從右到左，且單目運算符的優先級高於其他運算符。
— 括號運算符的優先級最高。
1、 數字表達式及運算符
數字表達式一般由數字常量、數字變量、數字運算符和括號構成。與數字表達式相關的運算符如下：
— “＋”、“－”、“×”、“/” 及“MOD”算術運算符
以上的算術運算符分別代表加、減、乘、除和取餘數運算。例如，以X和Y表示兩個數字表達式，則：
X＋Y 表示X與Y的和。
X－Y 表示X與Y的差。
X×Y 表示X與Y的乘積。
X/Y 表示X除以Y的商。
X：MOD：Y 表示X除以Y的餘數。
— “ROL”、“ROR”、“SHL”及“SHR”移位運算符
以X和Y表示兩個數字表達式，以上的移位運算符代表的運算如下：
X：ROL：Y 表示將X循環左移Y位。
X：ROR：Y 表示將X循環右移Y位。
X：SHL：Y 表示將X左移Y位。
X：SHR：Y 表示將X右移Y位。
— “AND”、“OR”、“NOT”及“EOR”按位邏輯運算符
以X和Y表示兩個數字表達式，以上的按位邏輯運算符代表的運算如下：
X：AND：Y 表示將X和Y按位作邏輯與的操作。
X：OR：Y 表示將X和Y按位作邏輯或的操作。
：NOT：Y 表示將Y按位作邏輯非的操作。
X：EOR：Y 表示將X和Y按位作邏輯異或的操作。
2、 邏輯表達式及運算符
邏輯表達式一般由邏輯量、邏輯運算符和括號構成，其表達式的運算結果爲真或假。與邏輯表達式相關的運算符如下：
— “=”、“>”、“<”、“>=”、“<= ”、“/=”、“ <>” 運算符
以X和Y表示兩個邏輯表達式，以上的運算符代表的運算如下：
X = Y 表示X等於Y。
X > Y 表示X大於Y。
X < Y 表示X小於Y。
X >= Y 表示X大於等於Y。
X <= Y 表示X小於等於Y。
X /= Y 表示X不等於Y。
X <> Y 表示X不等於Y。
— “LAND”、“LOR”、“LNOT”及“LEOR”運算符
以X和Y表示兩個邏輯表達式，以上的邏輯運算符代表的運算如下：
X：LAND：Y 表示將X和Y 作邏輯與的操作。
X：LOR：Y 表示將X和Y作邏輯或的操作。
：LNOT：Y 表示將Y作邏輯非的操作。
X：LEOR：Y 表示將X和Y作邏輯異或的操作。
3、 字符串表達式及運算符
字符串表達式一般由字符串常量、字符串變量、運算符和括號構成。編譯器所支持的字符串最大長度爲512字節。常用的與字符串表達式相關的運算符如下：
— LEN運算符
LEN運算符返回字符串的長度（字符數），以X表示字符串表達式，其語法格式如下：
：LEN：X
— CHR運算符
CHR運算符將0～255之間的整數轉換爲一個字符，以M表示某一個整數，其語法格式如下：
：CHR：M
— STR運算符
STR運算符將將一個數字表達式或邏輯表達式轉換爲一個字符串。對於數字表達式，STR運算符將其轉換爲一個以十六進制組成的字符串；對於邏輯表達式，STR運算符將其轉換爲字符串T或F，其語法格式如下：
：STR：X
其中，X爲一個數字表達式或邏輯表達式。
— LEFT運算符
LEFT運算符返回某個字符串左端的一個子串，其語法格式如下：
X：LEFT：Y
其中：X爲源字符串，Y爲一個整數，表示要返回的字符個數。
— RIGHT運算符
與LEFT運算符相對應，RIGHT運算符返回某個字符串右端的一個子串，其語法格式如下：
X：RIGHT：Y
其中：X爲源字符串，Y爲一個整數，表示要返回的字符個數。
— CC運算符
CC運算符用於將兩個字符串連接成一個字符串，其語法格式如下：
X：CC：Y
其中：X爲源字符串1，Y爲源字符串2，CC運算符將Y連接到X的後面。
4、 與寄存器和程序計數器（PC）相關的表達式及運算符
常用的與寄存器和程序計數器（PC）相關的表達式及運算符如下：
— BASE運算符
BASE運算符返回基於寄存器的表達式中寄存器的編號，其語法格式如下：
：BASE：X
其中，X爲與寄存器相關的表達式。
— INDEX運算符
INDEX運算符返回基於寄存器的表達式中相對於其基址寄存器的偏移量，其語法格式如下：
：INDEX：X
其中，X爲與寄存器相關的表達式。
5、 其他常用運算符
— ？運算符
？運算符返回某代碼行所生成的可執行代碼的長度，例如：
?X
返回定義符號X的代碼行所生成的可執行代碼的字節數。
— DEF運算符
DEF運算符判斷是否定義某個符號，例如：
：DEF：X
如果符號X已經定義，則結果爲真，否則爲假。
4.3 彙編語言的程序結構
4.3.1彙編語言的程序結構
在ARM（Thumb）彙編語言程序中，以程序段爲單位組織代碼。段是相對獨立的指令或數據序列，具有特定的名稱。段可以分爲代碼段和數據段，代碼段的內容爲執行代碼，數據段存放代碼運行時需要用到的數據。一個彙編程序至少應該有一個代碼段，當程序較長時，可以分割爲多個代碼段和數據段，多個段在程序編譯鏈接時最終形成一個可執行的映象文件。
可執行映象文件通常由以下幾部分構成：
—一個或多個代碼段，代碼段的屬性爲只讀。
— 零個或多個包含初始化數據的數據段，數據段的屬性爲可讀寫。
— 零個或多個不包含初始化數據的數據段，數據段的屬性爲可讀寫。
鏈接器根據系統默認或用戶設定的規則，將各個段安排在存儲器中的相應位置。因此源程序中段之間的相對位置與可執行的映象文件中段的相對位置一般不會相同。
以下是一個彙編語言源程序的基本結構：
AREA Init，CODE，READONLY
ENTRY
Start
LDR R0，=0x3FF5000
LDR R1，0xFF
STR R1，[R0]
LDR R0，=0x3FF5008
LDR R1，0x01
STR R1，[R0]
┉┉
END
在彙編語言程序中，用AREA僞指令定義一個段，並說明所定義段的相關屬性，本例定義一個名爲Init的代碼段，屬性爲只讀。ENTRY僞指令標識程序的入口點，接下來爲指令序列，程序的末尾爲END僞指令，該僞指令告訴編譯器源文件的結束，每一個彙編程序段都必須有一條END僞指令，指示代碼段的結束。
4.3.2彙編語言的子程序調用
在ARM彙編語言程序中，子程序的調用一般是通過BL指令來實現的。在程序中，使用指令：BL 子程序名
即可完成子程序的調用。
該指令在執行時完成如下操作：將子程序的返回地址存放在連接寄存器LR中，同時將程序計數器PC指向子程序的入口點，當子程序執行完畢需要返回調用處時，只需要將存放在LR中的返回地址重新拷貝給程序計數器PC即可。在調用子程序的同時，也可以完成參數的傳遞和從子程序返回運算的結果，通常可以使用寄存器R0～R3完成。
以下是使用BL指令調用子程序的彙編語言源程序的基本結構：
AREA Init，CODE，READONLY
ENTRY
Start
LDR R0，=0x3FF5000
LDR R1，0xFF
STR R1，[R0]
LDR R0，=0x3FF5008
LDR R1，0x01
STR R1，[R0]
BL PRINT_TEXT
┉┉
PRINT_TEXT
┉┉
MOV PC，BL
┉┉
END
4.3.3彙編語言程序示例
以下是一個基於S3C4510B的串行通訊程序，關於S3C4510B的串行通訊的工作原理，可以參考第六章的相關內容，在此僅向讀者說明一個完整彙編語言程序的基本結構：
;********************************************************************************
; Institute of Automation,Chinese Academy of Sciences
;Description: This example shows the UART communication！
;Author: JuGuang,Lee
;Date:
;********************************************************************************
UARTLCON0 EQU 0x3FFD000
UARTCONT0 EQU 0x3FFD004
UARTSTAT0 EQU 0x3FFD008
UTXBUF0 EQU 0x3FFD00C
UARTBRD0 EQU 0x3FFD014
AREA Init,CODE,READONLY
ENTRY
;**************************************************
;LED Display
;**************************************************
LDR R1,=0x3FF5000
LDR R0,=&ff
STR R0,[R1]
LDR R1,=0x3FF5008
LDR R0,=&ff
STR R0,[R1]
;*************************************************
;UART0 line control register
;*************************************************
LDR R1,=UARTLCON0
LDR R0,=0x03
STR R0,[R1]
;**************************************************
;UART0 control regiser
;**************************************************
LDR R1,=UARTCONT0
LDR R0,=0x9
STR R0,[R1]
;**************************************************
;UART0 baud rate divisor regiser
;Baudrate=19200，對應於50MHz的系統工作頻率
;***************************************************
LDR R1,=UARTBRD0
LDR R0,=0x500
STR R0,[R1]
;***************************************************
;Print the messages!
;***************************************************
LOOP
LDR R0,=Line1
BL PrintLine
LDR R0,=Line2
BL PrintLine
LDR R0,=Line3
BL PrintLine
LDR R0,=Line4
BL PrintLine
LDR R1,=0x7FFFFF
LOOP1
SUBS R1,R1,#1
BNE LOOP1
B LOOP
;***************************************************
;Print line
;***************************************************
PrintLine
MOV R4,LR
MOV R5,R0
Line
LDRB R1,[R5],#1
AND R0,R1,#&FF
TST R0,#&FF
MOVEQ PC,R4
BL PutByte
B Line
PutByte
LDR R3,=UARTSTAT0
LDR R2,[R3]
TST R2,#&40
BEQ PutByte
LDR R3,=UTXBUF0
STR R0,[R3]
MOV PC,LR
Line1 DCB &A,&D,"******************************************************************",0
Line2 DCB &A,&D,"Chinese Academy of Sciences,Institute of Automation,Complex System Lab.",0
Line3 DCB &A,&D," ARM Development Board Based on Samsung ARM S3C4510B.",0
Line4 DCB &A,&D,&A,&D,&A,&D,&A,&D,&A,&D,&A,&D,&A,&D,&A,&D,&A,&D,&A,&D,&A,&D,&A,&D,&A,&D,&A,&D,&A,&D,0
END
4.3.4彙編語言與C/C++的混合編程
在應用系統的程序設計中，若所有的編程任務均用彙編語言來完成，其工作量是可想而知的，同時，不利於系統升級或應用軟件移植，事實上，ARM體系結構支持C/C＋以及與彙編語言的混合編程，在一個完整的程序設計的中，除了初始化部分用彙編語言完成以外，其主要的編程任務一般都用C/C++ 完成。
彙編語言與C/C++的混合編程通常有以下幾種方式：
－ 在C/C＋＋代碼中嵌入彙編指令。
－ 在彙編程序和C/C＋＋的程序之間進行變量的互訪。
－ 彙編程序、C/C＋＋程序間的相互調用。
在以上的幾種混合編程技術中，必須遵守一定的調用規則，如物理寄存器的使用、參數的傳遞等，這對於初學者來說，無疑顯得過於煩瑣。在實際的編程應用中，使用較多的方式是：程序的初始化部分用彙編語言完成，然後用C/C＋＋完成主要的編程任務，程序在執行時首先完成初始化過程，然後跳轉到C/C＋＋程序代碼中，彙編程序和C/C＋＋程序之間一般沒有參數的傳遞，也沒有頻繁的相互調用，因此，整個程序的結構顯得相對簡單，容易理解。以下是一個這種結構程序的基本示例，該程序基於第五、六章所描述的硬件平臺：
;*************************************************************************
; Institute of Automation, Chinese Academy of Sciences
;File Name: Init.s
;Description:
;Author: JuGuang,Lee
;Date:
;************************************************************************
IMPORT Main ;通知編譯器該標號爲一個外部標號
AREA Init,CODE,READONLY ；定義一個代碼段
ENTRY ；定義程序的入口點
LDR R0,=0x3FF0000 ；初始化系統配置寄存器，具體內容可參考第五、六章
LDR R1,=0xE7FFFF80
STR R1,[R0]
LDR SP,=0x3FE1000 ；初始化用戶堆棧，具體內容可參考第五、六章
BL Main ；跳轉到Main（）函數處的C/C++代碼執行
END ；標識彙編程序的結束
以上的程序段完成一些簡單的初始化，然後跳轉到Main（）函數所標識的C/C＋＋代碼處執行主要的任務，此處的Main僅爲一個標號，也可使用其他名稱，與C語言程序中的main（）函數沒有關係。
/*******************************************************************************
* Institute of Automation, Chinese Academy of Sciences
* File Name: main.c
* Description: P0,P1 LED flash.
* Author: JuGuang,Lee
* Date:
******************************************************************************/
void Main(void)
{
int i;
*((volatile unsigned long *) 0x3ff5000) = 0x0000000f;
while(1)
{
*((volatile unsigned long *) 0x3ff5008) = 0x00000001;
for(i=0; i<0x7fFFF; i++);
*((volatile unsigned long *) 0x3ff5008) = 0x00000002;
for(i=0; i<0x7FFFF; i++);
}
}
4.4 本章小節
4.4 本章小節
本章介紹了ARM程序設計的一些基本概念，以及在彙編語言程序設計中常見的僞指令、彙編語言的基本語句格式等，彙編語言程序的基本結構等，同時簡單介紹了C/C＋＋和彙編語言的混合編程等問題，這些問題均爲程序設計中的基本問題，希望讀者掌握，注意本章最後的兩個示例均與後面章節介紹的基於S3C4510B的硬件平臺有關係，讀者可以參考第五、六章的相關內容。