總述
在現實生活中,如果一個物體是透明的,意味着我們不僅僅可以透過它看到其他物體的樣子,也可以看到它內部的結構。但是在前面實現的透明效果中,無論是透明度測試還是透明度混合,都無法觀察到正方體內部及其背面的形狀,導致物體看起來好像只有半個一樣。這是因爲,默認情況下渲染引擎剔除了物體背面(相對於攝像機的方向)的渲染圖元,而只渲染了物體的正面。如果想要得到雙面渲染的效果,可以使用Cull指令來控制需要剔除哪個面的渲染圖元。
命令 | 描述 |
---|---|
Cull Off | 關閉剔除功能,所有圖元都會被渲染,由於這時需要渲染的圖元數目會成倍增加,一般不會用到。 |
Cull Back(默認) | 背對攝像機的渲染圖元不會被渲染 |
Cull Front | 正對攝像機的渲染圖元不會被渲染 |
透明度測試的雙面渲染
- 只需要在Pass的渲染設置中使用 Cull Off 即可。
- 關閉深度寫入,因此可以利用深度緩衝按逐像素的粒度進行深度排序,保證渲染的正確性。
透明度混合的雙面渲染
- 不能直接關閉剔除功能,即 Cull Off。原因是透明度混合需要關閉深度寫入。而想要得到正確的半透明效果,渲染順序要是從後往前渲染的。
- 把雙面渲染分成兩個Pass,第一個Pass只渲染背面,第二個Pass只渲染正面。Unity 順序執行 SubShader 中的各個Pass,因此可以保證背面總是在正面被渲染之前渲染,從而保證正確的深度渲染關係。
透明度測試雙面渲染的實現
Properties
{
_Color("Color", Color) = (1,1,1,1)
_MainTex("MainTex", 2D) = "white"{}
_AlphaScale("Alpha Scale", Range(0,1)) = 1 // 用於控制整個物體的透明度比例
}
SubShader
{
Tags { "Queue"="AlphaTest" "RenderType"="transparentCutout" "IgnoreProjector"="true"}
LOD 200
Pass
{
Tags{"LightMode"="ForwardBase"}
Cull Off
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
fixed _AlphaScale;
struct appdata_t
{
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 texcoord : TEXCOORD;
};
struct v2f
{
float4 vertex : SV_POSITION;
float3 worldPosiiton : TEXCOORD0;
float3 worldNormal : TEXCOORD1;
float2 uv : TEXCOORD2;
};
v2f vert(appdata_t v)
{
v2f OUT;
OUT.vertex = UnityObjectToClipPos(v.vertex);
OUT.worldPosiiton = mul(unity_ObjectToWorld, v.vertex);
OUT.worldNormal = UnityObjectToWorldNormal(v.normal);
OUT.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
return OUT;
}
fixed4 frag(v2f IN):SV_Target
{
fixed3 worldNormal = normalize(IN.worldNormal);
fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(IN.worldPosiiton));
fixed4 texColor = tex2D(_MainTex, IN.uv);
clip(texColor.a - _AlphaScale);
fixed3 albedo = texColor.rgb * _Color.rgb;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
fixed3 diffuse = _LightColor0.rgb * albedo * (0.5 * dot(worldNormal, worldLightDir) + 0.5);
return fixed4(albedo + diffuse, 1);
}
ENDCG
}
}
FallBack "Transparent/Cutout/VertexLit"
透明度混合雙面渲染的實現
Properties {
_Color ("Color Tint", Color) = (1, 1, 1, 1)
_MainTex ("Main Tex", 2D) = "white" {}
_AlphaScale ("Alpha Scale", Range(0, 1)) = 1
}
SubShader {
Tags {"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}
Pass {
Tags { "LightMode"="ForwardBase" }
// First pass renders only back faces
Cull Front
ZWrite Off
Blend SrcAlpha OneMinusSrcAlpha
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
fixed _AlphaScale;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 texcoord : TEXCOORD0;
};
struct v2f {
float4 pos : SV_POSITION;
float3 worldNormal : TEXCOORD0;
float3 worldPos : TEXCOORD1;
float2 uv : TEXCOORD2;
};
v2f vert(a2v v) {
v2f o;
o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
o.worldPos = mul(_Object2World, v.vertex).xyz;
o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
return o;
}
fixed4 frag(v2f i) : SV_Target {
fixed3 worldNormal = normalize(i.worldNormal);
fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
fixed4 texColor = tex2D(_MainTex, i.uv);
fixed3 albedo = texColor.rgb * _Color.rgb;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, worldLightDir));
return fixed4(ambient + diffuse, texColor.a * _AlphaScale);
}
ENDCG
}
Pass {
Tags { "LightMode"="ForwardBase" }
// Second pass renders only front faces
Cull Back
ZWrite Off
Blend SrcAlpha OneMinusSrcAlpha
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
fixed _AlphaScale;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 texcoord : TEXCOORD0;
};
struct v2f {
float4 pos : SV_POSITION;
float3 worldNormal : TEXCOORD0;
float3 worldPos : TEXCOORD1;
float2 uv : TEXCOORD2;
};
v2f vert(a2v v) {
v2f o;
o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
o.worldPos = mul(_Object2World, v.vertex).xyz;
o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
return o;
}
fixed4 frag(v2f i) : SV_Target {
fixed3 worldNormal = normalize(i.worldNormal);
fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
fixed4 texColor = tex2D(_MainTex, i.uv);
fixed3 albedo = texColor.rgb * _Color.rgb;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, worldLightDir));
return fixed4(ambient + diffuse, texColor.a * _AlphaScale);
}
ENDCG
}
}
FallBack "Transparent/VertexLit"