Unity2D Sprite灰白圖（Unity3D開發之十一）

猴子原創，歡迎轉載。轉載請註明： 轉載自Cocos2D開發網–Cocos2Dev.com，謝謝！

原文地址: http://www.cocos2dev.com/?p=596

昨晚看到羣裏問到2DSprite怎麼變成灰白圖，晚上看了下，修改shader是最方便的。

下面是Sprites-Gray.shader的實現，請放入自己工程：

Shader "Sprites/Gray"
{
Properties
{
    [PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
    _Color ("Tint", Color) = (1,1,1,1)
    [MaterialToggle] PixelSnap ("Pixel snap", Float) = 0
}


SubShader
{
    Tags
    { 
        "Queue"="Transparent" 
        "IgnoreProjector"="True" 
        "RenderType"="Transparent" 
        "PreviewType"="Plane"
        "CanUseSpriteAtlas"="True"
    }


    Cull Off
    Lighting Off
    ZWrite Off
    Fog { Mode Off }
    Blend One OneMinusSrcAlpha


    Pass
    {
    CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #pragma multi_compile DUMMY PIXELSNAP_ON
        #include "UnityCG.cginc"


        struct appdata_t
        {
            float4 vertex   : POSITION;
            float4 color    : COLOR;
            float2 texcoord : TEXCOORD0;
        };


        struct v2f
        {
            float4 vertex   : SV_POSITION;
            fixed4 color    : COLOR;
            half2 texcoord  : TEXCOORD0;
        };


        fixed4 _Color;


        v2f vert(appdata_t IN)
        {
            v2f OUT;
            OUT.vertex = mul(UNITY_MATRIX_MVP, IN.vertex);
            OUT.texcoord = IN.texcoord;
            OUT.color = IN.color * _Color;
            #ifdef PIXELSNAP_ON
            OUT.vertex = UnityPixelSnap (OUT.vertex);
            #endif


            return OUT;
        }


        sampler2D _MainTex;


        fixed4 frag(v2f IN) : SV_Target
        {
            fixed4 c = tex2D(_MainTex, IN.texcoord) * IN.color;
            c.rgb *= c.a;
            float gray = dot(c.xyz, float3(0.299, 0.587, 0.114));
            c.xyz = float3(gray, gray, gray);
            return c;
        }
    ENDCG
    }
}
}

使用方法：

// Use this for initialization
void Start () {
    SpriteRenderer render = this.GetComponent<SpriteRenderer> ();
    render.material.shader = Shader.Find ("Sprites/Gray");
}