在用Go編寫應用程序的時候，可以認爲main.main是整個應用程序的入口，但站在整個Go程序的角度來看，卻並非如此。在main.main函數之前，Go底層已經做了大量的初始化工作，下面開始從程序真正的入口開始瞭解下初始化前的工作。
入口
通過GDB可以找到程序入口：
go build -gcflags "-N -l" -o test test.go
info files會列出程序的入口地址：
(gdb) info files
Symbols from "/home/sandydu/program/golang/test".
Local exec file:
`/home/sandydu/program/golang/test', file type elf64-x86-64.
Entry point: 0x452890
Entry point: 0x452890這個就是我們要打的入口地址，直接對這個地址打斷點，GDB就會自動列出斷點的具體位置：
(gdb) b *0x452890
Breakpoint 1 at 0x452890: file /usr/local/go/src/runtime/rt0_linux_amd64.s, line 8.
rt0_linux_amd64.s文件的第8行就是真正的入口地址，看下詳細代碼：
@(src/runtime/rt0_linux_amd64.s:8)
TEXT _rt0_arm64_linux(SB),NOSPLIT|NOFRAME,$0
MOVD 0(RSP), R0 // argc
ADD $8, RSP, R1 // argv
BL main(SB)
_rt0_arm64_linux的工作就是把命令行參數argc、argv放到寄存器，然後跳轉到本文件的main繼續執行，代碼如下：
@(src/runtime/rt0_linux_amd64.s:98)
TEXT main(SB),NOSPLIT|NOFRAME,$0
MOVD $runtime·rt0_go(SB), R2
BL (R2)
exit:
MOVD $0, R0
MOVD $94, R8 // sys_exit
SVC
B exit
再繼續跳轉到runtime·rt0_go執行（沒搞懂爲啥要這樣跳來跳去，直接點不好嘛。。。）
runtime·rt0_go開始進入初始化的流程，這個方法主要工作如下：
- 處理命令行參數，將argc,argv放入棧。
- 獲取CPU相關信息
- 將g0(0號goroutine)存入TLS，將m0(0號線程)存入TLS
- 調用runtime.args，去 stack 裏讀取參數和環境變量
- 調用runtime.osinit，獲取CPU核數
- 調用runtime.schedinit，這個函數功能很多，主要初始化調度相關的信息，後面詳細介紹
- 調用runtime.newproc，創建一個新的協程，並執行runtime.main，這個函數會調用我們熟悉的main.init和main.main
- 創建 一個m，並調用schedule開始進入調度狀態，整個程序開始run起來
TEXT runtime·rt0_go(SB),NOSPLIT,$0
// 將參數argc、argv放到堆棧上
MOVQ DI, AX // argc
MOVQ SI, BX // argv
SUBQ $(4*8+7), SP // 2args 2auto
ANDQ $~15, SP
MOVQ AX, 16(SP)
MOVQ BX, 24(SP)
// 初始化g0的stackguard和stack
// g0.stackguard0 = (-64*1024+104)(SP)
// g0.stackguard1 = (-64*1024+104)(SP)
// g0.stack.l0 = (-64*1024+104)(SP)
// g0.stack.hi = SP
MOVQ $runtime·g0(SB), DI
LEAQ (-64*1024+104)(SP), BX
MOVQ BX, g_stackguard0(DI)
MOVQ BX, g_stackguard1(DI)
MOVQ BX, (g_stack+stack_lo)(DI)
MOVQ SP, (g_stack+stack_hi)(DI)
// 通過CPUID指令獲取CPU信息
// 詳見https://c9x.me/x86/html/file_module_x86_id_45.html
MOVL $0, AX
CPUID
MOVL AX, SI
CMPL AX, $0
JE nocpuinfo
// Figure out how to serialize RDTSC.
// On Intel processors LFENCE is enough. AMD requires MFENCE.
// Don't know about the rest, so let's do MFENCE.
CMPL BX, $0x756E6547 // "Genu"
JNE notintel
CMPL DX, $0x49656E69 // "ineI"
JNE notintel
CMPL CX, $0x6C65746E // "ntel"
JNE notintel
MOVB $1, runtime·isIntel(SB)
MOVB $1, runtime·lfenceBeforeRdtsc(SB)
notintel:
// Load EAX=1 cpuid flags
MOVL $1, AX
CPUID
MOVL AX, runtime·processorVersionInfo(SB)
nocpuinfo:
// 如果啓用了cgo，就執行_cgo_init函數
MOVQ _cgo_init(SB), AX
TESTQ AX, AX
JZ needtls
// g0 already in DI
MOVQ DI, CX // Win64 uses CX for first parameter
MOVQ $setg_gcc<>(SB), SI
CALL AX
// 重新更新g0的g0的stackguard和stack
MOVQ $runtime·g0(SB), CX
MOVQ (g_stack+stack_lo)(CX), AX
ADDQ $const__StackGuard, AX
MOVQ AX, g_stackguard0(CX)
MOVQ AX, g_stackguard1(CX)
needtls:
// 初始化TLS
LEAQ runtime·m0+m_tls(SB), DI
CALL runtime·settls(SB)
// 驗證TLS是否初始化成功
get_tls(BX)
MOVQ $0x123, g(BX)
MOVQ runtime·m0+m_tls(SB), AX
CMPQ AX, $0x123
JEQ 2(PC)
CALL runtime·abort(SB)
ok:
// 把g0放入TLS，後面可以通過getg函數找到了
get_tls(BX)
LEAQ runtime·g0(SB), CX
MOVQ CX, g(BX)
LEAQ runtime·m0(SB), AX
// 將g0存到m0中，m->g0 = g0
MOVQ CX, m_g0(AX)
// 將m0存到g0中，g0->m = m0
MOVQ AX, g_m(CX)
CLD // convention is D is always left cleared
CALL runtime·check(SB)
// 處理參數
MOVL 16(SP), AX // copy argc
MOVL AX, 0(SP)
MOVQ 24(SP), AX // copy argv
MOVQ AX, 8(SP)
CALL runtime·args(SB)
// 初始化OS:獲取CPU數量
CALL runtime·osinit(SB)
// 初始化調度，非常重要的函數，後續詳解
CALL runtime·schedinit(SB)
// 創建一個goruntine並執行，執行函數爲runtime.main
// 即: go runtime.main()
MOVQ $runtime·mainPC(SB), AX // entry
PUSHQ AX
PUSHQ $0 // arg size
CALL runtime·newproc(SB)
POPQ AX
POPQ AX
// 啓動這個m，即m0，裏面會調用schedule函數進入調度狀態
CALL runtime·mstart(SB)
CALL runtime·abort(SB) // mstart should never return
RET
MOVQ $runtime·debugCallV1(SB), AX
RET
DATA runtime·mainPC+0(SB)/8,$runtime·main(SB)
GLOBL runtime·mainPC(SB),RODATA,$8