翻譯Shader(7)---漸變貼圖

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "BBBBBBBBBB/貼圖/03---漸變貼圖" {
	Properties{
		_Color("Color Tint", Color) = (1, 1, 1, 1)
		_RampTex("Ramp Tex", 2D) = "white" {}
		_Specular("Specular", Color) = (1, 1, 1, 1)
		_Gloss("Gloss", Range(8.0, 256)) = 20
	}
		SubShader{
			Pass {
				Tags { "LightMode" = "ForwardBase" }

				CGPROGRAM

				#pragma vertex vert
				#pragma fragment frag

				#include "Lighting.cginc"

				fixed4 _Color;
				sampler2D _RampTex;
				float4 _RampTex_ST;
				fixed4 _Specular;
				float _Gloss;

				struct a2v {
					float4 vertex : POSITION;
					float3 normal : NORMAL;
				};

				struct v2f {
					float4 pos : SV_POSITION;
					float3 worldNormal : TEXCOORD0;
					float3 worldPos : TEXCOORD1;
				};

				v2f vert(a2v v) {
					v2f o;
					//將頂點從模型空間轉換到裁剪空間
					o.pos = UnityObjectToClipPos(v.vertex);
					//將法線轉換到世界空間
					o.worldNormal = UnityObjectToWorldNormal(v.normal);
					//點再世界空間中的位置	
					o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;

					return o;
				}

				fixed4 frag(v2f i) : SV_Target {
				//計算環境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
				//序列化法線
				fixed3 worldNormal = normalize(i.worldNormal);
				//得到光源方向
				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				//半蘭伯特 漫反射計算
				fixed halfLambert = 0.5 * dot(worldNormal, worldLightDir) + 0.5;
				fixed3 diffuseColor = tex2D(_RampTex, fixed2(halfLambert,halfLambert)).rgb * _Color.rgb;
				fixed3 diffuse = _LightColor0.rgb * diffuseColor;
				//高光反射
				//獲取點到攝像機的方向角度，視角方向
				fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
				//光源方向+視角方向？？？
				fixed3 halfDir = normalize(worldLightDir + viewDir);
				//dot(worldNormal, halfDir)?不應該是視角方向*反射角方向嗎
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);
				//環境光   +   漫反射   +高光
				return fixed4(ambient + diffuse + specular, 1.0);
			}

			ENDCG
		}
		}
			FallBack "Specular"
}