Unity流光shader，無需圖片

本片博客實現流光shader的方式無需黑色帶有白道的圖片，單純通過計算實現，可以調節光帶寬度、亮度、方向、角度，靈活性比較大。
下面圖是實現效果

下面是代碼的實現：

Shader "Unlit/liuguang"
{
	Properties
	{
		_MainTex ("Texture", 2D) = "white" {}
		
		// 速度 默認左->右
		_Speed ("Speed", range(-2, 2)) = 1.04
		
		// 寬度
		_Width ("Width", range(1, 10)) = 5.83

		// 角度
		_Angle ("Angle", range(-1, 1)) = 0.33

		// 亮度
		_Light ("Light", range(0, 1)) = 0.51
	}
	SubShader
	{
		Tags { "RenderType"="Opaque" }
		LOD 100

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			
			#include "UnityCG.cginc"

			struct appdata
			{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
			};

			struct v2f
			{
				float2 uv : TEXCOORD0;
				float4 vertex : SV_POSITION;
			};

			sampler2D _MainTex;
			
			v2f vert (appdata v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv = v.uv;
				return o;
			}
			
			float _Speed; 
			float _Width; 
			float _Angle; 
			float _Light; 
			fixed4 frag (v2f i) : SV_Target
			{
				fixed4 col = tex2D(_MainTex, i.uv);
				float x = i.uv.x + i.uv.y * _Angle;
				float v = sin(x - _Time.w * _Speed);
				v = smoothstep(1 - _Width / 1000, 1.0, v);
				float3 target = float3(v, v, v) + col.rgb;
				col.rgb = lerp(col.rgb, target, _Light);
				return col;
			}
			ENDCG
		}
	}
}

流光是一條光帶，所以無需進行進行頂點計算，正在片元着色器按照規則疊加像素值就可以。使用sin函數和_Time可以得到-1到1的波浪，與原像素疊加，可以得到下面的效果：

觀察上圖會發現有以下幾個部分：

1. 出現了陰暗：
   因爲sin函數取值到了小於0的部分，跟原像素疊加就變成了暗的或者黑色，取值越小，越暗
2. 全白或全黑：
   在sin函數取值範圍[-1, 0]和[0, 1]的區間內，都進行了像素值疊加，所以看起來整張圖片明暗都變了。
   爲解決上面兩個問題，需要對sin函數的的取值進行取捨，使用smoothstep函數進行範圍先定，去除了[-1, 0]的部分，以及不符合自定義的取值部分。再使用lerp函數插值處理，使得看起來更平滑。

---

具體項目可見到我的GitHub倉庫：流光shader