（二十三）unity shader之——————使用噪聲：上篇（消融效果）

很多時候向規則的事物裏添加一些“雜亂無章”的效果往往會有意想不到的效果，這些效果的來源就是造成，我們會學習使用噪聲來模擬各種看似“神奇”的特效。

一、消融效果

消融效果常見於遊戲中角色死亡、地圖燒燬等效果。在這些效果中，消融往往從不同的區域開始，並向看似隨機的方向擴張，最後整個物體都將消失不見。效果類似如下：

實現原理概況來說就是噪聲紋理+透明度測試。我們使用對噪聲紋理採樣的結果和某個控制消融程度的閾值比較，如果小於閾值，就使用clip函數把他對應的像素裁減掉，這些部分就對應了圖中被“燒燬”的區域。而鏤空區域邊緣的燒焦效果則是將兩種顏色混合，再利用pow函數處理後，與原紋理顏色混合後的結果。

1.聲明屬性：

Properties {
		_BurnAmount ("Burn Amount", Range(0.0, 1.0)) = 0.0
		_LineWidth("Burn Line Width", Range(0.0, 0.2)) = 0.1
		_MainTex ("Base (RGB)", 2D) = "white" {}
		_BumpMap ("Normal Map", 2D) = "bump" {}
		_BurnFirstColor("Burn First Color", Color) = (1, 0, 0, 1)
		_BurnSecondColor("Burn Second Color", Color) = (1, 0, 0, 1)
		_BurnMap("Burn Map", 2D) = "white"{}
	}

_BurnAmount屬性用於控制消融程度，當值爲0時，物體爲正常效果，爲1會完全消融。_LineWidth屬性控制模擬燒焦效果時的線寬，它的值越大，火焰邊緣的蔓延範圍越廣。_MainTex和_BumpMap分別對應了物體原本的漫反射紋理和法線紋理，_BurnFirstColor和_BurnSecondColor對應了火焰邊緣的兩種顏色值。_BumpMap則是噪聲紋理。

2.定義Pass：

Pass {
			Tags { "LightMode"="ForwardBase" }

			Cull Off
			
			CGPROGRAM
			
			#include "Lighting.cginc"
			#include "AutoLight.cginc"
			
			#pragma multi_compile_fwdbase

這裏使用Cull命令關閉了該shader的面片剔除，也就是說模型的正面和背面都會被渲染，這時因爲消融會導致裸露模型內部的構造，如果只渲染正面會出現錯誤的結果。

3.定義頂點着色器：

struct v2f {
				float4 pos : SV_POSITION;
				float2 uvMainTex : TEXCOORD0;
				float2 uvBumpMap : TEXCOORD1;
				float2 uvBurnMap : TEXCOORD2;
				float3 lightDir : TEXCOORD3;
				float3 worldPos : TEXCOORD4;
				SHADOW_COORDS(5)
			};
			
			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				
				o.uvMainTex = TRANSFORM_TEX(v.texcoord, _MainTex);
				o.uvBumpMap = TRANSFORM_TEX(v.texcoord, _BumpMap);
				o.uvBurnMap = TRANSFORM_TEX(v.texcoord, _BurnMap);
				
				TANGENT_SPACE_ROTATION;
  				o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)).xyz;
  				
  				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
  				
  				TRANSFER_SHADOW(o);
				
				return o;
			}

這裏把光源方向從模型空間變換到了切線空間。

4.實現片元着色器來模擬消融效果:

	fixed4 frag(v2f i) : SV_Target {
				fixed3 burn = tex2D(_BurnMap, i.uvBurnMap).rgb;
				
				clip(burn.r - _BurnAmount);
				
				float3 tangentLightDir = normalize(i.lightDir);
				fixed3 tangentNormal = UnpackNormal(tex2D(_BumpMap, i.uvBumpMap));
				
				fixed3 albedo = tex2D(_MainTex, i.uvMainTex).rgb;
				
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
				
				fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(tangentNormal, tangentLightDir));

				fixed t = 1 - smoothstep(0.0, _LineWidth, burn.r - _BurnAmount);
				fixed3 burnColor = lerp(_BurnFirstColor, _BurnSecondColor, t);
				burnColor = pow(burnColor, 5);
				
				UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
				fixed3 finalColor = lerp(ambient + diffuse * atten, burnColor, t * step(0.0001, _BurnAmount));
				
				return fixed4(finalColor, 1);
			}

