UI平面特效火

使用shader寫了個平面火焰的特效，可以在UI上使用，類似於live2d的效果。
有以下特點：

1. 火焰流動
2. 火焰左右搖擺
3. 火焰大小變化，忽大忽小，忽明忽暗

由於上傳圖片大小限制，gif的幀數低，看起來效果不是很好看。
效果如下：

代碼如下：

Shader "Unlit/MyFire"{   
    Properties {   
        _MainTex ("_MainTex", 2D) = "white" { }
        _wave ("_wave", 2D) = "white" { }
    }   
    SubShader {   
        Tags {
            "Queue"="Transparent"
        }
        pass {   
            Blend SrcAlpha  OneMinusSrcAlpha   
            CGPROGRAM  
            #pragma vertex vert   
            #pragma fragment frag   
            #include "UnityCG.cginc"   
            float4 _MainTex_ST;
            sampler2D _MainTex;   
            sampler2D _wave;   
            struct appdata_t {
                float4 vertex   : POSITION;
                float2 texcoord : TEXCOORD0;
            };
            struct v2f {   
                float4  pos : SV_POSITION;
                float2  _uv_MainTex : TEXCOORD0;
                float2  _uv_STD : TEXCOORD1;
            };   


            v2f vert (appdata_t IN) {
                v2f OUT;   
                OUT.pos = UnityObjectToClipPos(IN.vertex);
                OUT._uv_STD = TRANSFORM_TEX(IN.texcoord,_MainTex);  
                return OUT;
            }   
            float4 frag (v2f i) : COLOR {

                float sintz = sin(_Time.z);
                float sintw = sin(_Time.w);
                //採樣波浪，使火焰流動以及熱膨脹膨脹,以下參數根據採樣圖片不同需要調整
                float2  uv_wave = i._uv_STD+fixed2(sintw*0.003,-16)*(_Time.x);
                uv_wave = uv_wave/fixed2(0.7,0.4);    
                float4 color_uv4 = tex2D(_wave,uv_wave);    
                uv_wave = -(color_uv4.r*fixed2(-0.08,0.12) + (color_uv4.g-0.1)*fixed2(0.2,0));    
                uv_wave.x *= i._uv_STD.y*1.5;

                float2  uv_image2 = i._uv_STD + uv_wave;
                //火焰左右搖動，幅度由uv的Y控制
                uv_image2.x += sintw*0.05*i._uv_STD.y;
                //火焰大小變化
                uv_image2.y = uv_image2.y*(sintz*0.06+0.9);
                fixed4 color_image2 = tex2D(_MainTex,uv_image2);
                //火焰明暗變化
                color_image2.rgb *=(1+ sintz*0.2);
                return color_image2;
            }  
            ENDCG
        }
    }
    fallback "Standard"
}