例1: 批量 查詢部門號爲 "10" 號的並把它們打印出來 .
DECLARE
TYPE emp_table_type IS TABLE OF my_emp%ROWTYPE INDEX BY BINARY_INTEGER;
v_emp_table emp_table_type;
BEGIN
SELECT * BULK COLLECT INTO v_emp_table FROM my_emp WHERE deptno=&deptno;
FOR i IN 1..v_emp_table.COUNT LOOP
dbms_output.put_line('EMPLOYEE_INFO:'||v_emp_table(i).ename||
','||v_emp_table(i).job||
','||v_emp_table(i).hiredate);
END LOOP;
END;
說明部分:
1. DECLARE 說明以下你要聲明的部分
2. Type 聲明是類型 emp_table_typ e 類型的名字
3. IS TABLE OF 指定是一個集合的表的數組類型, 簡單的來說就是一個可以存儲一列多行的數據類型 , my_emp 指出在哪個表上( 存在的表 ) %ROWTYPE 指在表上的行的數據類型.
4. INDEX BY BINARY_INTEGER 指索引組織類型
5. v_emp_table 定義一個變量來存儲集合數據類型
6. BULK COLLECT INTO 指是一個成批聚合類型, 簡單的來說 , 它可以存儲一個多行多列存儲類型 ,into 後面指定從哪裏來 ,
7. v_emp_table.COUNT 用來 v_emp_table 裏面的數量
8. (i)表示下標號
例2: 批量 更新部門號爲 "10" 的員工工資
DECLARE
TYPE ename_table_type IS TABLE OF my_emp.ename%TYPE;
TYPE sal_table_type IS TABLE OF my_emp.sal%TYPE;
v_ename_table ename_table_type;
v_sal_table sal_table_type;
BEGIN
UPDATE my_emp SET sal=sal*1.20 WHERE deptno=&deptno RETURNING ename,sal
BULK COLLECT INTO v_ename_table,v_sal_table;
FOR i IN 1..v_ename_table.COUNT LOOP
dbms_output.put_line('EMPLOYEE_INFO:'||v_ename_table(i)||','||v_sal_table(i));
END LOOP;
END;
說明部分:
1. %TYPE和 my_emp.ename 數據類型一樣
v_ename_table ename_table_type;
2. v_sal_table sal_table_type; 定義變量來存儲它們 .
3. RETURNING 用來指定要返回的部分 ,BULK COLLECT INTO 成批聚合類型
4. 用for 把它們打印出來
(總結 ):
1. 實驗時把set serveroutput on 打開
2. 以上的例子的目的主要是爲了提高性能. 這裏的性能主要指的是速度 . 如果綜合的從整個 OLTP 或者 OLAP 系統的話就是另外一回事了 , 不以這裏討論 .
3. 速度指的是批量插入, 更新 , 刪除 , 爲什麼會提高速度呢 ?
4. 提取到的數據都在內存中進行處理, 因爲在內存處理比較快 , 這是常識 .
5. 附以下幾個例子大家自己看吧.
例3 ：批量插入
CREATE TABLE my_emp(empno number(4),ename varchar2(15))
/
DECLARE
TYPE empno_table_type IS TABLE OF number(4) INDEX BY BINARY_INTEGER;
TYPE ename_table_type IS TABLE OF varchar2(20) INDEX BY BINARY_INTEGER;
v_empno_table empno_table_type;
v_ename_table ename_table_type;
BEGIN
FOR i IN 1..1000 LOOP
v_empno_table(i):=i+2000;
v_ename_table(i):='NAME'||to_char(i);
END LOOP;
FORALL i IN 1..v_empno_table.COUNT INSERT INTO my_emp VALUES(v_empno_table(i),v_ename_table(i));
END;
/
例4: 批量更新
CREATE TABLE my_emp(empno number(4),ename varchar2(15))
/
DECLARE
TYPE empno_table_type IS TABLE OF my_emp.empno%TYPE INDEX BY BINARY_INTEGER;
TYPE ename_table_type IS TABLE OF my_emp.ename%TYPE INDEX BY BINARY_INTEGER;
v_empno_table empno_table_type;
v_ename_table ename_table_type;
BEGIN
FOR i IN 1..1000 LOOP
v_empno_table(i):=i+2000;
v_ename_table(i):='CN'||to_char(i);
END LOOP;
FORALL i IN 1..v_empno_table.COUNT UPDATE my_emp SET ename=v_ename_table(i) WHERE empno=v_empno_table(i);
END;
/
例5 ：批量刪除
DECLARE
TYPE empno_table_type IS TABLE OF my_emp.empno%TYPE INDEX BY BINARY_INTEGER;
v_empno_table empno_table_type;
BEGIN
FOR i IN 1..8 LOOP
v_empno_table(i):=i+2000;
END LOOP;
FORALL i IN 1..3 DELETE FROM my_emp WHERE empno=v_empno_table(i);
END;
/
例6 ： SQL%BULK_ROWCOUNT 屬性
DECLARE
TYPE deptno_table_type IS TABLE OF number(2);
v_deptno_table deptno_table_type:=deptno_table_type(10,20,30);
BEGIN
FORALL i IN 1.. v_deptno_table.COUNT UPDATE emp2 SET sal=sal*0.5 WHERE deptno=v_deptno_table(i);
dbms_output.put_line('DEPARTMENT_10:'||SQL%BULK_ROWCOUNT(1)||' rows');
dbms_output.put_line('DEPARTMENT_10:'||SQL%BULK_ROWCOUNT(1)||' rows');
dbms_output.put_line('DEPARTMENT_20:'||SQL%BULK_ROWCOUNT(2)||' rows');
dbms_output.put_line('DEPARTMENT_30:'||SQL%BULK_ROWCOUNT(3)||' rows');
END;
/
SQL%BULK_ROWCOUNT(i)表示 FORALL 語句第 i 元素所作用的行數