人物渲染篇（一） —— 基礎卡通渲染 上

人物渲染篇開篇，暫停下手邊的Java Web，決定開始練習角色的渲染，以後會嘗試更多的效果
shaderlab編寫前後對比：

這一次用到的知識點複習&總結

1. 梯度漫反射

float3 diffuse = _LightColor0.rgb * albedo * tex2D(_Ramp, float2(diff, diff)).rgb;

通過對這類梯度圖進行採樣，控制漫反射

2. 頂點擴張描邊法
   用一個pass在視角空間下把模型頂點沿着法線方向向外擴張一段距離

viewPos=viewPos+viewNormal*_Outline;

爲了防止一些內凹的模型出現背面遮擋正面面片，給頂點法線z分量一個定值，然後歸一化

viewNormal.z=-.05;
viewNormal=normalize(viewNormal);
viewPos=viewPos+viewNormal*_Outline;

3. 邊緣光
   視角方向與法線方向點成的方法控制邊緣光

 float edge=abs(dot(worldNormal,worldViewDir));
 edge = pow(1-edge,_ReflectionCount);

4. 基於切線的高光（各向異性高光）
   高光擾動圖與算法都來自於
   https://gameinstitute.qq.com/community/detail/100050

模型導入

從愛給網下的模型資源

鏈接：https://pan.baidu.com/s/1O8cpmApY8D5mMlyIhTNgpQ 
提取碼：u20h 

關於MAX單位設置，導出設置，軸心問題，可以參考博客
https://blog.csdn.net/fmx521/article/details/30315085?utm_source=blogxgwz1
導出MAX之前，一定要把貼圖資源複製到Textures文件夾下，不然貼圖丟失，材質也無效
我用2018.3導出失敗了，然後請網友用5.6成功了，懷疑與新prefab系統有關。。。

關於ShaderLab

附上一張效果圖

整個人物也只用到4個Shader，hair、body、eye、other

• 我不太懂建模與MAX，這個模型有很多沒有暴露在表面或者暴露面積很少的Mesh，我賦給它們一個other材質，這個材質只有邊緣光效果。（可能是專門用來描邊的？不太清楚）
• 眼睛部分就是梯度漫反射+高光
• 身體部分shader爲 頂點擴張+梯度漫反射+邊緣光
• 頭髮最麻煩，梯度漫反射+頂點擴張描邊+邊緣光+各向異性高光
  各項異性高光可以參考
  https://www.jianshu.com/p/7dc980ea4c51
  https://gameinstitute.qq.com/community/detail/100050

以bodyShader爲例

Shader "MyShaders/body" {
	Properties {
		_Color ("顏色", Color) = (1, 1, 1, 1)
		_MainTex ("主貼圖", 2D) = "white" {}
		_Ramp ("梯度漫反射紋理", 2D) = "white" {}
		_Outline ("描邊粗細", Range(0, 1)) = 0.1
		_OutlineColor ("邊線顏色", Color) = (0, 0, 0, 1)
		_ReflectionCount("邊緣光反射係數",Range(0,20))=10
	}
    SubShader {
		Tags { "RenderType"="Opaque" "Queue"="Geometry"}
		
		Pass {
			NAME "OUTLINE"
			
			Cull Front
			
			CGPROGRAM
			
			#pragma vertex vert
			#pragma fragment frag
			
			#include "UnityCG.cginc"
			
			float _Outline;
			fixed4 _OutlineColor;
			
			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
			}; 
			
			struct v2f {
			    float4 pos : SV_POSITION;
			};
			
			v2f vert (a2v v) {
				v2f o;
				
				float4 pos = mul(UNITY_MATRIX_MV, v.vertex); 
				float3 normal = mul((float3x3)UNITY_MATRIX_IT_MV, v.normal);  
				normal.z = -0.5;
				pos = pos + float4(normalize(normal), 0) * _Outline;
				o.pos = mul(UNITY_MATRIX_P, pos);
				
				return o;
			}
			
			float4 frag(v2f i) : SV_Target { 
				return float4(_OutlineColor.rgb, 1);               
			}
			
			ENDCG
		}
		
		Pass {
			Tags { "LightMode"="ForwardBase" }
			
			Cull Back
		
			CGPROGRAM
		
			#pragma vertex vert
			#pragma fragment frag
			
			#pragma multi_compile_fwdbase
		
			#include "UnityCG.cginc"
			#include "Lighting.cginc"
			#include "AutoLight.cginc"
			#include "UnityShaderVariables.cginc"
			
			fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			sampler2D _Ramp;
			float _ReflectionCount;
			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				float4 texcoord : TEXCOORD0;
				float4 tangent : TANGENT;
			}; 
		
			struct v2f {
				float4 pos : POSITION;
				float2 uv : TEXCOORD0;
				float3 worldNormal : TEXCOORD1;
				float3 worldPos : TEXCOORD2;
				SHADOW_COORDS(3)
			};
			
			v2f vert (a2v v) {
				v2f o;
				
				o.pos = UnityObjectToClipPos( v.vertex);
				o.uv = TRANSFORM_TEX (v.texcoord, _MainTex);
				o.worldNormal  = UnityObjectToWorldNormal(v.normal);
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				
				TRANSFER_SHADOW(o);
				
				return o;
			}
			
			float4 frag(v2f i) : SV_Target { 
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				fixed3 worldViewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
				
				fixed4 c = tex2D (_MainTex, i.uv);
				fixed3 albedo = c.rgb * _Color.rgb;
				
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
				
				UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
				
				fixed diff =  dot(worldNormal, worldLightDir);
				diff = (diff * 0.5 + 0.5) * atten;
				
				fixed3 diffuse = _LightColor0.rgb * albedo * tex2D(_Ramp, float2(diff, diff)).rgb;
			
				float edge=abs(dot(worldNormal,worldViewDir));
				float Fr = pow(1-edge,_ReflectionCount);

				return fixed4(ambient + diffuse, 1.0) + Fr;
			}
		
			ENDCG
		}
	}
	FallBack "Diffuse"
}