Oracle PL/SQL进阶编程（第六弹：使用系统包：DBMS_OUTPUT）

该包使得我们可以从存储过程、包或触发器中发送信息。

Oracle推荐在调试PL/SQL程序时使用该包，不建议使用它来做报表输出或其他的格式化应用。

启用或禁用DBMS_OUTPUT

默认情况下，Oracle并没有启用DBMS_OUTPUT包，也就是说，直接使用DBMS_OUTPUT.PUT_LINE或GET_LINE来输出或获取消息，是看不到任何输出的。要先使用DBMS_OUTPUT.ENABLE来启用包的功能。
DBMS_OUTPUT.ENABLE(buffer_size IN INTEGER DEFAULT 20000);
buffer_size用来指定缓冲区，缓冲区的最大尺寸为1000000字节 ，最小为2000字节，默认为20000字节。

SQL*Plus有一个SET SERVEROUTPUT ON语句，来启用DBMS_OUTPUT包，如果执行了该语句，则没有必要使用DBMS_OUTPUT.ENABLE，因为SET SERVEROUTPUT ON会自动调用该语句。

禁用DBMS_OUTPUT只需要调用DBMS_OUTPUT.DISABLE即可，它同时会清除缓冲区中所有的数据。当执行SET SERVEROUTPUT OFF时，SQL*Plus也会调用DBMS_OUTPUT.DISABLE过程。

向缓冲区中提取与写入内容

必须要理解的是，DBMS_OUTPUT并不是直接将信息输出到屏幕，而是将数据写入到了一个缓冲区中，然后再次将这些输出读回。当在SQL*Plus中使用SET SERVEROUTPUT ON命令时，实际上是让SQL*Plus在每条DBMS_OUTPUT之后检查缓冲区中的内容，然后在屏幕上进行显示。

可以使用如下几个过程来向缓冲区中输入消息：
- PUT：将信息写入缓冲区，不包含换行符。
- PUT_LINE：将完整的行信息写入缓冲区，包含换行符。
- NEW_LINE：在行尾添加换行符。

可以使用如下几个过程来从缓冲区中提取消息：
- GET_LINE：用于取得缓冲区中的单行信息。
- GET_LINES：用于取得缓冲区中的多行信息。

基本语法如下：

DBMS_OUTPUT.PUT(item IN NUMBER);
DBMS_OUTPUT.PUT(item IN VARCHAR2);
DBMS_OUTPUT.PUT(item IN DATE);
DBMS_OUTPUT.PUT_LINE(item IN NUMBER);
DBMS_OUTPUT.PUT_LINE(item IN VARCHAR2);
DBMS_OUTPUT.PUT_LINE(item IN DATE);
DBMS_OUTPUT.NEW_LINE;
DBMS_OUTPUT.GET_LINE(line OUT VARCHAR2, status OUT INTEGER);
DBMS_OUTPUT.GET_LINES(line OUT CHARARR, numlines IN OUT INTEGER);

PUT和PUT_LINE的参数很容易理解，下面说一下GET_LINE和GET_LINES的参数。
- line：被GET_LINE取回的行，GET_LINES中的line是一个CHARARR类型，它是一个VARCHAR2(255)的嵌套表，它将返回缓冲区的多行信息的数组。
- status：指出是否取回一行，1表示行参数包含从缓冲区中取回1行，0表示缓冲区为空，没有取回数据。
- numlines：它既可以作为输入参数，也可以作为输出参数。作为输入参数表明希望返回的行数，作为输出时返回实际取回的行数。如果返回的数字比要求返回的数字少，则表明缓冲区中已经没有数据了。

演示代码如下：

DECLARE
   v_line1 VARCHAR(200);                  
   v_line2 VARCHAR(200);      
   v_status NUMBER;
 BEGIN
    DBMS_OUTPUT.ENABLE;                                              --开启DBMS_OUTPUT
    DBMS_OUTPUT.PUT_LINE('DBMS_OUTPUT主要用于输出信息，它包含：');  --写入并换行
    DBMS_OUTPUT.PUT('PUT_LINE');                                     --写入文本不换行
    DBMS_OUTPUT.PUT(',PUT_LINE');
    DBMS_OUTPUT.PUT(',PUTE');
    DBMS_OUTPUT.PUT(',NEW_LINE');
    DBMS_OUTPUT.PUT(',GET_LINE');
    DBMS_OUTPUT.PUT(',GET_LINES等过程');
    DBMS_OUTPUT.NEW_LINE;                                           --在文本最后加上换行符
    DBMS_OUTPUT.GET_LINE(v_line1,v_status);  
    DBMS_OUTPUT.GET_LINE(v_line2,v_status);                         --获取缓冲区中的数据行
    DBMS_OUTPUT.PUT_LINE(v_line1);                                  --输出变量的值到缓冲区
    DBMS_OUTPUT.PUT_LINE(v_line2);       
 END;
 /

缓冲区使用了先进先出（FIFO）算法，最先写入的最先被读取。如果一次从缓冲区读取多行，可以采用GET_LINES，然后循环获取到行进行显示：

DECLARE
   v_lines DBMS_OUTPUT.CHARARR;                                     --定义集合类型的变量
   v_status NUMBER;
 BEGIN
    DBMS_OUTPUT.ENABLE;                                             --开启DBMS_OUTPUT
    DBMS_OUTPUT.PUT_LINE('DBMS_OUTPUT主要用于输出信息，它包含：');  --写入并换行
    DBMS_OUTPUT.PUT('PUT_LINE');                                     --写入文本不换行
    DBMS_OUTPUT.PUT(',PUT_LINE');
    DBMS_OUTPUT.PUT(',PUTE');
    DBMS_OUTPUT.PUT(',NEW_LINE');
    DBMS_OUTPUT.PUT(',GET_LINE');
    DBMS_OUTPUT.PUT(',GET_LINES等过程');
    DBMS_OUTPUT.NEW_LINE;                                           --在文本最后加上换行符     
    DBMS_OUTPUT.GET_LINES(v_lines,v_status);                        --获取缓冲区中所有的行
    FOR i IN 1..v_status LOOP
       DBMS_OUTPUT.PUT_LINE(v_lines(i));                            --输出集合中所有的数据行
    END LOOP;   
 END; 
 /