3d遊戲中人物被遮擋後以其它顏色顯示的方法

好久沒有更新博客，最近忙於其他事情了。

今天玩了一下九陰真經，偶然發現裏邊有一個效果，如圖顯示：

我們一步步來解釋這個效果的原理，涉及的方面其實還挺多的。

首先我們必須清楚地知道，在角色被遮擋的時候，已經暴露出來模型其實是分兩次渲染，也就是該模型的着色器必然是存在兩個通道的。第一個通道便是遮擋後顯示出來的藍色，第二個通道就是普通情況下顯示出來的模型。

第一步：前面的屋子沒有能夠遮擋住角色的渲染，那麼說明角色的渲染一定是在屋子的模型渲染之後進行渲染的並且能通過深度測試，於是第一步裏，我們要做的就是將角色模型的渲染隊列設置爲在屋子的模型隊列之後渲染，一般情況下是設置爲Tags { "Queue" = "Transparent" }，當然你也可以設置其他的，只要保證是在遮擋物之後渲染就可以了。而且明顯角色被遮擋並且是在最後渲染，也就是說角色不可能通過深度測試，於是，我們需要加上一條命令ZTest Always，保證一定能覆蓋原像素。

第二步：我們知道在沒有遮擋的時候顯示的模型是正常的，不會顯示裏面藍色的部分，所以我們前面說的角色模型的兩個着色器通道里面的第二個通道就必須能保證覆蓋第一個通道渲染的藍色像素值，我們可以設置第一個通道的深度值是不寫入的，於是就保證了第二個通道的絕對覆蓋。所以在第一個通道里面，我們還需要加上ZWrite Off。

第三步：我們理一下第二步，第二步裏面說第一個通道的深度值是不寫入的，那麼在寫入之前深度緩衝區中緩存的是哪裏的深度值呢？正是屋子模型的深度，也就是說，（1）在被遮擋的時候，當渲染第一個通道的時候，由於ZTest Always和ZWrite Off的存在，使得不需要測試深度，計算機就把像素替換成了模型的像素，但是卻保留了屋子模型的深度。當開始渲染第二個通道的時候，卻沒辦法通過深度測試，所以最終輸出了第一個通道的顏色；（2）當角色模型沒有被遮擋的時候，第一個通道輸出後，深度緩衝區緩存的是地面的深度值，而角色模型的深度明顯是小於地面的深度值的，所以第二個通道的深度測試通過了，也就覆蓋了第一個通道，所以沒有遮擋的時候輸出了第二個通道的模型顏色。

下面奉上源碼：

Shader "Outlined/Silhouetted Bumped Diffuse" {
	Properties {
		_Color ("Main Color", Color) = (.5,.5,.5,1)
		_OutlineColor ("Outline Color", Color) = (0,0,0,1)
		_Outline ("Outline width", Range (0.0, 0.03)) = .005
		_MainTex ("Base (RGB)", 2D) = "white" { }
		_BumpMap ("Bumpmap", 2D) = "bump" {}
	}
 
CGINCLUDE
#include "UnityCG.cginc"
 
struct appdata {
	float4 vertex : POSITION;
	float3 normal : NORMAL;
};
 
struct v2f {
	float4 pos : POSITION;
	float4 color : COLOR;
};
 
uniform float _Outline;
uniform float4 _OutlineColor;
 
v2f vert(appdata v) {
	// just make a copy of incoming vertex data but scaled according to normal direction
	v2f o;
	o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
 
	float3 norm   = mul ((float3x3)UNITY_MATRIX_IT_MV, v.normal);
	float2 offset = TransformViewToProjection(norm.xy);
 
	o.pos.xy += offset * o.pos.z * _Outline;
	o.color = _OutlineColor;
	return o;
}
ENDCG
 
	SubShader {
		Tags { "Queue" = "Transparent" }
 
		// note that a vertex shader is specified here but its using the one above
		Pass {
			Name "OUTLINE"
			Tags { "LightMode" = "Always" }
			Cull Off
			ZWrite Off
			ZTest Always
 
			// you can choose what kind of blending mode you want for the outline
			Blend SrcAlpha OneMinusSrcAlpha // Normal
			//Blend One One // Additive
			//Blend One OneMinusDstColor // Soft Additive
			//Blend DstColor Zero // Multiplicative
			//Blend DstColor SrcColor // 2x Multiplicative
 
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
 
half4 frag(v2f i) : COLOR {
	return i.color;
}
ENDCG
		}
 
 
CGPROGRAM
#pragma surface surf Lambert
struct Input {
	float2 uv_MainTex;
	float2 uv_BumpMap;
};
sampler2D _MainTex;
sampler2D _BumpMap;
uniform float3 _Color;
void surf(Input IN, inout SurfaceOutput o) {
	o.Albedo = tex2D(_MainTex, IN.uv_MainTex).rgb * _Color;
	o.Normal = UnpackNormal(tex2D(_BumpMap, IN.uv_BumpMap));
}
ENDCG
 
	}
 
	Fallback "Outlined/Silhouetted Diffuse"
}