Shader | Unity Shader入門之基礎紋理

單張紋理

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Custom/Chapter7_SingleTexture"
{
    Properties
    {
        _Color ("Color Tint", Color) = (1,1,1,1)
        _MainTex ("Main Tex", 2D) = "white" {}
        _Specular ("Specular", Color) = (1,1,1,1)
        _Gloss ("Gloss", Range(0.8,256)) = 20
    }
    SubShader
    {
        Pass
        {
            Tags {"LightMode"="ForwadBase"}

            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"

            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;
            fixed4 _Specular;
            float _Gloss;

            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;
                float4 texcoord:TEXCOORD0;
            };

            struct v2f
            {
                float4 pos:SV_POSITION;
                float3 worldNormal:TEXCOORD0;
                float3 worldPos:TEXCOORD1;
                float2 uv:TEXCOORD2;
            };
            
            v2f vert(a2v v)
            {
                v2f o;
                o.pos=UnityObjectToClipPos(v.vertex);
                o.worldNormal=UnityObjectToWorldNormal(v.normal);
                o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;
                o.uv=v.texcoord.xyz*_MainTex_ST.xy+_MainTex_ST.zw;
                return o;
            }
            
            fixed4 frag(v2f i):SV_Target
            {
                fixed3 worldNormal=normalize(i.worldNormal);
                fixed3 worldLightDir=normalize(UnityWorldSpaceLightDir(i.worldPos));
                fixed3 albedo=tex2D(_MainTex,i.uv).rgb*_Color.rgb;
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz*albedo;
                fixed3 diffuse=_LightColor0.rgb*albedo*max(0,dot(worldNormal,worldLightDir));
                fixed3 viewDir=normalize(UnityWorldSpaceViewDir(i.worldPos));
                fixed3 halfDir=normalize(worldLightDir+viewDir);
                fixed3 specular=_LightColor0.rgb*_Specular.rgb*pow(max(0,dot(worldNormal,halfDir)),_Gloss);
                return fixed4(ambient+diffuse+specular,1.0);
            }


            ENDCG
        }
    }
    FallBack "Specular"
}

紋理的屬性

• Texture Type/ Default 即是 Diffuse Texture類型
• Wrap Mode 紋理平鋪方式：Repeat 重複；Clamp 截取邊界填充
• Filter Mode 紋理拉伸方式：Point 最近鄰濾波、Bilinear 線性濾波、Trilinear 同多級漸遠紋理混合。
  
  
  
• Default/ Format 決定紋理存儲格式

凹凸映射

Shader "Custom/Chapter7_NormalMapTangentSpace"
{
    Properties
    {
        _Color ("Color", Color) = (1,1,1,1)
        _MainTex ("Main Tex", 2D) = "white" {}
        _BumpMap ("Normal Map",2D) = "bump" {}
        _BumpScale ("Bump Scale", Float) = 1.0
        _Specular ("Specular", Color) = (1,1,1,1)
        _Gloss ("Gloss", Range(8.0,256)) = 20
    }
    SubShader
    {
        Pass
        {
            Tags { "LightMode"="ForwadBase" }

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"

            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;
            sampler2D _BumpMap;
            float4 _BumpMap_ST;
            float _BumpScale;
            fixed4 _Specular;
            float _Gloss;

            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;
                float4 tangent:TANGENT;
                float4 texcoord:TEXCOORD0;
            };

            struct v2f
            {
                float4 pos:SV_POSITION;
                float4 uv:TEXCOORD0;
                float3 lightDir:TEXCOORD1;
                float3 viewDir:TEXCOORD2;
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos=UnityObjectToClipPos(v.vertex);

                o.uv.xy=v.texcoord.xy*_MainTex_ST.xy+_MainTex_ST.zw;
                o.uv.zw=v.texcoord.xy*_BumpMap_ST.xy+_BumpMap_ST.zw;

                float3 binormal=cross(normalize(v.normal),normalize(v.tangent.xyz))*v.tangent.w;
                float3x3 rotation=float3x3(v.tangent.xyz,binormal,v.normal);
                //TANGENT_SPACE_ROTATION;

                o.lightDir=mul(rotation,ObjSpaceLightDir(v.vertex)).xyz;
                o.viewDir=mul(rotation,ObjSpaceViewDir(v.vertex)).xyz;

                return o;
            }

            fixed4 frag(v2f i):SV_Target
            {
                fixed3 tangentLightDir=normalize(i.lightDir);
                fixed3 tangentViewDir=normalize(i.viewDir);

                fixed4 packedNormal=tex2D(_BumpMap,i.uv.zw);
                fixed3 tangentNormal;

                tangentNormal=UnpackNormal(packedNormal);
                tangentNormal.xy*=_BumpScale;
                tangentNormal.z=sqrt(1.0-saturate(dot(tangentNormal.xy,tangentNormal.xy)));

                fixed3 albedo=tex2D(_MainTex,i.uv).rgb*_Color.rgb;
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz*albedo;
                fixed3 diffuse=_LightColor0.rgb*albedo*max(0,dot(tangentNormal,tangentLightDir));
                fixed3 halfDir=normalize(tangentLightDir+tangentViewDir);
                fixed3 specular=_LightColor0.rgb*_Specular.rgb*pow(max(0,dot(tangentNormal,halfDir)),_Gloss);
                return fixed4(ambient+diffuse+specular,1.0);
            }

            ENDCG
        }
    }
    FallBack "Specular"
}

