忘記在哪裏找的的shader了,有的我做了簡單的修改,有的我只是結合了一下,我會把以轉載的方式發出來,以尊重原創開發。
這次的是找到的模型的“裁剪”效果,並不是真正的基於模型的裁剪,並不會影像碰撞等效果,而是基於渲染的裁剪,效果如下:
接下來上代碼:
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'
//消失效果
//by:puppet_master
//2017.8.11
Shader "SepShader/DissolveEffectX"
{
Properties{
_Diffuse("Diffuse", Color) = (1,1,1,1)
_DissolveColor("Dissolve Color", Color) = (0,0,0,0)
_MainTex("Base 2D", 2D) = "white"{}
_ColorFactor("ColorFactor", Range(0,1)) = 0.7//這個值什麼時候光圈在最下邊呢,當模型比例爲1時最下端點到中心點的Y值差
_DissolveThreshold("DissolveThreshold", Float) = 0
}
CGINCLUDE
#include "Lighting.cginc"
uniform fixed4 _Diffuse;
uniform fixed4 _DissolveColor;
uniform sampler2D _MainTex;
uniform float4 _MainTex_ST;
uniform float _ColorFactor;
uniform float _DissolveThreshold;
struct v2f
{
float4 pos : SV_POSITION;
float3 worldNormal : TEXCOORD0;
float2 uv : TEXCOORD1;
float4 objPos : TEXCOORD2;
};
v2f vert(appdata_base v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
o.objPos = v.vertex;//以模型座標爲標準
//o.objPos = mul(unity_ObjectToWorld, v.vertex);//以世界座標爲標準
return o;
}
fixed4 frag(v2f i) : SV_Target
{
float factor = i.objPos.z - _DissolveThreshold;//這句話我理解爲相對於中心在Y方向上的值減去閾值
clip(factor);
//Diffuse + Ambient光照計算
fixed3 worldNormal = normalize(i.worldNormal);
fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
fixed3 lambert = saturate(dot(worldNormal, worldLightDir));
fixed3 albedo = lambert * _Diffuse.xyz * _LightColor0.xyz + UNITY_LIGHTMODEL_AMBIENT.xyz;
fixed3 color = tex2D(_MainTex, i.uv).rgb * albedo;
//等價於下面註釋代碼的操作
fixed lerpFactor = saturate(sign(_ColorFactor - factor));
return lerpFactor * _DissolveColor + (1 - lerpFactor) * fixed4(color, 1);
/*
if (factor < _ColorFactor)
{
return _DissolveColor;
}
return fixed4(color, 1);*/
}
ENDCG
SubShader
{
Tags{ "RenderType" = "Opaque" }
Pass
{
//不讓模型穿幫,關掉了背面裁剪
Cull Off
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
ENDCG
}
}
FallBack "Diffuse"
}
注:是基於哪個軸的裁剪需要修改片元着色器中的i.objPos的軸