凹凸映射的目的是使用一張紋理來修改模型表面的法線，以便爲模型提供更多的細節。
這個方法不會真的改變模型的頂點位置。
凹凸映射的兩種方式：
1.高度映射：使用一張高度紋理來模擬表面位移，然後得到一個修改後的法線值。
2.法線映射：使用一張法線紋理來直接存儲表面法線。
我們通常使用 高度圖和發現映射一起使用，來修改光照。
法線紋理：
存儲的是表面的法線方向，法線方向的分量範圍在[-1,1],而像素的分量爲[0,1]，因此我們需要一個映射 pixel= (normal+1)/2
這樣我們在shader中對法線紋理採樣後，還需要來一次反映射，得到原先法線方向。
normal=pixel*2-1
由於法線方向是根據座標空間來的，那麼法線紋理又分爲：模型空間的法線紋理 和 切線空間的法線紋理。
模型空間法線紋理：模型頂點自帶的法線，此紋理看起來 比較五顏六色
切線空間法線紋理：模型的每個頂點都有一個屬於自己的切線空間，該空間的原點 就是頂點自身，z軸 頂點的法線方向，x軸頂點的切線方向，y軸 是由 法線和切線的叉積得到的，也叫做 副切線 或者副法線。此紋理看起來 顏色單一。
模型空間法線優點：
1. 實現簡單，更加直觀
2.可以提供平滑的邊界
切線空間法線優點：
1.自由度高，記錄的是相對法線信息，可以應用到完全不同的網格上。
2.可以進行uv動畫。水或者火山熔岩上面
3.可以重用法線紋理
4.可壓縮，切線空間下的法線z方向總是正方向，可以僅存儲xy，推出z。
所以一般美術 都會使用切線空間下的 法線紋理。
由於在計算光照模型的時候，需要統一所在的座標空間。所以這裏有兩種方法：
1.在切線空間下進行光照計算，這時需要把光照方向，視角方向變換到切線空間下。
2. 在世界空間下進行光照計算，我們需要把切線空間下的法線方向變換到世界空間，再和世界空間下的光照方向視角方向進行計算。
- 切線空間下
Shader "Custom/TangentOT"
{
Properties
{
_Color("Color",Color)=(1,1,1,1)
_MainTex("Main Tex",2D)="white" {}
_BumpMap("Normal Map",2D)="bump" {}
_BumpScale("Bump Scale",float)=1
_Specular("Specular",Color)=(1,1,1,1)
_Gloss("Gloss",Range(8,256))=20
}
SubShader
{
pass
{
Tags{"LightMode"="ForwardBase"}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _BumpMap;
float4 _BumpMap_ST;
//控制凹凸 度
float _BumpScale;
fixed4 _Specular;
float _Gloss;
struct a2v
{
float4 vertex:POSITION;
float3 normal:NORMAL;
float4 texcoord:TEXCOORD0;
//頂點的切線信息
float4 tangent:TANGENT;
};
struct v2f
{
float4 pos:SV_POSITION;
//存儲兩套紋理座標的變量float4
float4 uv:TEXCOORD0;
float3 lightDir:TEXCOORD1;
float3 viewDir:TEXCOORD2;
};
v2f vert(a2v v)
{
v2f o;
o.pos=UnityObjectToClipPos(v.vertex);
//這兩個紋理使用同一組紋理座標，爲節省插值寄存器的使用數目
o.uv.xy=v.texcoord.xy*_MainTex_ST.xy+_MainTex_ST.zw;
o.uv.zw=v.texcoord.xy*_BumpMap_ST.xy+_BumpMap_ST.zw;
// float3 binormal=cross(normalize(v.normal),normalize(v.tangent.xyz))*v.tangent.w;
// float3x3 rotation=float3x3(v.tangent.xyz,binormal,v.normal);
//模型空間到切線空間的變換矩陣
TANGENT_SPACE_ROTATION;
//轉換到切線空間 中 變換矩陣rotation
o.lightDir=mul(rotation,ObjSpaceLightDir(v.vertex)).xyz;
o.viewDir=mul(rotation,ObjSpaceViewDir(v.vertex)).xyz;
return o;
}
fixed4 frag(v2f i):SV_Target
{
fixed3 tangentLightDir=normalize(i.lightDir);
fixed3 tangentViewDir=normalize(i.viewDir);
//對法線紋理進行採樣
fixed4 packedNormal=tex2D(_BumpMap,i.uv.zw);
fixed3 tangentNormal;
// tangentNormal.xy=(packedNormal.xy*2-1)*_BumpScale;
// tangentNormal.z=sqrt(1-saturate(dot(tangentNormal.xy,tangentNormal.xy)));
tangentNormal=UnpackNormal(packedNormal); //得到正確的法線方向
tangentNormal.xy*=_BumpScale;
tangentNormal.z=sqrt(1-saturate(dot(tangentNormal.xy,tangentNormal.xy)));
//對紋理進行採樣，與顏色屬性乘積 來作爲材質的反光率albedo
fixed3 albedo=tex2D(_MainTex,i.uv).rgb*_Color.rgb;
fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz*albedo;
//使用 albedo 來計算漫反射
fixed3 diffuse=_LightColor0.rgb*albedo*max(0,dot(tangentNormal,tangentViewDir));
fixed3 halfDir=normalize(tangentLightDir+tangentViewDir);
fixed3 specular=_LightColor0.rgb*_Specular.rgb*pow(max(0,dot(tangentNormal,halfDir)),_Gloss);
fixed3 scolor=ambient+diffuse+specular;
return fixed4(scolor,1);
}
ENDCG
}
}
FallBack "Diffuse"
}
- 世界空間下計算光照
Shader "Custom/WorldSpaceOT"
{
Properties
{
_Color("Color",Color)=(1,1,1,1)
_MainTex("Main Tex",2D)="white" {}
_BumpMap("Normal Map",2D)="bump" {}
_BumpScale("Bump Scale",float)=1
_Specular("Specular",Color)=(1,1,1,1)
_Gloss("Gloss",Range(8,256))=20
}
SubShader
{
pass
{
Tags{"LightMode"="ForwardBase"}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _BumpMap;
float4 _BumpMap_ST;
//控制凹凸 度
float _BumpScale;
fixed4 _Specular;
float _Gloss;
struct a2v
{
float4 vertex:POSITION;
float3 normal:NORMAL;
float4 texcoord:TEXCOORD0;
float4 tangent:TANGENT;
};
struct v2f
{
float4 pos:SV_POSITION;
//存儲兩套紋理座標的變量float4
float4 uv:TEXCOORD0;
//存儲從切線空間到世界空間的變換矩陣
float4 Ttow0:TEXCOORD1;
float4 Ttow1:TEXCOORD2;
float4 Ttow2:TEXCOORD3;
};
v2f vert(a2v v)
{
v2f o;
o.pos=UnityObjectToClipPos(v.vertex);
o.uv.xy=v.texcoord.xy*_MainTex_ST.xy+_MainTex_ST.zw;
o.uv.zw=v.texcoord.xy*_BumpMap_ST.xy+_BumpMap_ST.zw;
float3 worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;
fixed3 worldNormal=UnityObjectToWorldNormal(v.normal);
fixed3 worldTangent=UnityObjectToWorldDir(v.tangent.xyz);
fixed3 worldBinormal=cross(worldNormal,worldTangent)*v.tangent.w;
o.Ttow0=float4(worldTangent.x,worldBinormal.x,worldNormal.x,worldPos.x);
o.Ttow1=float4(worldTangent.y,worldBinormal.y,worldNormal.y,worldPos.y);
o.Ttow2=float4(worldTangent.z,worldBinormal.z,worldNormal.z,worldPos.z);
return o;
}
fixed4 frag(v2f i):SV_Target
{
float3 worldPos=float3(i.Ttow0.w,i.Ttow1.w,i.Ttow2.w);
fixed3 lightDir=normalize(UnityWorldSpaceLightDir(worldPos));
fixed3 viewDir=normalize(UnityWorldSpaceViewDir(worldPos));
fixed3 bump=UnpackNormal(tex2D(_BumpMap,i.uv.zw));
bump.xy*=_BumpScale;
bump.z=sqrt(1-saturate(dot(bump.xy,bump.xy)));
bump=normalize(half3(dot(i.Ttow0.xyz,bump),dot(i.Ttow1.xyz,bump),dot(i.Ttow2.xyz,bump)));
//對紋理進行採樣，與顏色屬性乘積 來作爲材質的反光率albedo
fixed3 albedo=tex2D(_MainTex,i.uv).rgb*_Color.rgb;
fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz*albedo;
//使用 albedo 來計算漫反射
fixed3 diffuse=_LightColor0.rgb*albedo*max(0,dot(bump,lightDir));
fixed3 halfDir=normalize(lightDir+viewDir);
fixed3 specular=_LightColor0.rgb*_Specular.rgb*pow(max(0,dot(bump,halfDir)),_Gloss);
fixed3 scolor=ambient+diffuse+specular;
return fixed4(scolor,1);
}
ENDCG
}
}
FallBack "Specular"
}
通過改變凹凸係數 可以看出模型表現效果