CreateFroomGrayscale 適用於高度圖

Bumpiness 決定凹凸度
Filtering 決定法線紋理平滑/ Sobel濾波

Shader | 基礎紋理

@(我的第一個筆記本)[Shader, Unity, Graphics]

---

漸變紋理

在渲染中使用紋理：定義物體顏色 -> 定義任何表面屬性
漸變紋理控制漫反射光照效果的方法：

• 表面法線 · 光照方向 * 材質反射率
• ？

半蘭博光照模型

用漸變紋理控制漫反射光照

1. 新建場景Scene_7_3, 去SkyBox
2. 新建材質RampTextureMat
3. 新建着色器Chapter7_RampTexture, 並賦給RampTextureMat
4. 場景中拖入Suzanne模型(Unity_Shaders_Book/Assets/Models/suzanne.obj)，並使用RampTextureMat材質
5. 保存場景
6. 編輯着色器Chapter7_RampTexture

    Shader "Custom/Chapter7_RampTexture"
{
    Properties
    {
        _Color ("Color Tint", Color) = (1,1,1,1)
        _RampTex ("Ramp Tex", 2D) = "white" {}
        _Specular ("Specular", Color) = (1,1,1,1)
        _Gloss ("Gloss", Range(8.0,256)) = 20
    }
    SubShader
    {
        Pass
        {
            Tags { "LightMode"="ForwardBase" }


            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"

            fixed4 _Color;
            sampler2D _RampTex;//定義漸變屬性
            float4 _RampTex_ST;//定義漸變紋理屬性變量
            fixed4 _Specular;
            float _Gloss;

            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;
                float4 texcoord:TEXCOORD0;
            };

            struct v2f
            {
                float4 pos:SV_POSITION;
                float3 worldNormal:TEXCOORD0;
                float3 worldPos:TEXCOORD1;
                float2 uv:TEXCOORD2;
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos=UnityObjectToClipPos(v.vertex);

                o.worldNormal=UnityObjectToWorldNormal(v.normal);

                o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;

                o.uv=TRANSFORM_TEX(v.texcoord,_RampTex);

                return o;
            }
            
            fixed4 frag(v2f i):SV_Target
            {
                fixed3 worldNormal=normalize(i.worldNormal);
                fixed3 worldLightDir=normalize(UnityWorldSpaceLightDir(i.worldPos));

                //fixed3 albedo=tex2D(_MainTex,i.uv).rgb*_Color.rgb;
                //fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz*albedo;
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;
                
                fixed halfLambert=0.5*dot(worldNormal,worldLightDir)+0.5;//使用材質採樣漫反射顏色
                fixed3 diffuseColor=tex2D(_RampTex,fixed2(halfLambert,halfLambert)).rgb*_Color.rgb;

                fixed3 diffuse=_LightColor0.rgb*diffuseColor;

                fixed3 viewDir=normalize(UnityWorldSpaceViewDir(i.worldPos));
                fixed3 halfDir=normalize(worldLightDir+viewDir);
                fixed3 specular=_LightColor0.rgb*_Specular.rgb*pow(max(0,dot(worldNormal,halfDir)),_Gloss);

                return fixed4(ambient+diffuse+specular,1.0);
            }            

            ENDCG
        }
    }
    FallBack "Specular"
}