首先對噪聲紋理採樣，將採樣結果和用於控制消融程度的屬性_BurnAmount相減，傳遞給clip函數。當結果小於0時，該像素將會被剔除，從而不會顯示到屏幕上。如果通過了測試，則進行正常的光照計算。先根據漫反射紋理得到材質的反射率albedo，並由此計算得到環境光照，進而得到漫反射光照。然後計算了燒焦顏色burnColor，我們想要在寬度爲_LineWidth的範圍內模擬一個燒焦的顏色變化，第一步就使用了smoothstep函數來計算混合係數t。當t值爲1時，表明該像素模擬一個燒焦效果。我們首先用t來混合兩種火焰顏色_BurnFirstColor和_BurnSecondColor，爲了讓效果更加接近燒焦的痕跡，我們還使用pow函數對結果進行處理。然後再次使用t來混合正常的光照顏色（環境光+漫反射）和燒焦顏色。我們這裏又使用了step函數來保證當_BurnAmount爲0時，不顯示任何消融效果。最後，返回混合後的顏色值finalColor。

5.我們還定義了一個用於投射陰影的Pass。使用透明度測試的物體的陰影需要特別處理，如果仍然使用普通的陰影Pass，那麼被剔除的區域仍然會向其他物體投射陰影，造成穿幫。爲了讓物體的陰影也能配合透明度測試產生正確的效果，需要自定義一個陰影投射Pass：

// Pass to render object as a shadow caster
		Pass {
			Tags { "LightMode" = "ShadowCaster" }
			
			CGPROGRAM
			
			#pragma vertex vert
			#pragma fragment frag
			
			#pragma multi_compile_shadowcaster
			
			#include "UnityCG.cginc"
			
			fixed _BurnAmount;
			sampler2D _BurnMap;
			float4 _BurnMap_ST;
			
			struct v2f {
				V2F_SHADOW_CASTER;
				float2 uvBurnMap : TEXCOORD1;
			};
			
			v2f vert(appdata_base v) {
				v2f o;
				
				TRANSFER_SHADOW_CASTER_NORMALOFFSET(o)
				
				o.uvBurnMap = TRANSFORM_TEX(v.texcoord, _BurnMap);
				
				return o;
			}
			
			fixed4 frag(v2f i) : SV_Target {
				fixed3 burn = tex2D(_BurnMap, i.uvBurnMap).rgb;
				
				clip(burn.r - _BurnAmount);
				
				SHADOW_CASTER_FRAGMENT(i)
			}
			ENDCG
		}

在unity中，用於投射陰影的Pass的LightMode需要被設置爲ShadowCaster，同時還需要使用#pragma_multi_compile_shadowcaster指明它需要的編譯指令。

陰影投射的重點在於我們需要按正常Pass的處理來剔除片元或進行頂點動畫，以便陰影可以和物體正常渲染的結果相匹配。在自定義陰影投射Pass中，我們通常會使用unity提供的內置宏V2F_SHADOW_CASTER、TRANSFER_SHADOW_CASTER_NORMALOFFSET、SHADOW_CASTER_FRAGMENT來幫助我們計算陰影投射所需要的各種變量，而我們可以只關注自定義計算的部分。上面代碼中，首先在v2f結構體中利用V2F_SHADOW_CASTER來定義陰影投射需要定義的變量，隨後在頂點着色器中，使用TRANSFER_SHADOW_CASTER_NORMALOFFSET來填充V2F_SHADOW_CASTER在背後聲明的一些變量，這裏由unity背後爲我們完成的。我們需要在頂點着色器中關注自定義的計算部分，這裏指的就是我們需要計算噪聲紋理的採樣結果來剔除片元，最後在利用SHADOW_CASTER_FRAGMENT來讓unity爲我們完成陰影投射的部分，把結果輸出到深度圖和陰影映射紋理中。

通過unity提供的三個內置宏（UnityCG.cginc文件中被定義），我們可以方便地自定義需要的陰影投射的Pass，但這些宏需要使用一些特定的輸入變量，比如v包含vertex和頂點法線信息等，這裏我們使用的內置的appdata_base結構體，它包含了這些必須的頂點變量，如果我們需要進行頂點動畫，可以在頂點着色器中直接修改v.vertex，在傳遞給宏中即可。

使用不同的噪聲和紋理屬性（即材質面板上紋理的Tiling和Offset值）都會得到不同的消融效果，因此想要得到更好的消融效果，也需要美術人員提供合適的噪聲紋理來配合。