zhuangz：http://www.unity.5helpyou.com/2367.html
一、一些基本概念認知
1.1 Shader和Material的基本概念認知
先引用一段文字，闡述Shader和Material的基本關係：
“Shader（着色器）實際上就是一小段程序，它負責將輸入的Mesh（網格）以指定的方式和輸入的貼圖或者顏色等組合作用，然後輸出。繪圖單元可以依據這個輸出來將圖像繪製到屏幕上。輸入的貼圖或者顏色等，加上對應的Shader，以及對Shader的特定的參數設置，將這些內容（Shader及輸入參數）打包存儲在一起，得到的就是一個Material（材質）。之後，我們便可以將材質賦予合適的renderer（渲染器）來進行渲染（輸出）了。
所以說Shader並沒有什麼特別神奇的，它只是一段規定好輸入（顏色，貼圖等）和輸出（渲染器能夠讀懂的點和顏色的對應關係）的程序。而Shader開發者要做的就是根據輸入，進行計算變換，產生輸出而已。“
這段文字出自《貓都能學會的Unity3D Shader入門指南（一）》，是比較好的Unity Shader的入門文章，可惜只寫了兩篇，後面就沒有繼續了。淺墨在文章開頭懶得寫了，就講這句引用了過來。
1.2 背景知識說明
在這裏需要說明，學習Unity中的Shader編程，最好是之前對OpenGL或Direct3D的渲染狀態等相關知識有一個基本的瞭解。如果之前沒有太接觸過這方面的知識，可以看看淺墨寫的DirectX相關的教程。而需要大量惡補提升圖形編程功力的童鞋，可以在NVIDIA和AMD開發者網站上可以找一些着色器教程和文檔來啃啃。
對於本期的光照和材質，需要的背景知識可以看淺墨之前寫的這篇以DirectX爲載體的光照和材質導論式的文章：
《【Visual C++】遊戲開發筆記四十 淺墨DirectX教程之八 繪製真實質感的三維世界：光照與材質專場》
如果對其中的C++&DirectX的代碼不太熟悉的話，沒關係。看看概念，瞭解個大概就可以了。
二、 Unity中Shader的三種基本類型
我們知道，計算機圖形學的中渲染管線一般可以分爲兩種類型：
1.固定功能渲染管線(fixed-functionrendering pipelines)
2.可編程渲染管線(programmablerendering pipelines)
按這樣的分類思路，在Unity中，Shader便可以分成如下三種基本類型：
1.固定功能着色器（Fixed Function Shader）
2.表面着色器（Surface Shader）
3.頂點着色器&片段着色器 （Vertex Shader & Fragment Shader）
顧名思義，其中的固定功能着色器便是我們所說的固定功能渲染管線(fixed-functionrendering pipelines)的具體表現，而表面着色器、頂點着色器以及片段着色器便屬於可編程渲染管線。下面分別對其進行簡單的介紹。
2.1 關於固定功能着色器
這裏的固定功能着色器可以說是Unity爲Shader的書寫自帶的一層殼，Unity已經在內部爲我們做了大量的工作，我們只要稍微記住一些關鍵字、一些規範就可以實現出很多不錯的效果。固定功能着色器是我們初學Unity Shader的最近幾篇文章中的主要學習對象。而後面的表面着色器、頂點着色器以及片段着色器就是在固定功能着色器的基礎上嵌套了CG語言的代碼而成的更加複雜的着色器。我們來看看他們的一些基本概念。
2.2 關於表面着色器
表面着色器（Surface Shader）這個概念更多的只是在Unity中聽說，可以說是Unity自己發揚光大的一項使Shader的書寫門檻降低和更易用的技術。我們會在接下來的學習中逐漸意識到Unity是如何爲我們把Shader的複雜性包裝起來，使其書寫的過程更便捷和易用的。
2.3 關於頂點着色器和片段着色器
研究過Direct3D和OpenGL着色器編程的童鞋們一定對這兩者不陌生。我們來簡單介紹一下他們的用途。
頂點着色器：產生紋理座標，顏色，點大小，霧座標，然後把它們傳遞給裁剪階段。
片段着色器：進行紋理查找，決定什麼時候執行紋理查找，是否進行紋理查找，及把什麼作爲紋理座標
2.4 如何區分Unity中的Shader類型
在Unity中想要區分他們很簡單。後面熟悉了自然知道。在這裏淺墨先劇透一下：
沒有嵌套CG語言，也就是代碼段中沒有CGPROGARAM和ENDCG關鍵字的，就是固定功能着色器。
嵌套了CG語言，代碼段中有surf函數的，就是表面着色器。
嵌套了CG語言，代碼段中有#pragma vertex name和 #pragma fragment frag聲明的，就是頂點着色器&片段着色器。
三、Unity中將Shader賦給Material的兩種方法
在Unity中將Shader賦給Material使用的兩種方法。
【方法一】直接將Shader拖拽到Material之上。這種方法我們上篇文章中已經多次講到，也就是這樣：
【方法二】在Material的Inspector面板中選擇。
Unity中內建的Shader都是通過這種方式來讓Material使用的。在Material的Inspector中，其名字下方的Shader欄中選擇。可以發現Unity已經爲我們準備好了很多種不同的Shader，基本可以滿足居家旅行的需求了。
而對於我們自己新寫的Shader，也會在這個菜單欄中顯示出來。細心的朋友們看上圖的時候，肯定就已經發現了。
這裏選擇的菜單取決於我們Shader中定義Shader的第一行代碼時緊接着Shader關鍵字的引號“”裏面的書寫方式：
四、Unity 中Shader的基本框架
因爲着色器代碼可以說專用性非常強，因此Shader的設計者人爲地規定了它的基本結構。而Unity中Shader整體的框架寫法可以用如下的形式來概括：
Shader “name” { [Properties] SubShaders[Fallback] }
也就是說，Unity中所有着色器都是由Shader關鍵字開始，隨後的字符串表示着色器的名字。這個名字會顯示在Inspector檢視面板中。所有用於這個着色器的代碼必須放置在之後的大括號中：{ }（稱爲“塊”）。ps：該名字應該是短且描述性的文字。它並不需要和shader文件名相同。而想要把着色器加入到Unity的子菜單裏，名字需要用斜線(/)。例如：淺墨Shader編程/TheFirstShader就是一個名叫TheFirstShader的着色器，而這個着色器位於“淺墨Shader編程”的子菜單下。這樣，我們就可以在Shader後面緊跟着的引號中用“/”來構造出子二級甚至多級的子菜單來，方便了後面Shader寫多了時候的合理分類,不至於太亂。
OK，我們繼續講。有圖有真相，Shader整體的框架寫法用圖來說就是這樣：
看圖可以知道，首先是一些屬性定義，用來指定這段代碼將有哪些輸入。接下來是一個或者多個的子着色器，在實際運行中，哪一個子着色器被使用是由運行的平臺所決定的。子着色器是代碼的主體，每一個子着色器中包含一個或者多個的Pass。在計算着色時，平臺先選擇最優先可以使用的着色器，然後依次運行其中的Pass，然後得到輸出的結果。最後指定一個Fallback，可譯爲“回滾”，俗稱備胎，用來處理所有SubShader都不能運行的情況（比如目標設備實在太老，所有SubShader中都有其不支持的特性，於是只好用備胎了，不然就顯示不出來）。
不同的圖形卡有不同的性能，這對遊戲開發者來說是永恆的問題，而這恰恰就是子着色器爲什麼可以發光發熱的原因。若我們開發出了一種使用了當前業界前沿技術構成的Shader，這種Shader目前只有百分之1的牛逼哄哄的顯卡可以支持。
比較明智的做法是，把這套採用最前沿技術的Shader作爲我們衆多SubShader的其中的一員，然後還得準備一堆Plan B，應對其他硬件上的運行。也就是說，我們爲所期望的採用最新技術的效果編寫一個子着色器，然後爲之前古老的顯卡再編制一些備用的着色器。這些子着色器能選擇使用更低層次的方式來實現我們的效果，或者選擇放棄實現某些細節，確保無論在什麼機器上跑，都能夠運行出正確的效果。雖然這些效果會有一些細微的差別，因爲使用的SubShader是不一樣的，但卻保證了我們的Shader在任何機器上都跑得起來。
PS:在實際進行表面着色器的開發時，我們就是直接在SubShader這個層次上寫代碼，系統會將把我們的代碼編譯成若干個合適的Pass。
用一個實例代碼來說明吧。
我們在Project面板中右鍵->Create->Shader。新建一個Shader文件，然後雙擊打開，刪掉原先代碼，分分鐘，我們按照上文的講解，對照着圖示，就可以寫出如下框架的Shader代碼來：
Shader “淺墨Shader編程/0.Shader框架示例”
{
//——————————-【屬性】—————————————–
Properties
{
//紋理
_MainTex(“基本紋理”,2D)=”White”{TexGen ObjectLinear}
}
//———————————【子着色器1】———————————-
SubShader
{
//—————-通道—————
Pass
{
//設置紋理爲屬性中選擇的紋理
SetTexture[_MainTex]{combine texture}
}
}
//———————————【備胎】—————————————-
//備胎設爲Unity自帶的普通漫反射
Fallback” Diffuse ”
}
解釋起來就是：
1.着色器通過properties來可選的定義一個可通過材質設定界面來自定義的列表。具體到上述代碼中寫的Properties，就是定義了一個基本屬性，參數名叫做_MainTex，在編輯器中顯示的名稱叫做“基本紋理”， 且紋理生成模式爲ObjectLinear。
2.後面緊跟着核心部分子着色器SubShader，裏面的一個Pass裏面設置了紋理爲我們屬性中定義的那個_ MainTex。
3.添加一句Fallback代碼用於應對我們Shader中的SubShader不能正確運行的情況。
需要注意的是，SubShader在UnityShader的代碼段中必須有且至少有一個，而properties和fallback對於追求簡單的Shader，是可以不寫出來的。而複雜一點的Shader，當然各種properties、fallback什麼的肯定都有，甚至有多個SubShader，而每個SubShader中又有多個Pass。
這個框架程序我們後面寫新的Shader的時候就可以直接複製然後粘貼，接着在Properties中添加新的屬性，SubShader中填充新的Pass以及開闢新的SubShader就行，就像做填空題一樣。
五、Properties 屬性相關內容講解
下面，我們詳細地來看一看作爲Shader框架中三大組成部分之一的Properties屬性的相關內容。
properties一般定義在着色器的起始部分，我們可以在Shader書寫的時候定義多種多樣的屬性，而使用Shader的時候可以直接在材質檢視面板(Material Inspector)裏編輯這些屬性，取不同的值或者紋理。這可以說是Unity貼心&可見即所得的又一體現吧。
以Unity自帶的BasicVertex Lighting 基本頂點光照爲例，一張很直觀的圖就是這樣:
需要注意，Properties塊內的語法都是單行的。每個屬性都是由內部名稱開始，後面括號中是顯示在檢視面板(Inspector)中的名字和該屬性的類型。等號後邊跟的是默認值。
5.1 Properties屬性 相關代碼寫法列舉
這一小節我們列舉Unity中Shader的Properties屬性相關語法參考，可以在需要時進行查閱：
Properties { Property [Property …] }
定義屬性塊，其中可包含多個屬性，其定義如下：
name (“display name”, Range (min, max)) =number
定義浮點數屬性，在檢視器中可通過一個標註最大最小值的滑條來修改。
name (“display name”, Color) =(number,number,number,number)
定義顏色屬性
name (“display name”, 2D) = “name” {options }
定義2D紋理屬性
name (“display name”, Rect) = “name”{ options }
定義長方形（非2次方）紋理屬性
name (“display name”, Cube) = “name”{ options }
定義立方貼圖紋理屬性
name (“display name”, Float) = number
定義浮點數屬性
name (“display name”, Vector) =(number,number,number,number)
定義一個四元素的容器(相當於Vector4)屬性
5.2 一些細節說明
包含在着色器中的每一個屬性通過name索引（在Unity中, 通常使用下劃線來開始一個着色器屬性的名字）。屬性會將display name顯示在材質檢視器中，還可以通過在等符號後爲每個屬性提供缺省值。
對於Range和Float類型的屬性只能是單精度值。
對於Color和Vector類型的屬性將包含4個由括號圍住的數描述。
對於紋理(2D, Rect, Cube) 缺省值既可以是一個空字符串也可以是某個內置的缺省紋理：”white”, “black”, “gray” or”bump”
隨後在着色器中，屬性值通過[name]來訪問。
接着，讓我們看一個示例，瞭解屬性Properties的實際用法：
Shader “淺墨Shader編程/SimpleWater”
{
Properties{
//properties for water shader
//水着色器的屬性
_WaveScale(“Wave scale”, Range (0.02,0.15)) = 0.07 // 滑動條
_ReflDistort(“Reflection distort”, Range (0,1.5)) = 0.5
_RefrDistort(“Refraction distort”, Range (0,1.5)) = 0.4
_RefrColor(“Refraction color”, Color) =(.34, .85, .92, 1) // 顏色
_ReflectionTex(“Environment Reflection”, 2D) = “” {} // 紋理
_RefractionTex(“Environment Refraction”, 2D) = “” {}
_Fresnel(“Fresnel (A) “, 2D) = “” {}
_BumpMap(“Bumpmap (RGB) “, 2D) = “” {}
}
//後續代碼省略
………
}
5.3 關於紋理屬性選項
紋理屬性在本文的第一個示例中就有用到，這裏先再貼一遍2D紋理屬性的寫法：
name (“display name”, 2D) =”name” { options }
需要注意的是，包含在紋理屬性的大括號中的選項Options是可選的。可能的選項有如下：
TexGen紋理生成類型。即紋理的自動生成紋理座標時的模式，可以是ObjectLinear, EyeLinear,SphereMap, CubeReflect, CubeNormal的其中之一;這些模式和OpenGL紋理生成模式相對應。注意如果使用自定義頂點程序，那麼紋理生成將被忽略。
LightmapMode 光照貼圖模式。如果我們給出這個選項，紋理將能被渲染器的光線貼圖屬性所影響。紋理不能被使用在材質中，而是取自渲染器的設定。這個我們以後會講到。
六、光照、材質與顏色相關內容講解
燈光和材質參數常常被用來控制內置的頂點光照。而Unity中的頂點光照也就是Direct3D/OpenGL標準的按每頂點計算的光照模型—— 光照打開時，光照受材質塊，顏色材質和平行高光命令的影響。
我們來一起看一看光照、材質與顏色具體的語法。
這裏講到的都是採用固定功能渲染的代碼寫法，以及一些控制選項。講得有些細了，不用一次全記住，需要的時候回過頭來進行查閱就行了。
6.1 用於通道Pass中的代碼寫法列舉
這些代碼一般是寫在Pass{ }中的，細節如下：
Color Color
設定對象的純色。顏色即可以是括號中的四值（RGBA），也可以是被方框包圍的顏色屬性名。
Material { Material Block }
材質塊被用於定義對象的材質屬性。
Lighting On | Off
開啓光照，也就是定義材質塊中的設定是否有效。想要有效的話必須使用Lighting On命令開啓光照，而顏色則通過Color命令直接給出。
SeparateSpecular On | Off
開啓獨立鏡面反射。這個命令會添加高光光照到着色器通道的末尾，因此貼圖對高光沒有影響。只在光照開啓時有效。
ColorMaterial AmbientAndDiffuse | Emission
使用每頂點的顏色替代材質中的顏色集。AmbientAndDiffuse 替代材質的陰影光和漫反射值;Emission 替代 材質中的光發射值。
6.2 材質塊Material Block 中相關代碼寫法列舉
如下這些代碼的使用的地方是在SubShader中的一個Pass{ }中新開一個Material{ }塊，在這個Material{ }塊中進行這些語句的書寫。這些代碼包含了包含材質如何和光線產生作用的一些設置。這些屬性默認爲值都被設定爲黑色（也就是說不產生作用），也就是說他們一般情況下可以被忽略。當然，還是有很多時候需要使用到他們的。
Diffuse Color(R,G,B,A)
漫反射顏色構成。這是對象的基本顏色。
Ambient Color(R,G,B,A)
環境色顏色構成.這是當對象被RenderSettings.中設定的環境色所照射時對象所表現的顏色。
Specular Color(R,G,B,A)
對象反射高光的顏色。(R,G,B,A)四個分量分別代表紅綠藍和Alpha，取值爲0到1之間。
Shininess Number
加亮時的光澤度，在0和1之間。0的時候你會發現更大的高亮也看起來像漫反射光照，1的時候你會獲得一個細微的亮斑。
Emission Color
自發光顏色，也就是當不被任何光照所照到時，對象的顏色。(R,G,B,A)四個分量分別代表紅綠藍和Alpha，取值爲0到1之間。
而打在對象上的完整光照顏色最終是：
FinalColor=
Ambient * RenderSettings ambientsetting + (Light Color * Diffuse + Light Color *Specular) + Emission
翻譯過來的中文式子便是：
最終顏色=環境光反射顏色* 渲染設置環境設置 （燈光顏色漫反射顏色+燈光顏色*鏡面反射顏色）+自發光
知道了這個式子，我們就知道了，在各種光的綜合作用下，我們材質最終的顏色是怎麼來的了。
需要注意的是：方程式的燈光部分（也就是帶括號的部分）對所有打在對象上的光線都是重複使用的。而我們在寫Shader的時候常常會將漫反射和環境光光保持一致（所有內置Unity着色器都是如此）。
七、Shader書寫實戰
上面講了一堆一堆的概念，估計大家一遍看下來頭都大了。沒關係，讓我們看一些示例Shader的寫法，弄清楚上面這一堆堆的概念是如何應用的。
1.單色Shader
首先，用上文講到的Color命令，寫出一個有效代碼僅僅四行的袖珍Shader：
Shader”淺墨Shader編程/1.基礎單色”
{
//———————————【子着色器】———————————-
SubShader
{
//—————-通道—————
Pass
{
//設爲藍色單色
Color(0,0,0.6,0)
}
}
}
此Shader編譯後賦給材質的效果如下：
2.材質顏色&開啓光照的Shader
同樣的，我們可以在Pass中加上材質塊Material，在其中將將材質的漫反射和環境光反射顏色設爲相同，並且在該Pass中開啓光照：
Shader”淺墨Shader編程/2.材質顏色設置&開啓光照”
{
//———————————【子着色器1】———————————-
SubShader
{
//—————-通道—————
Pass
{
//———-材質————
Material
{
//將漫反射和環境光反射顏色設爲相同
Diffuse(0.9,0.5,0.4,1)
Ambient(0.9,0.5,0.4,1)
}
//開啓光照
Lighting On
}
}
}
此Shader編譯後賦給材質的效果如下：
3.可調漫反射光的Shader
在上面Shader的基礎上，我們引入一個color屬性，於是就得到了如下可調漫反射光顏色的Shader：
Shader “淺墨Shader編程/3.簡單的可調漫反射光照”
{
//——————————-【屬性】—————————————–
Properties
{
_MainColor (“主顏色”, Color) = (1,.1,.5,1)
}
//———————————【子着色器】———————————-
SubShader
{
//—————-通道—————
Pass
{
//———–材質————
Material
{
//可調節的漫反射光和環境光反射顏色
Diffuse [_MainColor]
Ambient[_MainColor]
}
Lighting On
}
}
}
此Shader編譯後賦給材質的效果如下：
4.光照材質完備beta版Shader
我們把餘下的Material屬性補上，便有了此光照材質完備beta版的shader：
Shader “淺墨Shader編程/4.光照材質完備beta版Shader”
{
//——————————-【屬性】—————————————–
Properties
{
_Color (“主顏色”, Color) = (1,1,1,0)
_SpecColor (“反射高光顏色”, Color) = (1,1,1,1)
_Emission (“自發光顏色”, Color) = (0,0,0,0)
_Shininess (“光澤度”, Range (0.01, 1)) = 0.7
}
//———————————【子着色器】———————————-
SubShader
{
//—————-通道—————
Pass
{
//———–材質————
Material
{
//可調節的漫反射光和環境光反射顏色
Diffuse [_Color]
Ambient [_Color]
//光澤度
Shininess [_Shininess]
//高光顏色
Specular [_SpecColor]
//自發光顏色
Emission [_Emission]
}
//開啓光照
Lighting On
}
}
}
此Shader編譯後賦給材質的效果如下，可以自由定製的選項多了不少：
5.簡單的紋理載入Shader
然後我們看一個簡單的紋理載入Shader的寫法：
Shader “淺墨Shader編程/5.簡單的紋理載入Shader”
{
//——————————-【屬性】—————————————–
Properties
{
//紋理
_MainTex(“基本紋理”,2D)=”White”{TexGen SphereMap}
}
//———————————【子着色器1】———————————-
SubShader
{
//—————-通道—————
Pass
{
//設置紋理爲屬性中選擇的紋理
SetTexture[_MainTex]{combine texture}
}
}
//———————————【備胎】—————————————-
//備胎設爲Unity自帶的普通漫反射
Fallback” Diffuse ”
}
此Shader編譯後賦給材質的效果如下：
需要注意，這裏用到了一點紋理生成的內容，具體用法我們下次再細講。
6.光照材質完備正式版Shader
結合Shader4 beta版的光照材質Shader和Shader5簡單的紋理載入，我們寫成了這篇文章的最終版Shader：
Shader “淺墨Shader編程/6.光照材質完備正式版Shader”
{
//——————————-【屬性】—————————————–
Properties
{
_Color (“主顏色”, Color) = (1,1,1,0)
_SpecColor (“高光顏色”, Color) = (1,1,1,1)
_Emission (“自發光顏色”, Color) = (0,0,0,0)
_Shininess (“光澤度”, Range (0.01, 1)) = 0.7
_MainTex (“基本紋理”, 2D) = “white” {}
}
//——————————–【子着色器】——————————–
SubShader
{
//—————-通道—————
Pass
{
//———–材質————
Material
{
//可調節的漫反射光和環境光反射顏色
Diffuse [_Color]
Ambient [_Color]
//光澤度
Shininess [_Shininess]
//高光顏色
Specular [_SpecColor]
//自發光顏色
Emission [_Emission]
}
//開啓光照
Lighting On
//開啓獨立鏡面反射
SeparateSpecular On
//設置紋理並進行紋理混合
SetTexture [_MainTex]
{
Combine texture * primary DOUBLE, texture * primary
}
}
}
}
其中，涉及到了紋理混合的知識，我們稍後會講解。
此Shader編譯後賦給材質的效果如下，可以發現，在這麼多的可定製選項下，我們可以自由調節出自己喜歡的材質效果來：
自由調節出各種詭異的材質：
OK，更多的材質效果圖就不放出了，大家下載文章末尾處提供的源工程，然後找到這個Shader自己調着玩吧。本文中所有的Shader和Material都位於Shaders文件夾中：