7. 保存代碼（編譯）
8. 導入漸變紋理資源(Unity_Shaders_Book/Assets/Textures/Chapter7/Ramp_Texture0.psd, Ramp_Texture1.psd, Ramp_Texture2.psd)，並將紋理資源的包裹模式Wrap Mode 設爲Clamp（固定）
   [外鏈圖片轉存失敗(img-RVIkff9d-1568973611258)(./1568792630748.png)]
9. 將紋理賦給材質RampTextureMat

得到結果分別如下
[外鏈圖片轉存失敗(img-0psGjWTh-1568973611259)(./1568793219339.png)]
[外鏈圖片轉存失敗(img-rTpaSQzy-1568973611261)(./1568793259273.png)]
[外鏈圖片轉存失敗(img-a7fpJr8l-1568973611262)(./1568793273487.png)]

遮罩紋理

Mask Texture（遮罩）：保護某些區域免於修改
遮罩紋理一般流程：①採樣得遮罩紋理 ②選取通道值*表面屬性

1. 新建場景Scene_7_4, 去SkyBox
2. 新建材質MaskTextureMat
3. 新建着色器Chapter7_MaskTexture, 並賦給MaskTextureMat
4. 場景新建Capsule，並使用RampTextureMat材質
5. 保存場景
6. 編輯着色器Chapter7_MaskTexture

Shader "Custom/Chapter7_MaskTexture"
{
    Properties
    {
        _Color ("Color Tint", Color) = (1,1,1,1)
        _MainTex ("Main Tex", 2D) = "white" {}

        _BumpMap ("Normal Map", 2D) = "bump" {}
		_BumpScale ("Bump Scale", Float) = 1.0

        _SpecularMask ("Specular Mask", 2D) = "white" {}
		_SpecularScale ("Specular Scale", Float) = 1.0
        _Specular ("Specular", Color) = (1,1,1,1)//反射
        _Gloss ("Gloss", Range(0.8,256)) = 20//光滑度
    }
    SubShader
    {
        Pass 
        { 
			Tags { "LightMode"="ForwardBase" }
		
			CGPROGRAM
			
			#pragma vertex vert
			#pragma fragment frag
			
			#include "Lighting.cginc"
			
			fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			sampler2D _BumpMap;
			float _BumpScale;
            sampler2D _SpecularMask;
            float _SpecularScale;
			fixed4 _Specular;
			float _Gloss;
			
			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				float4 tangent : TANGENT;
				float4 texcoord : TEXCOORD0;
			};
			
			struct v2f {
				float4 pos : SV_POSITION;
				float2 uv : TEXCOORD0;
				float3 lightDir : TEXCOORD1;  
				float3 viewDir : TEXCOORD2;  
			};
			
			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				
				o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
				
                TANGENT_SPACE_ROTATION;
				o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)).xyz;
				o.viewDir = mul(rotation, ObjSpaceViewDir(v.vertex)).xyz;

				return o;
			}
			
			fixed4 frag(v2f i) : SV_Target {
				fixed3 tangentLightDir = normalize(i.lightDir);
				fixed3 tangentViewDir = normalize(i.viewDir);
				
                fixed3 tangentNormal=UnpackNormal(tex2D(_BumpMap,i.uv));
                tangentNormal.xy*=_BumpScale;
                tangentNormal.z=sqrt(1.0-saturate(dot(tangentNormal.xy,tangentNormal.xy)));
				
				fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
				
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
				
				fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(tangentNormal, tangentLightDir));

				fixed3 halfDir = normalize(tangentLightDir + tangentViewDir);

                fixed specularMask=tex2D(_SpecularMask,i.uv).r*_SpecularScale;

				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(tangentNormal, halfDir)), _Gloss)*specularMask;
				
				return fixed4(ambient + diffuse + specular, 1.0);
			}
			
			ENDCG
        }
	}
    FallBack "Specular"
}

7. 裝載模型基本紋理、法線紋理和遮罩紋理，得到結果如下
   diffuse+specular+mask
   [外鏈圖片轉存失敗(img-V0EyNmkz-1568973611263)(./1568881741870.png)]
   diffuse
   [外鏈圖片轉存失敗(img-2FME4xvH-1568973611264)(./1568881783234.png)]
   diffuse+specular
   [外鏈圖片轉存失敗(img-7zfSlrSG-1568973611265)(./1568881889106.png)]